My macro setup

[gimmemabrewski]

Just sharing a zsh script I made and the lua script section to define my macro setup. I haven't tested this all that much (and I'm but a simple carpenter and mechanic, not a programmer 😆 ) so I can't guarantee it'll work for everyone but I don't see why not. You need to be using X11 to make use of this because it uses xclip. I imagine it wouldn't be too hard to add or switch the script to using wl-clipboard for wayland (I might mess around with it later). I plan to add a selection menu to maybe use as one of my macros also in the future so theres some commented parts. I tried to leave out any unfinished parts from the help section. Hopefully I didn't miss anything. Maybe one day I'll set up my profile on github and share all my scripts but I'm too lazy right now. Anyways, I hope someone finds this useful!

The first file is the main script. To use it:

• Copy and paste it into your editor
• Save it as 'text-macros'
• Open the terminal in the saved directory
• Make it executable with chmod +x saved-script
• Run text-macros --help for help context
• Run text-macros /INSTALL to create these files
  • '$HOME/.local/bin/text-macros'
  • '/usr/bin/eruption-text-macros'

The second file needs sudo privileges. I'M NOT RESPONSIBLE FOR ANY PROBLEMS THAT MAY ARISE! That seems to be the standard disclaimer lol. Although I believe it's perfectly safe 😝 , I would suggest looking the script over before running it. Below this is the section that gets edited into the copied user-macros.lua

To edit what each macro does, you'll edit '/usr/bin/eruption-text-macros'.

#!/bin/zsh
#
# Further scripting or app specific keyboard shortcuts may be needed to make more use of this script
#
# colorpicker variables
# R=${${(s: :)cp[1]}[2]} G=${${(s: :)cp[2]}[2]} B=${${(s: :)cp[3]}[2]} HEX=${${(s: :)cp[1]}[-1]}
#
# Text Macros
#
#   Created for use with keyboard macro shortcuts. Quote or add ansi escapes to clipboard text. Useful
#       for making scripts with a lot of output. Simply cut the text with ctrl+x, run script, and paste
#       text back in place. Not all options require a selection. Thanks to X3n0m0rph59 over at github,
#       I was inspired to make this to use with his eruption driver for Roccat keyboards. You can find
#       his work here:
#                   https://github.com/X3n0m0rph59/eruption
#
#   This uses colorpicker to get color escape code sequences or hex codes. Credit goes to Jack12816 at
#       github for making this app, which can be found here:
#                   https://github.com/Jack12816/colorpicker
#
#   Requires xclip and kdialog for the select option (select option not completed yet). As of now, this
#       will only work with the X11 desktop. I'll likely add support for wayland using wl-clipboard but
#       I have not messed with it and I use X11 so it is not a priority for me at the moment :P. This
#       started off as a simple script for a few macros but, as usual, I went overboard with it. Hope
#       you find it useful!
#
# USAGE:
#   text-macros [option] [sub-option(s)]
#
# OPTIONS:
#
#   [/INSTALL]                 Install script
#
#   [-h|--help]                This help message
#   [-c|--color]               Use colorpicker to create a color code. Does NOT return selected text
#                                unless the ^--wrap^ option is used
#       [-b|--bg]              Select background color
#       [-bf|--bgfg]           Select background color, then foreground color
#       [-c|--common]          Use a common color
#                               Options:
#                                 [blue],[cyan],[gray],[dark-gray]
#                                 [green],[purple],[red],[white],[yellow]
#
#       [-h|--hex]             Output the chosen color as a HEX value (will NOT return clipboard text)
#       [-f|--fg]              Select foreground color (defaults to this when no sub-option is given)
#       [-fb|--fgfb]           Select foreground color, then background color
#       [-g|--group-off]       Add escapes to each individual line (default groups)
#       [-w|--wrap]            Adds "'033[0m'" (reset) to end of line or selection
##
##   [-s|--select]             Select option from a pop-up dialog
##
##   [--typeset]               Edit text to be used as a vaariable assignment
##       [-a|--array]          Convert selected text into an array
##       [-s|--strong]         Use strong quoting (block cmd/var expansion) default allows expansion
##       [-A|--associative]    Create associative array from a selection of scalar assignments
##       [-r|--readable]       Keep values on seperate lines (default bundles the array into one line)
#
#   [-w|--wrap]                Text wrapping options
#       [-C|--command]         Wraps text with ^$(^ ^)^
#       [-c|--curly-brace]     Wraps text with ^{^ ^}^
#       [-g|--group]           Wrap all selected text as one group (defaults to individual lines)
#       [-m|--math]            Wraps text with ^$((^ ^))^
#       [-p|--parenthesis]     Wraps text with ^(^ ^)^
#       [-pp|--double-paranth] Wraps text with ^((^ ^))^
#       [-q|--quote]           Quotes text, allowing cmd/var expansion
#       [-qq|--quote-strong]   Quotes text, blocking cmd/var expansion
#       [-s|--square]          Wraps text with ^[^ ^]^
#       [-ss|--double-square]  Wraps text with ^[[^ ^]]^
#       [-v|--variable]        Wraps text with ^${^ ^}^
#
# END_OPTIONS
# set -x

#  Check for xclip
if [[ -z $(command -p -v 'xclip') ]]; then
    case $SHLVL in
    1) notify-send -a "Text Macro" "Error: 'xclip' is missing" ;;
    *) printf '\n%b\n\n' "\033[0;31m    [ERROR]  xclip is missing\033[0m" ;;
    esac
    exit 2
fi

# variables
cp=() opts=() col_wrap=()
R='' G='' B='' HEX='' quit='' insert='' esc_code='' output_text='' group=0 newlines=0 wrap=0
input_text=("${(@f)$(xclip -o -selection 'clipboard')}") script="$0"

select-color () {
    cp=("${(s:,:)$(colorpicker --one-shot)}") &>/dev/null
    R=${${(s: :)cp[1]}[2]} G=${${(s: :)cp[2]}[2]} B=${${(s: :)cp[3]}[2]} HEX=${${(s: :)cp[3]}[-1]}
}
err () {
    local msg
    case $1 in
    arg) msg="Syntax Error: '$2' not a valid option" ;;
    miss) msg="Error: missing parameter" ;;
    color) msg="Error: no color selected" ;;
    esac
    case $SHLVL in
    1) notify-send -a "Text Macro" -t 3000 "$msg" ;;
    *) printf '\n%b\n\n' "\033[0;31m    $msg" ;;
    esac
}
_exit () {
    printf '%s' "$output_text" | xclip -i -selection 'clipboard'
    if [[ -n $ERUPTION_MACRO ]]; then notify-send -t 5000 -a "Text Macro" "Ran by 'Eruption'"
        else notify-send -t 5000 -a "Text Macro" "Ran by '$USER'"
    fi
    exit
}
# select-opt () {                   # add select menu
#
# }
help-msg () {
    local i H='' cnt=0
    for i in "${(@f)$(<$script)}"; do
        if [[ $i == "# END_OPTIONS"* ]]; then break
        elif [[ $i == "# R="* ]]; then H=1; continue
        elif [[ -n $H ]]; then
            if [[ $i == ('# Text Macros'*|'# USAGE:'*|'# OPTIONS:'*) ]]; then printf '%b\n' "${(Q)${i/\# /'\033[1;37;4m'}}\033[0m"
            elif [[ ${"${(@f)$(<$script)}"[$cnt]} == '# USAGE'* ]]; then printf '%b\n' "${(Q)${i/\#/'\033[0;35m'}/s \[/'s\033[0;37;3m ['}\033[0m"
            elif [[ $i == *'http'* ]]; then printf '%b\n' "\033[0;36m${i/\#/}\033[0m"
            elif [[ $i == *'blue'* ]]; then printf '%b\n' "${(Q)${${${i/blue/'\033[0;34mblue\033[0m'}/cyan/'\033[0;36mcyan\033[0m'}/dark-gray/'\033[1;30mdark-gray\033[0m'}/\#/}"
            elif [[ $i == *'green'* ]]; then
                printf '%b\n' "${(Q)${${${${${i/green/'\033[0;32mgreen\033[0m'}/purple/'\033[0;35mpurple\033[0m'}/red/'\033[0;31mred\033[0m'}/white/'\033[1;37mwhite\033[0m'}/yellow/'\033[1;33myellow\033[0m'}/\#/}"
            else c=1 line=$i
                until [[ $line != *'^'* ]]; do if [[ $((c%2)) -eq 0 ]]; then line="${${line/$/~}/\^/'\033[0m]\033[1;30;3m'}"
                    else line="${${line/$/~}/\^/'\033[0m[\033[1;33m'}"
                fi; ((c++)); done
                case $i in
                '#   ['*|'#       ['*) printf '%b\n' "${${(Q)${${${line/\#/}/\[/'\033[1;37m[\033[1;33m'}/\|/'\033[1;37m|\033[1;33m'}/\]/'\033[1;37m]\033[1;30;3m'}/\~/$}\033[0m" ;;
                '# '*) printf '%b\n' "\033[1;30;3m${${(Q)line/\#/}/\~/$}\033[0m" ;;
                '##'*) ;;
                *) printf '%b\n' "${${(Q)line/\#/ }/\~/$}" ;;
                esac
    fi; fi; ((cnt++)); done
}

case $1 in
/INSTALL)                      # INSTALL
    trap 'rm -f /tmp/eruption-macro'EXIT
    TRAPINT () { printf '\n%b\n\n' "\033[0;31m    Installation cancelled by user\033[0m"; exit }
    TRAPERR () { printf '\n%b\n\n' "\033[0;31m    Installation failed for unknown reason\033[0m"; exit }
        binfile=('#!/bin/bash' "USER=$USER" "USER_ID=$UID" "DISPLAY=$DISPLAY" "HOME=$HOME" "ERUPTION_MACRO=1" "DBUS_SESSION_BUS_ADDRESS=\"$DBUS_SESSION_BUS_ADDRESS\"" "export HOME ERUPTION_MACRO USER USER_ID DISPLAY DBUS_SESSION_BUS_ADDRESS" 'case $1 in' "1) cmd=\"$HOME/.local/bin/text-macros --wrap -n -q\" ;;" "2) cmd=\"$HOME/.local/bin/text-macros --wrap -n -qq\" ;;" "3) cmd=\"$HOME/.local/bin/text-macros --color -g -w -f\" ;;" "4) cmd=\"$HOME/.local/bin/text-macros --wrap -v\" ;;" "5) cmd=\"$HOME/.local/bin/text-macros --wrap -c\" ;;" "6) cmd=\"$HOME/.local/bin/text-macros --color -g -fb\" ;;" "*) ;;" "esac" 'eval "exec $cmd"')
    printf '%b\n' ' ' "\033[1;37m  This creates files:\033[0;36m" "    $HOME/.local/bin/text-macros" "    /usr/bin/eruption-text-macros"
    printf '%b\n' ' ' "\033[1;30;3m      The second file requires sudo privileges to create" "        Hit 'ctrl+c' to cancel, 'enter' to continue..." '\033[0m'
    read -s; mkdir -p $HOME/.local/bin
    printf '%s\n' $binfile > /tmp/eruption-text-macros
    sudo cp -f /tmp/eruption-text-macros /usr/bin/eruption-text-macros
    sudo chmod 755 /usr/bin/eruption-text-macros
    if [[ $0 != $HOME/.local/bin/text-macros ]]; then
        cp "$0" -f $HOME/.local/bin/text-macros
        chmod +x $HOME/.local/bin/text-macros
    fi
    printf '%b\n' "\033[1;37m  Restarting eruption daemon...\033[0m"
    sudo systemctl restart eruption.service
    sleep 3
    printf '%b\n' ' ' "\033[1;37m    Install complete\033[0m" ' '
    exit
    ;;
-c|--color) shift; group=1; opts=()
    for i in $@; do if [[ $i == ('-g'|'--nogroup') ]]; then group=0
        elif [[ $i == ('-n'|'--newlines') ]]; then newlines=1
        elif [[ $i == ('-w'|'--wrap') ]]; then wrap=1
        else opts=($opts "$i")
    fi; done
    if [[ $newlines -eq 1 ]]; then group=0; fi
    case $opts[1] in
    -b|--bg) mode='bg' ;;
    -bf|--bgfg) mode='bgfg' ;;
    -fb|--fgbg) mode='fgbg' ;;
    -f|--fg|'') mode='fg' ;;
    -h|--hex) select-color; printf '%s' "$HEX" | xclip -i -selection 'clipboard'; exit ;;
    -c|--common) shift opts
        case $opts[1] in
        blue) esc_code='\033[0;34m' ;;              # Blue
        cyan) esc_code='\033[0;36m' ;;              # Cyan
        gray) esc_code='\033[0;37m' ;;              # Gray
        dark-gray) esc_code='\033[1;30m' ;;         # Gray (dark)
        green) esc_code='\033[0;32m' ;;             # Green
        purple) esc_code='\033[0;35m' ;;            # Purple
        red) esc_code='\033[0;31m' ;;               # Red
        white) esc_code='\033[1;37m' ;;             # White
        yellow) esc_code='\033[1;33m' ;;            # Yellow
        '') err color; exit 1 ;;
        *) err miss; exit 1 ;;
        esac
        ;;
    *) err arg "$opts[1]"; exit 1 ;;
    esac
    if [[ -z $esc_code ]]; then select-color; fi
    case $mode in
    fg) esc_code="\\033[38;2;$R;$G;${B}m" ;;                # foreground color
    bg) esc_code="\\033[48;2;$R;$G;${B}m" ;;                # background color
    fgbg) fg="$R;$G;${B}m"; select-color; bg="$R;$G;$B"     # foreground / background
        esc_code="\\033[48;2;$bg;$fg"
        ;;
    bgfg) bg="$R;$G;$B"; select-color; fg="$R;$G;${B}m"     # background / foreground
        esc_code="\\033[48;2;$bg;$fg"
        ;;
    '') if [[ -z $esc_code ]]; then err color; exit 1; fi ;;
    *) err arg "$mode"; exit 1 ;;
    esac
    if [[ $wrap -eq 1 ]]; then
        case $group in                                                  # group ON
        1) output_text="$esc_code$(for i in $input_text; printf '%s\n' "$i")\\033[0m" ;;
        0) case $newlines in                                                           # group OFF
            0) output_text="$(for i in $input_text; printf '%s\n' "$output_text$esc_code$i\\033[0m")" ;;
            1) output_text="$(for i in $input_text; printf '%s\n' "$output_text$esc_code$i\\033[0m \\")"    # add '\' for newline
                output_text="$output_text[1,-3]" ;;
            esac ;;
        esac
        else output_text="$esc_code"
    fi; _exit
    ;;
-h|--help) help-msg; exit ;;                # help
# -s|--select) select-opt; exit ;;                     # add select menu
-w|--wrap) shift
    if [[ -z $1 ]]; then err miss; exit 1; fi
    for i in $@; do if [[ $i == ('-g'|'--group') ]]; then group=1
        elif [[ $i == ('-n'|'--newlines') ]]; then newlines=1
        else opts=($opts "$i")
    fi; done
    case $opts[1] in
    -q|--quote) case $group in                                              # quote (allow command/variable expansion)
        0) case $newlines in
            0) output_text="$(for l in $input_text; printf '%s\n' "${${(qqq)l//\\$/$}//\!/\\\!}")"; _exit ;;
            1) output_text="$(for l in $input_text; printf '%s\n' "${${${(qqq)l}//\\$/$}//\!/\\\!} \\")"; output_text=${output_text[1,-3]}; _exit ;;
            esac ;;
        1) output_text="${${$(for l in $input_text; printf '%s ' "${(qqq)l}")//\\$/$}//\!/\\\!}"; _exit ;;
        esac
        ;;
    -qq|--quote-strong) case $group in                                # quote (block command/variable expansion)
        0) case $newlines in
            0) output_text="$(for l in $input_text; printf '%s\n' "${(qq)l}")"; _exit ;;
            1) output_text="$(for l in $input_text; printf '%s\n' "${(qq)l} \\")"; output_text=${output_text[1,-3]}; _exit ;;
            esac ;;
        1) output_text="$(for l in $input_text; printf '%s ' "${(qq)l}")"; _exit ;;
        esac
        ;;
    -C|--command) wrapL='$(' wrapR=')' ;;
    -c|--curly-brace) wrapL='{' wrapR='}' ;;
    -p|--parenthesis) wrapL='(' wrapR=')' ;;
    -pp|--double-paranthesis) wrapL='((' wrapR='))' ;;
    -m|--math) wrapL='$((' wrapR='))' ;;
    -s|--square) wrapL='[' wrapR=']' ;;
    -ss|--double-square) wrapL='[[' wrapR=']]' ;;
    -v|--variable) wrapL='${' wrapR='}' ;;
    '') err miss; exit 1 ;;
    *) err arg "$opts[1]"; exit 1 ;;
    esac
    if [[ $group -eq 1 ]]; then
        output_text="$wrapL$(printf '%s\n' $input_text)$wrapR"
    else
        output_text="$(for i in $input_text; printf '%s\n' "$wrapL$i$wrapR")"
    fi
    _exit ;;
*) err arg "$1" ;;
esac

Section to place in lua script found in '/usr/share/eruption/scripts/lib/macros'

Replace 'YOUR_USERNAME' with your actual username

function on_macro_key_down(index)
	info("UserMacros: Executing: Macro #" .. index + 1)

	-- NOTE:
	-- We filter by slots, if you want to enable macros on all slots equally,
	-- just remove the 'and get_current_slot() == 0' part in each if statement.

	if index == 0 then
		-- Quote selected text, allowing for variable/command expansion

		if MODIFIER_KEY ~= RIGHT_MENU then
			inject_key(MODIFIER_KEY_EV_CODE, false)  -- modifier key up
		end

		-- consume the original keystroke
		consume_key()

		-- place your code here --
		debug("Executing: 'quote macro newlines'")

		-- cut selected text
		inject_key_with_delay(29, true, 0)        -- left ctrl down
		inject_key_with_delay(45, true, 5)       -- 'x' down
		inject_key_with_delay(45, false, 10)     -- 'x' up
		inject_key_with_delay(29, false, 15)     -- left ctrl up

		-- run 'text-macros --wrap -n -q' (1)
		result = system("/usr/bin/sudo", {"-u", "YOUR_USERNAME", "/usr/bin/eruption-text-macros", "1"})
		if result ~= 0 then
			error("Command execution failed with result: " .. result)
		end

		-- paste selected text
		inject_key_with_delay(29, true, 200)        -- left ctrl down
		inject_key_with_delay(47, true, 225)       -- 'v' down
		inject_key_with_delay(47, false, 230)     -- 'v' up
		inject_key_with_delay(29, false, 235)     -- left ctrl up

	elseif index == 1 then
		-- Strong quote selected text, blocking variable/command expansion

		if MODIFIER_KEY ~= RIGHT_MENU then
			inject_key(MODIFIER_KEY_EV_CODE, false)  -- modifier key up
		end

		-- consume the original keystroke
		consume_key()

		-- place your code here --
		debug("Executing: 'strong quote macro'")

		-- cut selected text
		inject_key_with_delay(29, true, 0)        -- left ctrl down
		inject_key_with_delay(45, true, 5)       -- 'x' down
		inject_key_with_delay(45, false, 10)     -- 'x' up
		inject_key_with_delay(29, false, 15)     -- left ctrl up

		-- run 'text-macro --wrap -qq' (2)
		result = system("/usr/bin/sudo", {"-u", "YOUR_USERNAME", "/usr/bin/eruption-text-macros", "2"})
		if result ~= 0 then
			error("Command execution failed with result: " .. result)
		end

		-- paste selected text
		inject_key_with_delay(29, true, 200)        -- left ctrl down
		inject_key_with_delay(47, true, 225)       -- 'v' down
		inject_key_with_delay(47, false, 230)     -- 'v' up
		inject_key_with_delay(29, false, 235)     -- left ctrl up

	elseif index == 2 then
		-- Select foreground color and wrap text with ansi escape codes

		if MODIFIER_KEY ~= RIGHT_MENU then
			inject_key(MODIFIER_KEY_EV_CODE, false)  -- modifier key up
		end

		-- consume the original keystroke
		consume_key()

		-- place your code here --
		debug("Executing: 'color foreground wrap macro'")

		-- cut selected text
		inject_key_with_delay(29, true, 0)        -- left ctrl down
		inject_key_with_delay(45, true, 5)       -- 'x' down
		inject_key_with_delay(45, false, 10)     -- 'x' up
		inject_key_with_delay(29, false, 15)     -- left ctrl up

		-- run 'text-macro --color -g -w -f' (3)
		result = system("/usr/bin/sudo", {"-u", "YOUR_USERNAME", "/usr/bin/eruption-text-macros", "3"})
		if result ~= 0 then
			error("Command execution failed with result: " .. result)
		end

		-- paste selected text
		inject_key_with_delay(29, true, 200)        -- left ctrl down
		inject_key_with_delay(47, true, 225)       -- 'v' down
		inject_key_with_delay(47, false, 230)     -- 'v' up
		inject_key_with_delay(29, false, 235)     -- left ctrl up

	elseif index == 3 then
		-- Wrap selected text with '${' '}'

		if MODIFIER_KEY ~= RIGHT_MENU then
			inject_key(MODIFIER_KEY_EV_CODE, false)  -- modifier key up
		end

		-- consume the original keystroke
		consume_key()

		-- place your code here --
		debug("Executing: 'variable wrap macro'")

		-- cut selected text
		inject_key_with_delay(29, true, 0)        -- left ctrl down
		inject_key_with_delay(45, true, 5)       -- 'x' down
		inject_key_with_delay(45, false, 10)     -- 'x' up
		inject_key_with_delay(29, false, 15)     -- left ctrl up

		-- run 'text-macro --wrap -v' (4)
		result = system("/usr/bin/sudo", {"-u", "YOUR_USERNAME", "/usr/bin/eruption-text-macros", "4"})
		if result ~= 0 then
			error("Command execution failed with result: " .. result)
		end

		-- paste selected text
		inject_key_with_delay(29, true, 200)        -- left ctrl down
		inject_key_with_delay(47, true, 225)       -- 'v' down
		inject_key_with_delay(47, false, 230)     -- 'v' up
		inject_key_with_delay(29, false, 235)     -- left ctrl up

	elseif index == 4 then
		-- Wrap selected text with '$(' ')'

		if MODIFIER_KEY ~= RIGHT_MENU then
			inject_key(MODIFIER_KEY_EV_CODE, false)  -- modifier key up
		end

		-- consume the original keystroke
		consume_key()

		-- place your code here --
		debug("Executing: 'curly brace wrap macro'")

		-- cut selected text
		inject_key_with_delay(29, true, 0)        -- left ctrl down
		inject_key_with_delay(45, true, 5)       -- 'x' down
		inject_key_with_delay(45, false, 10)     -- 'x' up
		inject_key_with_delay(29, false, 15)     -- left ctrl up

		-- run 'text-macro --wrap -c' (5)
		result = system("/usr/bin/sudo", {"-u", "YOUR_USERNAME", "/usr/bin/eruption-text-macros", "5"})
		if result ~= 0 then
			error("Command execution failed with result: " .. result)
		end

		-- paste selected text
		inject_key_with_delay(29, true, 200)        -- left ctrl down
		inject_key_with_delay(47, true, 225)       -- 'v' down
		inject_key_with_delay(47, false, 230)     -- 'v' up
		inject_key_with_delay(29, false, 235)     -- left ctrl up

	elseif index == 5 then
		-- Select foreground then background color and wrap selection with ansi escape codes

		if MODIFIER_KEY ~= RIGHT_MENU then
			inject_key(MODIFIER_KEY_EV_CODE, false)  -- modifier key up
		end

		-- consume the original keystroke
		consume_key()

		-- place your code here --
		debug("Executing: 'foreground/background color macro'")

		-- cut selected text
		inject_key_with_delay(29, true, 0)        -- left ctrl down
		inject_key_with_delay(45, true, 5)       -- 'x' down
		inject_key_with_delay(45, false, 10)     -- 'x' up
		inject_key_with_delay(29, false, 15)     -- left ctrl up

		-- run 'text-macro --color -fgbg' (6)
		result = system("/usr/bin/sudo", {"-u", "YOUR_USERNAME", "/usr/bin/eruption-text-macros", "6"})
		if result ~= 0 then
			error("Command execution failed with result: " .. result)
		end

		-- paste selected text
		inject_key_with_delay(29, true, 200)        -- left ctrl down
		inject_key_with_delay(47, true, 225)       -- 'v' down
		inject_key_with_delay(47, false, 230)     -- 'v' up
		inject_key_with_delay(29, false, 235)     -- left ctrl up


	else
		-- no match, just consume the original keystroke and do nothing
		consume_key()
	end
end

Enjoy!