build.gradle

plugins {
    id 'com.github.johnrengelman.shadow' version '5.1.0'
    id 'java-library'
    id 'maven-publish'
    id 'signing'
}

archivesBaseName = 'Rtflc'
group = 'net.termer.rtflc'
version = '1.3'

jar {
    manifest {
        attributes 'Main-Class': 'net.termer.rtflc.Main'
    }
}

repositories {
    jcenter()
}

dependencies {
    // Use JUnit test framework
    testImplementation 'junit:junit:4.12'

    // Application dependencies
    implementation 'net.lingala.zip4j:zip4j:2.5.0'
    implementation 'org.json:json:20190722'
}

java {
    withJavadocJar()
    withSourcesJar()
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifactId = 'Rtflc'
            from components.java
            versionMapping {
                usage('java-api') {
                    fromResolutionOf('runtimeClasspath')
                }
                usage('java-runtime') {
                    fromResolutionResult()
                }
            }
            pom {
                name = 'Rtflc'
                description = 'Advanced and high(er) permformance Rtfl runtime and compiler'
                url = 'https://github.com/termermc/rtflc'
                licenses {
                    license {
                        name = 'MIT License'
                        url = 'https://opensource.org/licenses/MIT'
                    }
                }
                developers {
                    developer {
                        id = 'termer'
                        name = 'Michael Termer'
                        email = 'termer@protonmail.com'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/termermc/rtflc.git'
                    developerConnection = 'scm:git:ssh://github.com/termermc/rtflc.git'
                    url = 'https://github.com/termermc/rtflc'
                }
            }
        }
    }
    repositories {
        maven {
            name = 'OSSRH'
            url = 'https://oss.sonatype.org/service/local/staging/deploy/maven2/'
            credentials {
                username = nexusUsername
                password = nexusPassword
            }
        }
    }
}

signing {
    sign publishing.publications.mavenJava
}


javadoc {
    if(JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}