Replace legacy struct providers with modern ones

Legacy struct providers have been deprecated by Bazel. Replacing them with modern providers, will make it possible to simplify and remove legacy handling from Bazel.

Author: comius

tensorboard/defs/internal/html.bzl

@@ -15,7 +15,7 @@
 """Rule for building the HTML binary."""
 
 load("@io_bazel_rules_closure//closure:defs.bzl", "closure_js_aspect")
-load("@io_bazel_rules_closure//closure/private:defs.bzl", "collect_js", "long_path", "unfurl")  # buildifier: disable=bzl-visibility
+load("@io_bazel_rules_closure//closure/private:defs.bzl", "WebFilesInfo", "long_path", "unfurl")  # buildifier: disable=bzl-visibility
 
 def _tb_combine_html_impl(ctx):
     """Compiles HTMLs into one HTML.
@@ -25,18 +25,11 @@ def _tb_combine_html_impl(ctx):
     JavaScript file when `js_path` is specified.
     """
 
-    deps = unfurl(ctx.attr.deps, provider = "webfiles")
-    manifests = depset(order = "postorder")
-    files = depset()
-    webpaths = depset()
-    for dep in deps:
-        manifests = depset(transitive = [manifests, dep.webfiles.manifests])
-        webpaths = depset(transitive = [webpaths, dep.webfiles.webpaths])
-        files = depset(transitive = [files, dep.data_runfiles.files])
+    deps = unfurl(ctx.attr.deps, provider = WebFilesInfo).exports
+    manifests = depset(order = "postorder", transitive = [dep[WebFilesInfo].manifests for dep in deps])
+    webpaths = depset(transitive = [dep[WebFilesInfo].webpaths for dep in deps])
+    files = depset(transitive = [dep.data_runfiles.files for dep in deps])
     webpaths = depset([ctx.attr.output_path], transitive = [webpaths])
-    closure_js_library = collect_js(
-        unfurl(ctx.attr.deps, provider = "closure_js_library"),
-    )
 
     # vulcanize
     ctx.actions.run(
@@ -91,23 +84,25 @@ def _tb_combine_html_impl(ctx):
             dep.data_runfiles.files,
         ])
 
-    return struct(
-        files = depset([ctx.outputs.html, ctx.outputs.js]),
-        webfiles = struct(
+    return [
+        DefaultInfo(
+            files = depset([ctx.outputs.html, ctx.outputs.js]),
+            runfiles = ctx.runfiles(
+                files = ctx.files.data + [
+                    manifest,
+                    ctx.outputs.html,
+                    ctx.outputs.js,
+                ],
+                transitive_files = transitive_runfiles,
+            ),
+        ),
+        WebFilesInfo(
             manifest = manifest,
             manifests = manifests,
             webpaths = webpaths,
             dummy = ctx.outputs.html,
         ),
-        runfiles = ctx.runfiles(
-            files = ctx.files.data + [
-                manifest,
-                ctx.outputs.html,
-                ctx.outputs.js,
-            ],
-            transitive_files = transitive_runfiles,
-        ),
-    )
+    ]
 
 tb_combine_html = rule(
     implementation = _tb_combine_html_impl,

tensorboard/defs/web.bzl

@@ -22,6 +22,8 @@ load(
     "@io_bazel_rules_closure//closure/private:defs.bzl",
     "CLOSURE_LIBRARY_BASE_ATTR",
     "CLOSURE_WORKER_ATTR",
+    "ClosureJsLibraryInfo",
+    "WebFilesInfo",
     "collect_js",
     "collect_runfiles",
     "difference",
@@ -49,10 +51,8 @@ def _tf_web_library(ctx):
         fail("when \"*\" is suppressed no other items should be present")
 
     # process what came before
-    deps = unfurl(ctx.attr.deps, provider = "webfiles")
-    webpaths = depset()
-    for dep in deps:
-        webpaths = depset(transitive = [webpaths, dep.webfiles.webpaths])
+    deps = unfurl(ctx.attr.deps, provider = WebFilesInfo).exports
+    webpaths = depset(transitive = [dep[WebFilesInfo].webpaths for dep in deps])
 
     # process what comes now
     manifest_srcs = []
@@ -93,11 +93,11 @@ def _tf_web_library(ctx):
         # If a rule exists purely to export other build rules, then it's
         # appropriate for the exported sources to be included in the
         # development web server.
-        export_deps = unfurl(ctx.attr.exports)
+        export_deps = unfurl(ctx.attr.exports).exports
         devserver_manifests = depset(
             order = "postorder",
             transitive = (
-                [manifests] + [dep.webfiles.manifests for dep in export_deps]
+                [manifests] + [dep[WebFilesInfo].manifests for dep in export_deps]
             ),
         )
     params = struct(
@@ -125,38 +125,38 @@ def _tf_web_library(ctx):
     # rule from rules_closure: because `tf_web_library`s may depend on
     # either other `tf_web_library`s or base `web_library`s, the
     # interfaces ~must be the same.
-    #
-    # buildozer: disable=rule-impl-return
-    return struct(
-        files = depset(web_srcs + [dummy]),
-        exports = unfurl(ctx.attr.exports),
-        webfiles = struct(
+    return [
+        WebFilesInfo(
             manifest = manifest,
             manifests = manifests,
             webpaths = webpaths,
             dummy = dummy,
         ),
-        closure_js_library = collect_js(
-            unfurl(ctx.attr.deps, provider = "closure_js_library"),
+        unfurl(ctx.attr.exports),
+        collect_js(
+            unfurl(ctx.attr.deps, provider = ClosureJsLibraryInfo).exports,
             ctx.files._closure_library_base,
         ),
-        runfiles = ctx.runfiles(
-            files = (ctx.files.srcs +
-                     ctx.files.data +
-                     ctx.files._closure_library_base + [
-                manifest,
-                params_file,
-                ctx.outputs.executable,
-                dummy,
-            ]),
-            transitive_files = depset(transitive = [
-                collect_runfiles([ctx.attr._WebfilesServer]),
-                collect_runfiles(deps),
-                collect_runfiles(export_deps),
-                collect_runfiles(ctx.attr.data),
-            ]),
+        DefaultInfo(
+            files = depset(web_srcs + [dummy]),
+            runfiles = ctx.runfiles(
+                files = (ctx.files.srcs +
+                         ctx.files.data +
+                         ctx.files._closure_library_base + [
+                    manifest,
+                    params_file,
+                    ctx.outputs.executable,
+                    dummy,
+                ]),
+                transitive_files = depset(transitive = [
+                    collect_runfiles([ctx.attr._WebfilesServer]),
+                    collect_runfiles(deps),
+                    collect_runfiles(export_deps),
+                    collect_runfiles(ctx.attr.data),
+                ]),
+            ),
         ),
-    )
+    ]
 
 def _make_manifest(ctx, src_list):
     manifest = _new_file(ctx, "-webfiles.pbtxt")
@@ -171,9 +171,7 @@ def _make_manifest(ctx, src_list):
 
 def _run_webfiles_validator(ctx, srcs, deps, manifest):
     dummy = _new_file(ctx, "-webfiles.ignoreme")
-    manifests = depset(order = "postorder")
-    for dep in deps:
-        manifests = depset(transitive = [manifests, dep.webfiles.manifests])
+    manifests = depset(order = "postorder", transitive = [dep[WebFilesInfo].manifests for dep in deps])
     if srcs:
         args = [
             "WebfilesValidator",
@@ -188,17 +186,13 @@ def _run_webfiles_validator(ctx, srcs, deps, manifest):
                 args.append(category)
         inputs = []  # list of depsets
         inputs.append(depset([manifest] + srcs))
-        direct_manifests = depset()
+        direct_manifests = depset([dep[WebFilesInfo].manifest for dep in deps])
         for dep in deps:
-            inputs.append(depset([dep.webfiles.dummy]))
+            inputs.append(depset([dep[WebFilesInfo].dummy]))
             inputs.append(dep.files)
-            direct_manifests = depset(
-                [dep.webfiles.manifest],
-                transitive = [direct_manifests],
-            )
-            inputs.append(depset([dep.webfiles.manifest]))
+            inputs.append(depset([dep[WebFilesInfo].manifest]))
             args.append("--direct_dep")
-            args.append(dep.webfiles.manifest.path)
+            args.append(dep[WebFilesInfo].manifest.path)
         for man in difference(manifests, direct_manifests):
             inputs.append(depset([man]))
             args.append("--transitive_dep")

tensorboard/defs/zipper.bzl

@@ -17,14 +17,10 @@
 load("@io_bazel_rules_closure//closure/private:defs.bzl", "unfurl")
 
 def _tensorboard_zip_file(ctx):
-    deps = unfurl(ctx.attr.deps, provider = "webfiles")
-    manifests = depset(order = "postorder")
-    files = depset()
-    webpaths = depset()
-    for dep in deps:
-        manifests = depset(transitive = [manifests, dep.webfiles.manifests])
-        webpaths = depset(transitive = [webpaths, dep.webfiles.webpaths])
-        files = depset(transitive = [files, dep.data_runfiles.files])
+    deps = unfurl(ctx.attr.deps, provider = WebFilesInfo).exports
+    manifests = depset(order = "postorder", transitive = [dep[WebFilesInfo].manifests for dep in deps])
+    webpaths = depset(transitive = [dep[WebFilesInfo].webpaths for dep in deps])
+    files = depset(transitive = [dep.data_runfiles.files for dep in deps])
     ctx.actions.run(
         mnemonic = "Zipper",
         inputs = depset(transitive = [manifests, files]).to_list(),
@@ -40,7 +36,7 @@ def _tensorboard_zip_file(ctx):
             transitive_runfiles,
             dep.data_runfiles.files,
         ])
-    return struct(
+    return DefaultInfo(
         files = depset([ctx.outputs.zip]),
         runfiles = ctx.runfiles(
             files = ctx.files.data + [ctx.outputs.zip],
@@ -52,7 +48,7 @@ tensorboard_zip_file = rule(
     implementation = _tensorboard_zip_file,
     attrs = {
         "data": attr.label_list(allow_files = True),
-        "deps": attr.label_list(providers = ["webfiles"], mandatory = True),
+        "deps": attr.label_list(providers = [WebFilesInfo], mandatory = True),
         "_Zipper": attr.label(
             default = Label("//tensorboard/java/org/tensorflow/tensorboard/vulcanize:Zipper"),
             executable = True,