build.gradle

buildscript {
    ext.kotlin_version = '1.9.22'
    repositories {
        google()
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:7.4.2'
        classpath 'com.github.dcendents:android-maven-gradle-plugin:2.1'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

allprojects {
    group = 'com.github.niqdev'
    version = getTag()

    repositories {
        google()
        mavenCentral()
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

@SuppressWarnings("unused")
static def getGitCommitCount() {
    def process = "git rev-list HEAD --count".execute()
    return process.text.toInteger()
}

@SuppressWarnings("unused")
static def getTag() {
    // with local un-commited changes a -DIRTY is added
    def processChanges = "git diff-index --name-only HEAD --".execute()
    def dirty = ""
    if (!processChanges.text.toString().trim().isEmpty())
        dirty = "-DIRTY"

    def process = "git describe --tags".execute()
    return process.text.toString().trim() + dirty
}