-
Notifications
You must be signed in to change notification settings - Fork 0
/
nuc case.scad
578 lines (498 loc) · 19.9 KB
/
nuc case.scad
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
use <modules.scad>;
/* [General] */
// https://en.wikibooks.org/wiki/OpenSCAD_User_Manual/Other_Language_Features#$fa,_$fs_and_$fn
// The number of fragments for circles. A bigger number takes longer to render but looks nicer.
$fn = 48; // [0:128]
// Which part to display
which_part = "case"; // ["lid", "case"]
// How thick the walls of the case are (except around ports)
wall_thickness = 3; // [2:20]
// How much additional width should the case have? (This will make the case non-square)
addl_width = 0; // [0:30]
/* [Lid] */
// Should the lid have mounts for a 2.5" hdd?
hdd_mount = true;
/* [Case] */
// Should the case have surface mount tabs?
surface_mount = true;
// Should the case have a side hole for cable passthrough?
cable_hole = true;
// How tall the interior cavity of the case is (including standoffs)
interior_height = 45; // [38:80]
// How thick the exaust ports for the fan are
fan_exhaust_width = 10; // [5:30]
// How much space is between fan exhaust ports (at least)
fan_exhaust_spacing = 2; // [2:15]
// The diameter of the power button hole
power_button_diameter = 13.5; // [0:16]
/* [Hidden] */
interior_width = 108;
interior_radius = 7;
inset_wall_thickness = 1.5;
standoff_radius = 3;
standoff_hole_size = 1;
standoff_height = 15.2;
fan_guide_width = 1.5;
fan_guide_left = 23;
fan_guide_right = 83;
fan_guide_gap = fan_guide_right - fan_guide_left - fan_guide_width;
exhaust_hole_count = floor((fan_guide_gap + fan_exhaust_spacing) / (fan_exhaust_width + fan_exhaust_spacing));
actual_exhaust_spacing = (fan_guide_gap - (exhaust_hole_count * fan_exhaust_width)) / (exhaust_hole_count - 1);
mounting_tab_width = 20;
mounting_tab_thickness = 5;
tab_hole_diameter = 5;
vent_hole_thickness = 5;
vent_hole_rotation = 45;
min_vent_hole_spacing = 3;
lid_thickness = 3;
lid_bevel_thickness = 2;
vent_area_offset_x = min(wall_thickness, 10) + lid_thickness;
vent_area_offset_y = wall_thickness + lid_thickness;
vent_area_width_x = interior_width + addl_width - (vent_area_offset_x * 2);
vent_area_width_y = interior_width - (vent_area_offset_y * 2);
vent_hole_x_spacing = actual_item_spacing(
item_size = vent_hole_thickness,
min_item_spacing = min_vent_hole_spacing,
desired_length = vent_area_width_x
);
vent_hole_y_spacing = actual_item_spacing(
item_size = vent_hole_thickness,
min_item_spacing = min_vent_hole_spacing,
desired_length = vent_area_width_y
);
hdd_tab_coords_x = [
vent_area_offset_x + (vent_hole_thickness / 2)
:
vent_hole_thickness + vent_hole_x_spacing
:
vent_area_width_x + vent_area_offset_x
];
hdd_tab_coords_list_x = [for(i = hdd_tab_coords_x) i];
hdd_tab_coords_y = [
vent_area_offset_y + (vent_hole_thickness / 2)
:
vent_hole_thickness + vent_hole_y_spacing
:
vent_area_width_y + vent_area_offset_y
];
hdd_tab_coords_list_y = [for(i = hdd_tab_coords_x) i];
hdd_tab_thickness = vent_hole_thickness + (2 * vent_hole_x_spacing);
hdd_tab_height = 17;
hdd_width = 70.5;
if(which_part == "case") {
render(convexity = 2)
union() {
if(surface_mount == true) {
translate([
(interior_width - addl_width) / 2,
interior_width / 2,
(mounting_tab_thickness / 2)- wall_thickness
])
copy_mirror([1, 0, 0])
translate([-((interior_width + addl_width) / 2) - (mounting_tab_width / 2) - wall_thickness, 0, 0])
mounting_tab(
tab_width = mounting_tab_width,
tab_thickness = mounting_tab_thickness,
tab_hole_diameter = tab_hole_diameter
);
}
difference() {
union() {
// Outside Surface
translate([
-wall_thickness - addl_width,
-wall_thickness,
-wall_thickness
])
rounded_cube(
size = [
interior_width + (wall_thickness * 2) + addl_width,
interior_width + (wall_thickness * 2),
interior_height + wall_thickness
],
radius = interior_radius + wall_thickness
);
}
// Interior Cavity
translate([-addl_width, 0, 0])
rounded_cube(
size = [
interior_width + addl_width,
interior_width,
interior_height + 10
],
radius = interior_radius
);
// Front IO Inset
translate([41.25, -wall_thickness, 25.37])
rotate([90, 0, 180])
roundamid(
size = [50 + (wall_thickness * 2), 22 + (wall_thickness * 2)],
height = wall_thickness - inset_wall_thickness,
radius = wall_thickness + inset_wall_thickness - 1,
center = true
);
// Front USB
translate([55.5, -14, 25.13])
usb_port();
// Front Audio
translate([39, -14, 20.29])
round_port(diameter = 6);
// Front IR
translate([23, -14, 20.4])
round_port(diameter = 8);
// Front Power Button
translate([90.5, -14, 25])
round_port(diameter = power_button_diameter);
// Rear IO Inset
translate([54, interior_width + wall_thickness, 25.37])
rotate([90, 0, 0])
roundamid(
size = [89 + (wall_thickness * 2), 22 + (wall_thickness * 2)],
height = wall_thickness - inset_wall_thickness,
radius = wall_thickness + inset_wall_thickness - 1,
center = true
);
// Rear USB
translate([88, 122, 25.13])
usb_port();
// Rear Audio
translate([29.4, 122, 19])
round_port(diameter = 7);
// Rear Power
translate([15, 122, 21.9])
round_port(diameter = 9);
// Rear Ethernet
translate([69, 122, 25.5])
ethernet_port();
// Rear HDMI
translate([49, 122, 20.5])
hdmi_port();
// Side IO Inset
translate([interior_width + wall_thickness, 26.8, 19])
rotate([90, 0, 270])
roundamid(
size = [33 + (wall_thickness * 2), 11 + (wall_thickness * 2)],
height = wall_thickness - inset_wall_thickness,
radius = wall_thickness + inset_wall_thickness - 1,
center = true
);
// Side SD
translate([122, 26.8, 19])
rotate([90, 0, 90])
rounded_cube(size = [27, 5, 30], center = true, radius = 1);
if(cable_hole == true) {
// Side Cable Inset
translate([-wall_thickness - addl_width, 30, 30])
rotate([90, 0, 90])
roundamid(
size = [28 + (wall_thickness * 2) + 3, 9 + (wall_thickness * 2) + 3],
height = wall_thickness - inset_wall_thickness,
radius = wall_thickness + inset_wall_thickness - 1,
center = true
);
// Side Cable Hole
translate([-addl_width, 30, 30])
rotate([90, 0, 90])
rounded_cube(size = [28, 9, 30], center = true, radius = 1);
}
// Fan Exhausts
for(x = [
fan_guide_left + ((fan_exhaust_width + fan_guide_width )/ 2)
:
actual_exhaust_spacing + fan_exhaust_width
:
fan_guide_right
]) {
translate([x, 122, 6.501])
rotate([90, 0, 0])
rounded_cube(size = [fan_exhaust_width, 13, 30], radius = 3, center = true);
}
}
// Lid Clip
translate([
(interior_width - addl_width) / 2,
0,
interior_height - (lid_thickness / 2)
])
rotate([0, 90, 0])
cylinder(
h = (vent_hole_row_spacing * 3) + (vent_hole_thickness * 2) - 2,
d = lid_thickness - 1,
center = true
);
// Lid Clip
translate([
(interior_width - addl_width) / 2,
interior_width,
interior_height - (lid_thickness / 2)
])
rotate([0, 90, 0])
cylinder(
h = (vent_hole_row_spacing * 3) + (vent_hole_thickness * 2) - 2,
d = lid_thickness - 1,
center = true
);
// Fan Guides
translate([fan_guide_left, 98, 5])
cube([fan_guide_width, 20, 10], center = true);
// Fan Guides
translate([fan_guide_right, 98, 5])
cube(size = [fan_guide_width, 20, 10], center = true);
// Fan Guides
translate([
(fan_guide_right + fan_guide_left) / 2,
88.75,
1.25
])
cube(
size = [
fan_guide_right - fan_guide_left + fan_guide_width,
fan_guide_width,
2.5
],
center = true
);
// Standoffs
intersection() {
translate([-addl_width, 0, 0])
rounded_cube(
size = [
interior_width + addl_width,
interior_width,
interior_height + 10
],
radius = interior_radius
);
for(x = [5.5, 100.5]) {
for(y = [8.6, 99.2]) {
translate([x, y, standoff_height / 2])
difference() {
direction_x = x < 50 ? -1 : 1;
direction_y = y < 50 ? -1 : 1;
union() {
// Standoff chamfer
cylinder(
h = standoff_height,
r = standoff_radius,
center = true
);
// Standoff filler
translate([
(direction_x * 4 * standoff_radius) + (addl_width * direction_x * 0.5),
direction_y * 5 * standoff_radius,
0
])
cube(
size = [
(10 * standoff_radius) + addl_width,
10 * standoff_radius,
standoff_height
],
center = true
);
// Standoff filler
translate([
(direction_x * 5 * standoff_radius) + (addl_width * direction_x * 0.5),
direction_y * 4 * standoff_radius,
0
])
cube(
size = [
(10 * standoff_radius) + addl_width,
10 * standoff_radius,
standoff_height
],
center = true
);
}
// Standoff screw hole
cylinder(
h = standoff_height + 1,
r = standoff_hole_size,
center = true
);
}
}
}
}
}
}
if(which_part == "lid") {
render(convexity = 2)
union() {
difference() {
// Lid Body
union() {
// Wide Part
translate([
-wall_thickness,
-wall_thickness,
0
])
rounded_cube(
size = [
interior_width + (wall_thickness * 2) + addl_width,
interior_width + (wall_thickness * 2),
wall_thickness
],
radius = interior_radius + wall_thickness
);
// Inside Part
rounded_cube(
size = [
interior_width + addl_width,
interior_width,
wall_thickness + lid_thickness
],
radius = interior_radius
);
// Inside Part Bevel
translate([0, 0, wall_thickness + lid_thickness])
roundamid(
size = [interior_width + addl_width, interior_width],
height = lid_bevel_thickness,
radius = interior_radius
);
// Lid Clip Catch
translate([
(interior_width + addl_width)/ 2,
1.25,
wall_thickness + (lid_bevel_thickness + lid_thickness) / 2
])
cube(
size = [
(vent_hole_x_spacing * 3) + (vent_hole_thickness * 2),
2.5,
lid_bevel_thickness + lid_thickness
],
center = true
);
translate([
(interior_width + addl_width)/ 2,
interior_width - 1.25,
wall_thickness + (lid_bevel_thickness + lid_thickness) / 2
])
cube(
size = [
(vent_hole_x_spacing * 3) + (vent_hole_thickness * 2),
2.5,
lid_bevel_thickness + lid_thickness
],
center = true
);
// HDD Mounts
if(hdd_mount == true) {
intersection() {
union () {
translate([
max([ for (i = hdd_tab_coords_list_x) if (i < 100) i ]),
(interior_width + hdd_width) / 2,
wall_thickness + lid_bevel_thickness + lid_thickness + (hdd_tab_height / 2)
])
rotate([0, 0, 90])
hdd_hook(thickness = hdd_tab_thickness);
translate([
max([ for (i = hdd_tab_coords_list_x) if (i < 100) i ]),
(interior_width - hdd_width) / 2,
wall_thickness + lid_bevel_thickness + lid_thickness + (hdd_tab_height / 2)
])
rotate([0, 0, -90])
hdd_hook(thickness = hdd_tab_thickness);
translate([
hdd_tab_coords_list_x[0],
(interior_width + hdd_width) / 2,
wall_thickness + lid_bevel_thickness + lid_thickness + (hdd_tab_height / 2)
])
rotate([0, 0, 90])
hdd_hook(thickness = hdd_tab_thickness);
translate([
hdd_tab_coords_list_x[0],
(interior_width - hdd_width) / 2,
wall_thickness + lid_bevel_thickness + lid_thickness + (hdd_tab_height / 2)
])
rotate([0, 0, -90])
hdd_hook(thickness = hdd_tab_thickness);
}
// Chop the edges off of the tabs where needed
translate([
(interior_width + addl_width) / 2,
interior_width / 2,
(30 + wall_thickness) / 2
])
rounded_cube(
size = [
interior_width - (lid_bevel_thickness * 2) + addl_width,
interior_width - (lid_bevel_thickness * 2),
30 + wall_thickness
],
radius = interior_radius - lid_bevel_thickness,
center = true
);
}
}
}
// Lid Clip Recess
translate([
(interior_width + addl_width)/ 2,
0,
wall_thickness + (lid_thickness / 2)
])
rotate([0, 90, 0])
cylinder(
h = (vent_hole_x_spacing * 3) + (vent_hole_thickness * 2),
d = lid_thickness,
center = true
);
translate([
(interior_width + addl_width)/ 2,
interior_width,
wall_thickness + (lid_thickness / 2)
])
rotate([0, 90, 0])
cylinder(
h = (vent_hole_x_spacing * 3) + (vent_hole_thickness * 2),
d = lid_thickness,
center = true
);
// Vent Holes
difference() {
for(x = hdd_tab_coords_x) {
direction = round((x - hdd_tab_coords_x[0]) / hdd_tab_coords_x[1]) % 2;
for(y = hdd_tab_coords_y) {
union () {
translate([x, y, 0])
rotate([0, 0, 90])
mirror([direction, 0, 0])
vent_hole(
size = [
vent_hole_thickness,
vent_hole_thickness,
40 + wall_thickness
],
radius = 0.5,
angle = vent_hole_rotation
);
}
}
}
// Remove extra holes from standoffs
translate([
max([ for (i = hdd_tab_coords_list_x) if (i < 100) i ]),
(interior_width + hdd_width) / 2,
wall_thickness + lid_bevel_thickness + lid_thickness + (hdd_tab_height / 2)
])
rotate([0, 0, 90])
mounting_tab_shield(hdd_tab_thickness = hdd_tab_thickness);
// Remove extra holes from standoffs
translate([
hdd_tab_coords_list_x[0],
(interior_width - hdd_width) / 2,
wall_thickness + lid_bevel_thickness + lid_thickness + (hdd_tab_height / 2)
])
rotate([0, 0, -90])
mounting_tab_shield(hdd_tab_thickness = hdd_tab_thickness);
}
}
}
}