Add macro mt_out_of_order

Author: oschulz

Project.toml

@@ -4,6 +4,7 @@ version = "0.4.1"
 
 [deps]
 Distributed = "8ba89e20-285c-5b6f-9357-94700520ee1b"
+MacroTools = "1914dd2f-81c6-5fcd-8719-6d5c9610ff09"
 
 [compat]
 julia = "1"

src/ParallelProcessingTools.jl

@@ -7,6 +7,8 @@ module ParallelProcessingTools
 using Base.Threads
 using Distributed
 
+using MacroTools
+
 include("threadsafe.jl")
 include("threadlocal.jl")
 include("onthreads.jl")

src/onthreads.jl

@@ -223,3 +223,57 @@ macro mt_async(expr)
     end
 end
 export @mt_async
+
+
+using MacroTools
+"""
+    @mt_out_of_order begin expr... end
+
+Runs all top-level expressions in `begin expr... end` on parallel tasks.
+On Julia >= v1.3, the tasks will run multi-threaded.
+
+Example:
+
+```
+@mt_out_of_order begin
+    a = foo()
+    bar()
+    c = baz()
+end
+
+will run `a = foo()`, `bar()` and `c = baz()` in parallel and in arbitrary
+order, results of assignments will appear in the outside scope.
+"""
+macro mt_out_of_order(ex)
+    if !(ex isa Expr && ex.head == :block)
+        throw(ErrorException("@mt_out_of_order expects a code block as it's argument"))
+    end
+
+    exprs = ex.args
+    idxs = eachindex(ex.args)
+    tasks = gensym(:tasks)
+    handle_results = Vector{Expr}()
+    for i in idxs
+        trg = nothing; val = nothing;
+        if @capture(exprs[i], trg_ = val_)
+            if val isa Expr
+                exprs[i] = :(push!($tasks, @mt_async($(esc(val)))))
+                push!(handle_results, :($(esc(trg)) = fetch(popfirst!($tasks))))
+            else
+                exprs[i] = esc(exprs[i])
+            end
+        elseif exprs[i] isa Expr
+            ftvar = gensym()
+            exprs[i] = :(push!($tasks, @mt_async($(esc(exprs[i])))))
+            push!(handle_results, :(wait(popfirst!($tasks))))
+        else
+            exprs[i] = esc(exprs[i])
+        end
+    end
+    pushfirst!(exprs, :($tasks = Vector{Task}()))
+    append!(exprs, handle_results)
+    push!(exprs, :(@assert isempty($tasks)))
+    push!(exprs, :nothing)
+    ex
+end
+export @mt_out_of_order

test/test_onthreads.jl

@@ -49,6 +49,23 @@ using Base.Threads
         end
     end
 
+    @testset "macro mt_out_of_order" begin
+        @test begin
+            b = 0
+            foo() = b = 9
+            bar() = 33
+
+            @mt_out_of_order begin
+                a = (sleep(0.05); 42)
+                foo()
+                c::Int = bar()
+
+                d = :trivial
+            end
+            (a, b, c, d) == (42, 9, 33, :trivial)
+        end
+    end
+
     @testset "Examples" begin
         @testset "Example 1" begin
             tlsum = ThreadLocal(0.0)