build.gradle

plugins {
    id "java-library"
    id "maven-publish"
    id "com.jfrog.bintray" version "1.8.5"
}

group = "ai.serenade"
version = "1.1.1"

repositories {
    mavenLocal()
    mavenCentral()
}

task buildSharedObject {
    inputs.file "lib/ai_serenade_treesitter_Languages.cc"
    inputs.file "lib/ai_serenade_treesitter_Languages.h"
    inputs.file "lib/ai_serenade_treesitter_TreeSitter.cc"
    inputs.file "lib/ai_serenade_treesitter_TreeSitter.h"
    outputs.file "libjava-tree-sitter.so"

    doLast {
        exec {
            commandLine "./build.py", "libjava-tree-sitter", "src/test/tree-sitter-python"
        }
    }
}

clean {
    delete "libjava-tree-sitter.so"
}

compileJava {
    options.compilerArgs += ["-h", "${project.projectDir.toString()}/lib"]
}

compileTestJava {
    dependsOn buildSharedObject
}

dependencies {
    testImplementation "org.junit.jupiter:junit-jupiter:5.6.2"
}

publishing {
    publications {
        maven(MavenPublication) {
            from components.java
        }
    }
}

bintray {
    user = System.getenv("BINTRAY_USER")
    key = System.getenv("BINTRAY_KEY")
    publications = ['maven']
    pkg {
        repo = "maven"
        name = "java-tree-sitter"
        userOrg = "serenadeai"
        licenses = ["MIT"]
        vcsUrl = "https://github.com/serenadeai/java-tree-sitter"
        version {
            name = project.getVersion()
        }
    }
}

test {
    useJUnitPlatform()
    testLogging {
        events "passed", "skipped", "failed"
    }

    environment "JAVA_TREE_SITTER", "${project.projectDir.toString()}/libjava-tree-sitter.so"
}