build.gradle

apply plugin: 'java'
apply plugin: 'scala'
apply plugin: 'idea'
apply plugin: 'eclipse'

apply plugin: 'propdeps'
apply plugin: 'propdeps-maven'
apply plugin: 'propdeps-idea'
apply plugin: 'propdeps-eclipse'

group 'org.springframework.scala'
archivesBaseName = "spring-scala_2.11"

//set Java compiler -source and -target options
sourceCompatibility = '1.7'
targetCompatibility = '1.7'

ext {
  springVersion = '3.2.4.RELEASE'
  scalaVersion = '2.11.2'
  scalaLibVersion = '2.11'
}

repositories {
  maven { url "https://repo.springsource.org/libs-snapshot" }
}

dependencies {
  // Spring
  optional("org.springframework:spring-aop:$springVersion")
  compile("org.springframework:spring-core:$springVersion")
  compile("org.springframework:spring-beans:$springVersion")
  compile("org.springframework:spring-context:$springVersion")
  optional("org.springframework:spring-jdbc:$springVersion")
  optional("org.springframework:spring-jms:$springVersion")
  optional("org.springframework:spring-web:$springVersion")
  optional("org.springframework:spring-test:$springVersion")

  // Scala
  compile("org.scala-lang:scala-library:$scalaVersion")
  compile("org.scala-lang:scala-reflect:$scalaVersion")
  //needs to be as separate jar file for scala 2.11
  compile("org.scala-lang.modules:scala-xml_$scalaLibVersion:1.0.2")

  // Jackson
  optional("com.fasterxml.jackson.module:jackson-module-scala_$scalaLibVersion:2.4.2")

  // Java EE
  provided("org.apache.geronimo.specs:geronimo-jms_1.1_spec:1.1")
  provided("javax.servlet:servlet-api:2.5")
  provided("javax.inject:javax.inject:1")

  // Test
  testCompile("org.scalatest:scalatest_$scalaLibVersion:2.2.2")
  testCompile("junit:junit:4.10")
  testRuntime("org.hsqldb:hsqldb-j5:2.2.4")
  testRuntime("log4j:log4j:1.2.16")
  testCompile("org.springframework:spring-aspects:$springVersion")
}

//Java compiler settings
tasks.withType(JavaCompile) {
    //ignore conjunction warning
    options.compilerArgs << '-Xlint:-options'
}

tasks.withType(ScalaCompile) {
  scalaCompileOptions.additionalParameters = ["-feature", "-language:implicitConversions", "-language:reflectiveCalls"]
  scalaCompileOptions.useAnt = false
}

task wrapper(type: Wrapper) {
  description = 'Generates gradlew[.bat] scripts'
  gradleVersion = '1.12'
}

buildscript {
    repositories {
        maven { url 'https://repo.springsource.org/plugins-release' }
    }
    dependencies {
        classpath 'org.springframework.build.gradle:propdeps-plugin:0.0.7'
    }
}