Adding a flake.nix?

[firecat53]

Would you be open to a PR adding a flake.nix file and associated documentation edits? This would allow people using Nix or NixOS the ability to run either nix develop to install rendercv in a python venv and use the included TinyTex, or to run nix develop .#latex to install a full latex environment on their machine to use with the --use-local-latex-command flag?

Here is the file if you are curious:

{
  description = "RenderCV";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs";
  };

  outputs = {
    self,
    nixpkgs,
  }: let
    systems = ["x86_64-linux" "i686-linux" "aarch64-linux"];
    forAllSystems = f:
      nixpkgs.lib.genAttrs systems (system:
        f {
          pkgs = nixpkgs.legacyPackages.${system};
        });
    in {
      devShells = forAllSystems ({ pkgs }: let
        fhs = pkgs.buildFHSUserEnv {
          name = "rendercv-shell";
          targetPkgs = pkgs: [
            pkgs.python3
          ];
          profile = ''
            test -d .venv-fhs || \
              (python -m venv .venv-fhs && source .venv-fhs/bin/activate && pip install rendercv) && \
              source .venv-fhs/bin/activate
          '';
        };
        latex = pkgs.mkShell {
          packages =  [
            pkgs.python3
            pkgs.python3Packages.venvShellHook
            pkgs.texlive.combined.scheme-full
          ];
          venvDir = "./.venv";
          shellHook = ''
            venvShellHook
            export LD_LIBRARY_PATH="${pkgs.lib.makeLibraryPath [
              pkgs.stdenv.cc.cc.lib
            ]}:$LD_LIBRARY_PATH"
          '';
          postVenvCreation = ''
            pip install rendercv
          '';
        };
      in {
        default = fhs.env;
        latex = latex;
    });
  };
}

Thanks for a great project!

[sinaatalay]

Thank you! Honestly, I am ignorant about Nix, so I have no idea if this file should be included in the repository.

Do you think we should include it? If so, I have a few questions:

1. Is it primarily for developers to quickly set up the development environment?
2. Is it also for users too, so that they can both install LaTeX and RenderCV quickly with it?
3. Do you think it's good practice for Python packages to have the flake.nix file in their repositories? I am trying to understand if it's specifically good for RenderCV or in general.
4. Also, for a similar purpose, we have the .devcontainer folder that works with a Dockerimage so that a development environment for RenderCV can easily be created. Is flake.nix an alternative to that? Should we put the flake.nix file inside the root of the repository or in the .devcontainer folder?

[firecat53]

Caveat -- I'm no Nix expert! I mostly created the flake.nix because I run NixOS and running binary applications (like TinyTeX) needs some help to work out of the box because NixOS is so different. This flake allows people running Nix (standalone) or NixOS to use rendercv without needing to install anything else on their system. To you specific questions:

1. This flake is designed for users. I do use flakes in my own projects for creating a development environment and to build the package. We could do that as well, but it's not required.
2. Yes, this one is a user flake. Again, depending on how you call the flake, it will either drop you into a python virtualenv with rendercv installed or into a full Latex environment.
3. I like setting up a flake.nix generally for my own projects because it allows a consistent development experience across distributions without needing to install anything other than Nix on the host OS. In this case, I think it's a nice benefit for Nix users primarily because of the tweaks needed to get the TinyTeX binary running.
4. The flake.nix (and flake.lock) sit in the root directory. It's a completely different idea from the devcontainer.

Nix is a pretty addictive rabbit hole because you can really see the power in its declarative nature. Steeeep learning curve though, not gonna lie! I have several servers all happily running services using NixOS with a few podman services thrown in for specific applications that weren't already available in Nix Packages.

No pressure for adding the flake.nix! Happy to chat more about it.