Globbing object keys in rego

[aflmp]

Hi there,

I'm trying to glob match keys in an object, can someone help spot the mistake.
playground link

data.json

{
     "sources": {
        "/resource/type/one": {
            "id_1": ["something-one"]
        },
        "/resource/type/two": {
            "id_1": ["something-one"],
            "id_2": ["something-two"]
        },
        "/resource/type/*/three": {
            "id_1": ["something-one"]
        }
    }   
}

first.rego

package play

default match = false
default id_match = false

match {
    id_match
}

# exact matching source names
source = s {
	s = data.sources[input.source]
}

# glob matching source names
source = s {
	glob.match(data.sources[_], ["/"], input.source)
	s = data.sources[_]
}

id_match {
    source[input.id_type][_] = input.id_value
}

for a sample input

{
    "source": "/resource/type/123456/third",
    "id_type": "id_1",
    "id_value": "something-one"
}

I'm expecting the output to be

{
    "id_match": true,
    "match": true,
    "source": {
        "id_1": [
            "something-one"
        ]
    }
}

instead, I'm getting

{
    "id_match": false,
    "match": false
}

any suggestions?

[anderseknert]

Hi Alam 👋 When iterating over the data.sources, you'd want to pass the key rather than the value (as that is an object) to the glob.match function. This should do it:

source = s {
	s := data.sources[k]
	glob.match(k, ["/"], input.source)	
}

[aflmp]

ah, maybe the playground link was outdated, this is the updated link

for below input

{
    "source": "/resource/type/123456/three",
    "id_type": "id_1",
    "id_value": "something-one"
}

I'm trying to glob match the keys in data.sources, specifically "resource/type/*/three"
once this matches and source get a value

{
     "id_1": ["something-one"]
}

id_match should just work with

id_match {
    source[input.id_type][_] = input.id_value
}

the challenge is to get the right source using

# glob matching source names
source = s {
	glob.match(data.sources[k], ["/"], input.source)
	s = data.sources[k]      # I don't have access to k, i need the rule to figure out based on glob.match success
}

I'm expecting ^ rule block to return the source

{
     "id_1": ["something-one"]
}

based on linearly running glob on all keys - "/resource/type/one", "/resource/type/two, and "/resource/type/*/three"; and glob.match should return true only for "/resource/type/*/three" return the source

[anderseknert]

I still feel like I'm missing something here 😅 Would this not produce the outcome you expect?

source = s {
	some k
        data.sources[k]
	glob.match(k, ["/"], input.source)
	s = data.sources[k]
}

[aflmp]

thanks Anders for looking at this, let me try one more time with a simple example - playground link

package play

default glob_match_key = false
default match = false

glob_match_key {
    some k
    glob.match(data.sources[k], ["/"], input.source)
    data.sources[k].id == input.id
}

match{
    glob.match("/resources/type/*/one", ["/"], input.source)
}

with data as

{
    "sources" : {
        "/resources/type/*/one": {
    		"id": "one"
    	}
    }
}

and input as

{
    "source": "/resources/type/12345678/one",
    "id": "one"
}

results in

{
    "glob_match_key": false,
    "match": true
}

and I'm expecting glob_match_key to be true.
I need the object key "/resources/type/*/one" in rego var k.
I think k is evaluating to { "id": "one"}, but I'm looking for "/resources/type/*/one", does that make sense?

[anderseknert]

Yes, but that's what we did in my example! 😄 The problem with this line:

glob.match(data.sources[k], ["/"], input.source)

Is that data.sources[k] will return the iterated values of data.sources and those are objects, not strings. You'll want to use the keys for this, which is what we did by moving the iteration out of the call an saving the value of k:

glob_match_key {
    some k
    data.sources[k]                    # iterate over all keys, i.e. "/resources/type/*/one" and so on
    glob.match(k, ["/"], input.source) # match key k against input.source
    data.sources[k].id == input.id
}

[aflmp]

oops, my bad. I misread glob.match(k, ["/"], input.source) as glob.match(data.sources[k], ["/"], input.source)
Thank you for the answer!