build.gradle

plugins {
    id 'groovy'
    id 'idea'
    id 'com.gradle.plugin-publish' version '0.12.0'
    id 'com.github.johnrengelman.shadow' version '6.0.0'
}

ext {
    inceptionYear = '2015'
    url = 'https://github.com/matthewprenger/CurseGradle'
}

version = '1.4.0'
group = 'com.matthewprenger'
description = 'Gradle plugin to upload artifacts to CurseForge'
archivesBaseName = 'CurseGradle'

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    jcenter()
}

dependencies {
    compileOnly gradleApi()
    compileOnly localGroovy()

    implementation group: 'net.sf.trove4j', name: 'trove4j', version: '3.0.3'
    implementation group: 'com.google.guava', name: 'guava', version: '19.0'
    implementation group: 'com.google.code.gson', name: 'gson', version: '2.6.2'
    implementation group: 'org.apache.httpcomponents', name: 'httpmime', version: '4.5.2'
    implementation group: 'org.apache.httpcomponents', name: 'httpclient', version: '4.5.2'
}

jar.manifest.mainAttributes([
        'Implementation-Title'  : project.name,
        'Implementation-Version': project.version
])

task javadocJar(type: Jar, dependsOn: javadoc) {
    from javadoc.destinationDir
    archiveClassifier.set('javadoc')
}

task sourcesJar(type: Jar) {
    from sourceSets.main.allSource
    archiveClassifier.set('sources')
}

artifacts {
    archives jar
    archives javadocJar
    archives sourcesJar
}

assemble.dependsOn javadocJar, sourcesJar

[compileJava, compileGroovy].each {
    it.options.encoding = 'UTF-8'
    it.options.deprecation = true
    it.options.fork = true
}

pluginBundle {
    website = project.url
    vcsUrl = 'https://github.com/matthewprenger/CurseGradle'
    plugins {
        curseGradlePlugin {
            id = 'com.matthewprenger.cursegradle'
            description = project.description
            displayName = 'CurseGradle'
            version = project.version
            tags = ['curseforge', 'publish', 'minecraft']
        }
    }
}