build.gradle

/*
 * (c) Copyright 2018 Palantir Technologies Inc. All rights reserved.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

buildscript {
    repositories {
        gradlePluginPortal()
        mavenCentral()
    }

    dependencies {
        classpath 'com.palantir.gradle.externalpublish:gradle-external-publish-plugin:1.2.1'
        classpath 'com.palantir.javaformat:gradle-palantir-java-format:1.0.1'
        classpath 'com.palantir.baseline:gradle-baseline-java:2.49.2'
        classpath 'com.palantir.gradle.conjure:gradle-conjure:5.10.0'
        classpath 'com.palantir.gradle.gitversion:gradle-git-version:0.12.3'
    }
}

apply plugin: 'com.palantir.external-publish'
apply plugin: 'com.palantir.git-version'
apply plugin: 'com.palantir.baseline'
apply plugin: 'com.palantir.external-publish-custom'

allprojects {
    apply plugin: 'com.palantir.java-format'
    version gitVersion()
    group 'com.palantir.conjure.verification'

    repositories {
        mavenCentral()
    }

    apply plugin: 'java-library'
}

['server', 'client'].each { String variant ->
    task "${variant}DistTarLinux"(type: Tar) {
        from "target/release/conjure-verification-${variant}"
        baseName = "verification-${variant}-linux"
        compression = Compression.GZIP
    }

    task "${variant}DistTarOsx"(type: Tar) {
        from "target/x86_64-apple-darwin/release/conjure-verification-${variant}"
        baseName = "verification-${variant}-osx"
        compression = Compression.GZIP
    }

    externalPublishing {
        publication("${variant}DistTarLinux") {
            artifactId "verification-$variant"
            artifact (tasks["${variant}DistTarLinux"]) {
                classifier "linux"
            }
        }

        publication("${variant}DistTarOsx") {
            artifactId "verification-$variant"
            artifact (tasks["${variant}DistTarOsx"]) {
                classifier "osx"
            }
        }
    }
}