build.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.1.2'
        classpath 'com.github.dcendents:android-maven-gradle-plugin:1.3'
    }
}

allprojects {
    group = 'org.mapsforge'
    version = '0.6.0-SNAPSHOT'
    ext.isReleaseVersion = !version.endsWith("SNAPSHOT")

    ext.androidBuildVersionTools = "23.0.3"
    ext.gdxVersion = "1.9.3"

    // Disable Java 8 doclint
    if (JavaVersion.current().isJava8Compatible()) {
        tasks.withType(Javadoc) {
            options.addStringOption('Xdoclint:none', '-quiet')
            logging.captureStandardError LogLevel.INFO
        }
    }
}

def androidCompileSdk() { return 23 }

def androidMinSdk() { return 10 }

def androidTargetSdk() { return 22 }

def versionCode() { return 50 }

def versionName() { return version }

subprojects {
    repositories {
        maven { url 'https://repo.boundlessgeo.com/main' }
        jcenter()
    }

    tasks.withType(JavaCompile) {
        sourceCompatibility = JavaVersion.VERSION_1_7
        targetCompatibility = JavaVersion.VERSION_1_7
    }
}