Backticked vars misinterpreted by quote do: when creating pragmas

[genotrance]

I'm using macros to create types with quote do: but added pragmas are not working correctly since backticked variables are interpreted incorrectly.

Example

import macros

var
  typ {.compiletime.} = "struct ABC"
  name {.compiletime.} = "ABC".newIdentNode()

macro abc(): untyped =
  result = newNimNode(nnkStmtList)

  result.add(quote do:
    type `name` {.importc: `typ`.} = object
  )

  echo result.repr

abc()

Current Output

type
  ABC {.importc: 3.} = object

Expected Output

type
  ABC {.importc: "struct ABC".} = object

Note that name is interpreted correctly, only contents in side the pragma section are misinterpreted. If you add more elements - e.g. header or something else, you get numbers again.

[narimiran]

I can reproduce.

---

Until this is fixed/resolved, here is a quick-n-dirty (-n-ugly ;)) version made by using dumpAstGen which works.

import macros

var
  typ {.compiletime.} = "struct ABC"
  name {.compiletime.} = "ABC".newIdentNode()

macro abc(): untyped =
  result = nnkStmtList.newTree(
    nnkTypeSection.newTree(
      nnkTypeDef.newTree(
        nnkPragmaExpr.newTree(
          name,
          nnkPragma.newTree(
            nnkExprColonExpr.newTree(
              newIdentNode("importc"),
              newLit(typ)
            )
          )
        ),
        newEmptyNode(),
        nnkObjectTy.newTree(
          newEmptyNode(),
          newEmptyNode(),
          newEmptyNode()
        )
      )
    )
  )
  echo result.repr

abc()

[genotrance]

Thanks for sharing. If quote do: is unreliable, is parseStmt() better? Makes the code readable. That being said, since this is a library I'm working on, I want reliable interpretation so let me know if writing full trees is worth it.

[alehander92]

https://github.com/alehander42/breeze this might make it a bit easier to build trees too.

[genotrance]

Thanks I'll check it out. For now I'm using parseStmt because it is a bit more readable than building full trees.

[mratsim]

I've also noticed that the symbol pass for importc and exportc is done very early. For example it is done before template are expanded here: #9366.

[krux02]

current output:

type
  ABC {.importc: "struct ABC".} = object