build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    ext.android_plugin_version = '7.3.0'
    ext.kotlin_version = '1.7.10'
    ext.kotlinx_version = '1.6.0'
    repositories {
        flatDir dirs: "gradle/plugins"
        google()
        mavenCentral()
        mavenLocal()
   }
    dependencies {
        classpath "com.android.tools.build:gradle:$android_plugin_version"
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath 'com.github.dcendents:android-maven-gradle-plugin:2.1'
        classpath 'com.vanniktech:gradle-maven-publish-plugin:0.22.0'
    }
}

allprojects {
    repositories {
        google()
        mavenCentral()
        mavenLocal()
    }
    tasks.withType(Javadoc) {
        // Ignores errors from mavenAndroidJavadocs task
        // (reference: github.com/novoda/bintray-release/issues/71#issuecomment-164324255)
        options.addStringOption('Xdoclint:none', '-quiet')
        options.addStringOption('encoding', 'UTF-8')
    }
    tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).configureEach {
        kotlinOptions {
            jvmTarget = JavaVersion.VERSION_1_8.toString()
            freeCompilerArgs += ['-opt-in=kotlin.RequiresOptIn']
        }
    }
}

ext {
    appId = "org.videolan.vlc"
    versionCode = 3050310
    versionName = project.hasProperty('forceVlc4') && project.getProperty('forceVlc4') ? '4.0.0-preview - ' + versionCode : '3.5.4 Beta 1'
    vlcMajorVersion = project.hasProperty('forceVlc4') && project.getProperty('forceVlc4') ? 4 : 3
    libvlcVersion = vlcMajorVersion == 3 ? '3.6.0-eap2' :'4.0.0-eap5'
    medialibraryVersion = vlcMajorVersion == 3 ? '0.13.13-rc2' : '0.13.13-vlc4-rc2'
    minSdkVersion = 17
    targetSdkVersion = 33
    compileSdkVersion = 33
    buildToolsVersion = '33.0.1'
    androidxLegacyVersion = '1.0.0'
    androidxCoreVersion = '1.7.0'
    appCompatVersion = '1.4.1'
    lifecycleVersion = '2.5.1'
    androidxPreferencesVersion = '1.1.1'
    androidxVersion = '1.1.0'
    androidxActivityVersion = '1.6.0'
    androidxFragmentVersion = '1.5.3'
    androidxAnnotationVersion = '1.5.0'
    androidxRecyclerviewVersion = '1.2.1'
    androidxMediaVersion = '1.1.0'
    androidxLeanbackVersion = '1.0.0'
    androidxMaterialVersion = '1.7.0'
    constraintLayoutVersion = '2.1.4'
    viewPager2Version = "1.0.0"
    archVersion = '2.1.0'
    roomVersion = '2.4.3'
    pagingVersion = '3.1.1'
    junitVersion = '4.13.2'
    junitExtVersion = '1.1.2'
    mockito = '2.25.0'
    //Retrofit 2.7 drops Android 5 support
    retrofit = '2.7.1'
    moshi = '1.8.0'
    powerMock = '2.0.2'
    espressoVersion = '3.4.0'
    livedataTest = '1.2.0'
    robolectric = '4.3.1'
    mockk = '1.9.3'
    testRunner = '1.4.0'
    orchestrator = '1.1.0'
    testCore = '1.4.0'
//    versionCode scheme is T M NN RR AA
//    T: Target/Flavour (1 for Android, 2 for Chrome?)
//    M: Major version from 0 to 9
//    NN: Minor version from 00 to 99
//    RR: Micro/Revision version from 00 to 99
//    AA: ABI from 0 to 99
//    0 is dev
//    1 was ARMv5        (deprecated)
//    2 was ARMv6-nofpu  (deprecated)
//    3 was ARMv6-fpu    (deprecated)
//    4 is ARMv7-A
//    5 is x86
//    6 is MIPS
//    7 is ARMv8
//    8 is x86_64
//    9 is MIPS64
}