build.gradle

plugins {
    id 'org.jetbrains.kotlin.jvm' version '1.8.10'
    id 'maven-publish'
    id 'signing'
    id 'io.codearte.nexus-staging' version '0.30.0'
}

group = 'io.github.ricardorlg'
version = '1.1.0'

ext {
    isReleasedVersion = !project.version.endsWith("-SNAPSHOT")
}

repositories {
    mavenCentral()
    maven {
        url = "https://oss.sonatype.org/content/repositories/snapshots"
    }
}

dependencies {
    implementation platform("software.amazon.awssdk:bom:$aws_version")
    implementation 'software.amazon.awssdk:devicefarm'
    implementation "io.arrow-kt:arrow-fx-coroutines:$arrow_version"
    implementation "org.jetbrains.kotlinx:kotlinx-coroutines-core:$kotlin_coroutines_version"
    implementation "io.github.microutils:kotlin-logging:$kotlin_logging_version"
    implementation "org.http4k:http4k-core:$http4k_version"
    implementation "com.jakewharton.picnic:picnic:$picnic_version"

    testImplementation "org.slf4j:slf4j-simple:$slf4j_version"
    testImplementation "io.mockk:mockk:$mockk_version"
    testImplementation "io.kotest:kotest-runner-junit5:$kotest_version"
    testImplementation "io.kotest:kotest-assertions-core:$kotest_version"
    testImplementation "io.kotest.extensions:kotest-assertions-arrow:$kotest_arrow_extension_version"
    testImplementation "io.kotest:kotest-extensions-htmlreporter:$kotest_version"
    testImplementation "io.kotest:kotest-property:$kotest_version"

}

java {
    withSourcesJar()
    withJavadocJar()
}

jar {
    manifest {
        attributes("Implementation-Title": "Device Farm Tractor",
                "Implementation-Version": project.version.toString())
    }
}

tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).configureEach {
    kotlinOptions {
        freeCompilerArgs += "-opt-in=kotlin.time.ExperimentalTime"
    }
}

test {
    testLogging.showStandardStreams = true
    useJUnitPlatform()
}

publishing {
    repositories {
        maven {
            name = "MavenCentral"
            credentials {
                username findProperty("ossrhUsername") ?: System.getenv("OSSRH_USERNAME")
                password findProperty("ossrhPassword") ?: System.getenv("OSSRH_PASSWORD")
            }

            if (!isReleasedVersion) {
                url "https://oss.sonatype.org/content/repositories/snapshots"
            } else {
                url "https://oss.sonatype.org/service/local/staging/deploy/maven2"
            }
        }

        maven {
            name = "GitHubPackages"
            url = uri("https://maven.pkg.github.com/ricardorlg/aws-device-farm-tractor")
            credentials {
                username = findProperty("GITHUB_ACTOR") ?: System.getenv("GITHUB_ACTOR")
                password = findProperty("GITHUB_TOKEN") ?: System.getenv("GITHUB_TOKEN")
            }
        }

    }
    publications {
        deviceFarmTractor(MavenPublication) {
            from(components.java)
            pom {
                name = "Device Farm Tractor"
                description = "Run Serenity BDD appium tests in AWS device farm"
                url = "https://github.com/ricardorlg/aws-device-farm-tractor"
                scm {
                    connection = "scm:git:git@github.com:ricardorlg/aws-device-farm-tractor.git"
                    developerConnection = "scm:git:ssh://github.com/ricardorlg/aws-device-farm-tractor.git"
                    url = "https://github.com/ricardorlg/aws-device-farm-tractor"
                }

                licenses {
                    license {
                        name = 'MIT License'
                        url = 'https://opensource.org/licenses/MIT'
                    }
                }

                developers {
                    developer {
                        id = 'ricardorlg'
                        name = 'Ricardo Larrahondo'
                        email = 'ricardolarrahondo2@hotmail.com'

                    }
                }

            }
        }
    }
}

signing {
    sign publishing.publications.deviceFarmTractor
}