[FEA] Add initial CMakeLists.txt

.gitattributes

@@ -0,0 +1 @@
+legate/_version.py export-subst

.gitignore

@@ -21,10 +21,16 @@
 *.json
 *.dylib
 legate/core/install_info.py
+/dist
 /build
 /legion
 /install*
+/_skbuild
 config.mk
 /docs/legate/core/build
 /docs/legate/core/source/api/generated
 *.egg-info
+.cache
+.vscode
+_cmake_test_compile
+!cmake/versions.json

CMakeLists.txt

@@ -0,0 +1,71 @@
+#=============================================================================
+# Copyright 2022 NVIDIA Corporation
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#=============================================================================
+
+cmake_minimum_required(VERSION 3.22.1 FATAL_ERROR)
+
+if(CMAKE_VERSION VERSION_GREATER_EQUAL 3.13)
+  cmake_policy(SET CMP0077 NEW)
+  set(CMAKE_POLICY_DEFAULT_CMP0077 NEW)
+endif()
+
+if(CMAKE_VERSION VERSION_GREATER_EQUAL 3.16)
+  cmake_policy(SET CMP0096 NEW)
+  set(CMAKE_POLICY_DEFAULT_CMP0096 NEW)
+endif()
+
+if(CMAKE_VERSION VERSION_GREATER_EQUAL 3.21)
+  cmake_policy(SET CMP0126 NEW)
+  set(CMAKE_POLICY_DEFAULT_CMP0126 NEW)
+endif()
+
+##############################################################################
+# - Download and initialize RAPIDS CMake helpers -----------------------------
+
+if(NOT EXISTS ${CMAKE_BINARY_DIR}/RAPIDS.cmake)
+  file(DOWNLOAD https://raw.githubusercontent.com/rapidsai/rapids-cmake/branch-22.08/RAPIDS.cmake
+       ${CMAKE_BINARY_DIR}/RAPIDS.cmake)
+endif()
+include(${CMAKE_BINARY_DIR}/RAPIDS.cmake)
+include(rapids-cmake)
+include(rapids-cpm)
+include(rapids-cuda)
+include(rapids-export)
+include(rapids-find)
+
+set(legate_core_version 22.07.00)
+
+# For now we want the optimization flags to match on both normal make and cmake
+# builds so we override the cmake defaults here for release, this changes
+# -O3 to -O2 and removes -DNDEBUG
+set(CMAKE_CXX_FLAGS_RELEASE "-O2")
+set(CMAKE_CUDA_FLAGS_RELEASE "-O2")
+set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-O2 -g")
+set(CMAKE_CUDA_FLAGS_RELWITHDEBINFO "-O2 -g")
+
+if(NOT SKBUILD)
+  project(legate_core VERSION ${legate_core_version} LANGUAGES C CXX)
+  include(${CMAKE_CURRENT_SOURCE_DIR}/legate_core_cpp.cmake)
+else()
+  project(
+    legate_core_python
+    VERSION ${legate_core_version}
+    LANGUAGES # TODO: Building Python extension modules via the python_extension_module requires the C
+              # language to be enabled here. The test project that is built in scikit-build to verify
+              # various linking options for the python library is hardcoded to build with C, so until
+              # that is fixed we need to keep C.
+              C CXX)
+  include(${CMAKE_CURRENT_SOURCE_DIR}/legate_core_python.cmake)
+endif()

MANIFEST.in

@@ -0,0 +1,2 @@
+include versioneer.py
+include legate/_version.py

bind.sh

@@ -104,4 +104,4 @@ if [[ -n "${NICS+x}" ]]; then
             ;;
     esac
 fi
-numactl "$@"
+exec numactl "$@"

cmake/Modules/cpm_helpers.cmake

@@ -0,0 +1,53 @@
+#=============================================================================
+# Copyright 2022 NVIDIA Corporation
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#=============================================================================
+
+function(get_cpm_git_args _out_var)
+
+  set(oneValueArgs TAG BRANCH REPOSITORY)
+  cmake_parse_arguments(GIT "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  set(repo_tag "")
+  set(gh_tag_prefix "")
+  # Default to specifying `GIT_REPOSITORY` and `GIT_TAG`
+  set(cpm_git_args GIT_REPOSITORY ${GIT_REPOSITORY})
+
+  if(GIT_BRANCH)
+    set(gh_tag_prefix "heads")
+    set(repo_tag "${GIT_BRANCH}")
+    list(APPEND cpm_git_args GIT_TAG ${GIT_BRANCH})
+  elseif(GIT_TAG)
+    set(gh_tag_prefix "tags")
+    set(repo_tag "${GIT_TAG}")
+    list(APPEND cpm_git_args GIT_TAG ${GIT_TAG})
+  endif()
+
+  # Remove `.git` suffix from repo URL
+  if(GIT_REPOSITORY MATCHES "^(.*)(\.git)$")
+    set(GIT_REPOSITORY "${CMAKE_MATCH_1}")
+  endif()
+  if(GIT_REPOSITORY MATCHES "github\.com")
+    # If retrieving from github use `.zip` URL to download faster
+    set(cpm_git_args URL "${GIT_REPOSITORY}/archive/refs/${gh_tag_prefix}/${repo_tag}.zip")
+  elseif(GIT_REPOSITORY MATCHES "gitlab\.com")
+    # GitLab archive URIs replace slashes with dashes
+    string(REPLACE "/" "-" archive_tag "${repo_tag}")
+    # If retrieving from gitlab use `.zip` URL to download faster
+    set(cpm_git_args URL "${GIT_REPOSITORY}/-/archive/${repo_tag}/legion-${archive_tag}.zip")
+  endif()
+
+  set(${_out_var} ${cpm_git_args} PARENT_SCOPE)
+
+endfunction()

cmake/Modules/cuda_arch_helpers.cmake

@@ -0,0 +1,88 @@
+#=============================================================================
+# Copyright 2022 NVIDIA Corporation
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#=============================================================================
+
+function(set_cuda_arch_from_names)
+  set(cuda_archs "")
+  # translate legacy arch names into numbers
+  if(CMAKE_CUDA_ARCHITECTURES MATCHES "fermi")
+    list(APPEND cuda_archs 20)
+  endif()
+  if(CMAKE_CUDA_ARCHITECTURES MATCHES "kepler")
+    list(APPEND cuda_archs 30)
+  endif()
+  if(CMAKE_CUDA_ARCHITECTURES MATCHES "k20")
+    list(APPEND cuda_archs 35)
+  endif()
+  if(CMAKE_CUDA_ARCHITECTURES MATCHES "k80")
+    list(APPEND cuda_archs 37)
+  endif()
+  if(CMAKE_CUDA_ARCHITECTURES MATCHES "maxwell")
+    list(APPEND cuda_archs 52)
+  endif()
+  if(CMAKE_CUDA_ARCHITECTURES MATCHES "pascal")
+    list(APPEND cuda_archs 60)
+  endif()
+  if(CMAKE_CUDA_ARCHITECTURES MATCHES "volta")
+    list(APPEND cuda_archs 70)
+  endif()
+  if(CMAKE_CUDA_ARCHITECTURES MATCHES "turing")
+    list(APPEND cuda_archs 75)
+  endif()
+  if(CMAKE_CUDA_ARCHITECTURES MATCHES "ampere")
+    list(APPEND cuda_archs 80)
+  endif()
+
+  if(cuda_archs)
+    list(LENGTH cuda_archs num_archs)
+    if(num_archs GREATER 1)
+      # A CMake architecture list entry of "80" means to build both compute and sm.
+      # What we want is for the newest arch only to build that way, while the rest
+      # build only for sm.
+      list(POP_BACK cuda_archs latest_arch)
+      list(TRANSFORM cuda_archs APPEND "-real")
+      list(APPEND cuda_archs ${latest_arch})
+    else()
+      list(TRANSFORM cuda_archs APPEND "-real")
+    endif()
+    set(CMAKE_CUDA_ARCHITECTURES ${cuda_archs} PARENT_SCOPE)
+  endif()
+endfunction()
+
+function(add_cuda_architecture_defines defs)
+  message(VERBOSE "legate.core: CMAKE_CUDA_ARCHITECTURES=${CMAKE_CUDA_ARCHITECTURES}")
+
+  set(_defs ${${defs}})
+
+  macro(add_def_if_arch_enabled arch def)
+    if("${arch}" IN_LIST CMAKE_CUDA_ARCHITECTURES OR
+      ("${arch}-real" IN_LIST CMAKE_CUDA_ARCHITECTURES) OR
+      ("${arch}-virtual" IN_LIST CMAKE_CUDA_ARCHITECTURES))
+      list(APPEND _defs ${def})
+    endif()
+  endmacro()
+
+  add_def_if_arch_enabled("20" "FERMI_ARCH")
+  add_def_if_arch_enabled("30" "KEPLER_ARCH")
+  add_def_if_arch_enabled("35" "K20_ARCH")
+  add_def_if_arch_enabled("37" "K80_ARCH")
+  add_def_if_arch_enabled("52" "MAXWELL_ARCH")
+  add_def_if_arch_enabled("60" "PASCAL_ARCH")
+  add_def_if_arch_enabled("70" "VOLTA_ARCH")
+  add_def_if_arch_enabled("75" "TURING_ARCH")
+  add_def_if_arch_enabled("80" "AMPERE_ARCH")
+
+  set(${defs} ${_defs} PARENT_SCOPE)
+endfunction()

cmake/Modules/legate_core_options.cmake

@@ -0,0 +1,121 @@
+#=============================================================================
+# Copyright 2022 NVIDIA Corporation
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#=============================================================================
+
+option(BUILD_SHARED_LIBS "Build legate.core shared libraries" ON)
+
+function(set_or_default var_name var_env)
+  list(LENGTH ARGN num_extra_args)
+  if(num_extra_args GREATER 0)
+    list(GET ARGN 0 var_default)
+  endif()
+  if(DEFINED ${var_name})
+    message(VERBOSE "legate.core: ${var_name}=${${var_name}}")
+  elseif(DEFINED ENV{${var_env}})
+    set(${var_name} $ENV{${var_env}} PARENT_SCOPE)
+    message(VERBOSE "legate.core: ${var_name}=$ENV{${var_env}} (from envvar '${var_env}')")
+  elseif(DEFINED var_default)
+    set(${var_name} ${var_default} PARENT_SCOPE)
+    message(VERBOSE "legate.core: ${var_name}=${var_default} (from default value)")
+  else()
+    message(VERBOSE "legate.core: not setting ${var_name}")
+  endif()
+endfunction()
+
+# Initialize these vars from the CLI, then fallback to an envvar or a default value.
+set_or_default(Legion_SPY USE_SPY OFF)
+set_or_default(Legion_USE_LLVM USE_LLVM OFF)
+set_or_default(Legion_USE_CUDA USE_CUDA OFF)
+set_or_default(Legion_USE_HDF5 USE_HDF OFF)
+set_or_default(Legion_USE_GASNet USE_GASNET OFF)
+set_or_default(Legion_USE_OpenMP USE_OPENMP OFF)
+set_or_default(Legion_BOUNDS_CHECKS CHECK_BOUNDS OFF)
+
+option(Legion_SPY "Enable detailed logging for Legion Spy" OFF)
+option(Legion_USE_LLVM "Use LLVM JIT operations" OFF)
+option(Legion_USE_HDF5 "Enable support for HDF5" OFF)
+option(Legion_USE_CUDA "Enable Legion support for the CUDA runtime" OFF)
+option(Legion_USE_GASNet "Enable the distributed GASNet backend" OFF)
+option(Legion_USE_OpenMP "Use OpenMP" OFF)
+option(Legion_USE_Python "Use Python" OFF)
+option(Legion_BOUNDS_CHECKS "Enable bounds checking in Legion accessors" OFF)
+
+if(Legion_USE_GASNet)
+  set_or_default(GASNet_ROOT_DIR GASNET)
+  set_or_default(GASNet_CONDUIT CONDUIT "udp")
+
+  if(Legion_USE_GASNet AND (NOT GASNet_ROOT_DIR))
+    option(Legion_EMBED_GASNet "Embed a custom GASNet build into Legion" ON)
+  endif()
+endif()
+
+set_or_default(Legion_MAX_DIM LEGION_MAX_DIM 4)
+
+# Check the max dimensions
+if((Legion_MAX_DIM LESS 1) OR (Legion_MAX_DIM GREATER 9))
+  message(FATAL_ERROR "The maximum number of Legate dimensions must be between 1 and 9 inclusive")
+endif()
+
+set_or_default(Legion_MAX_FIELDS LEGION_MAX_FIELDS 256)
+
+# Check that max fields is between 32 and 4096 and is a power of 2
+if(NOT Legion_MAX_FIELDS MATCHES "^(32|64|128|256|512|1024|2048|4096)$")
+  message(FATAL_ERROR "The maximum number of Legate fields must be a power of 2 between 32 and 4096 inclusive")
+endif()
+
+
+option(legate_core_STATIC_CUDA_RUNTIME "Statically link the cuda runtime library" OFF)
+option(legate_core_EXCLUDE_LEGION_FROM_ALL "Exclude Legion targets from legate.core's 'all' target" OFF)
+
+set_or_default(NCCL_DIR NCCL_PATH)
+set_or_default(Thrust_DIR THRUST_PATH)
+set_or_default(CUDA_TOOLKIT_ROOT_DIR CUDA)
+set_or_default(CMAKE_CUDA_ARCHITECTURES GPU_ARCH NATIVE)
+set_or_default(Legion_HIJACK_CUDART USE_CUDART_HIJACK OFF)
+
+include(CMakeDependentOption)
+cmake_dependent_option(Legion_HIJACK_CUDART
+  "Allow Legion to hijack and rewrite application calls into the CUDA runtime"
+  ON
+  "Legion_USE_CUDA;Legion_HIJACK_CUDART"
+  OFF)
+# This needs to be added as an option to force values to be visible in Legion build
+option(Legion_HIJACK_CUDART "Replace default CUDA runtime with the Realm version" OFF)
+
+if(Legion_HIJACK_CUDART)
+  message(WARNING [=[
+#####################################################################
+Warning: Realm's CUDA runtime hijack is incompatible with NCCL.
+Please note that your code will crash catastrophically as soon as it
+calls into NCCL either directly or through some other Legate library.
+#####################################################################
+]=])
+endif()
+
+if(BUILD_SHARED_LIBS)
+  if(Legion_HIJACK_CUDART)
+    # Statically link CUDA if HIJACK_CUDART is set
+    set(Legion_CUDA_DYNAMIC_LOAD OFF)
+    set(CUDA_USE_STATIC_CUDA_RUNTIME ON)
+  elseif(NOT DEFINED Legion_CUDA_DYNAMIC_LOAD)
+    # If HIJACK_CUDART isn't set and BUILD_SHARED_LIBS is true, default Legion_CUDA_DYNAMIC_LOAD to true
+    set(Legion_CUDA_DYNAMIC_LOAD ON)
+    set(CUDA_USE_STATIC_CUDA_RUNTIME OFF)
+  endif()
+elseif(NOT DEFINED Legion_CUDA_DYNAMIC_LOAD)
+  # If BUILD_SHARED_LIBS is false, default Legion_CUDA_DYNAMIC_LOAD to false also
+  set(Legion_CUDA_DYNAMIC_LOAD OFF)
+  set(CUDA_USE_STATIC_CUDA_RUNTIME ON)
+endif()