Local files support

[mitar]

Just to document here for others. I am using the following code for local files. It works "good enough", but probably one could do smarter things with settings _require and _response to some random values, just to be sure.

fs = require 'fs'

URL_BASE = '/srv/files/'

class LocalFilesXMLHttpRequest extends XMLHttpRequest
  _sendRelative: (data) ->
    fullUrl = url.resolve URL_BASE, @_url.href
    @_url = @_parseUrl fullUrl

    @_sendFile data

  _sendFile: (data) ->
    unless @_method is 'GET'
      throw new NetworkError "The file protocol only supports GET"

    if data? and (@_method is 'GET' or @_method is 'HEAD')
      console.warn "Discarding entity body for #{ @_method } requests"
      data = null
    else
      # Send Content-Length: 0
      data or= ''

    @upload._setData data
    @_finalizeHeaders()

    @_request = null
    @_dispatchProgress 'loadstart'

    if @_sync
      defer = (f) ->
        f()
    else
      defer = process.nextTick

    defer =>
      try
        data = fs.readFileSync @_url.pathname
      catch error
        # TODO: Should set status based on the error
        data = new Buffer "#{ error }"
        status = 404

      @_response = null
      @status = status
      @statusText = http.STATUS_CODES[@status]
      @_totalBytes = data.length
      @_lengthComputable = true

      @_setReadyState XMLHttpRequest.HEADERS_RECEIVED

      @_onHttpResponseData null, data
      @_onHttpResponseEnd null

[letmaik]

Desperately waiting for built-in file:// support as well.