build.gradle

apply plugin: 'com.android.library'

def DEFAULT_COMPILE_SDK_VERSION     = 31
def DEFAULT_TARGET_SDK_VERSION      = 30
def DEFAULT_MIN_SDK_VERSION 	    = 16
def DEFAULT_LIFE_CYCLE_RUNTIME_VERSION              = "2.4.1"
def DEFAULT_LIFE_CYCLE_EXTENSIONS_VERSION           = "2.2.0"

def safeExtGet(prop, fallback) {
    rootProject.ext.has(prop) ? rootProject.ext.get(prop) : fallback
}

android {
    if (project.android.hasProperty("namespace")) {
        namespace("com.transistorsoft.rnbackgroundfetch")
    }

    compileSdkVersion safeExtGet('compileSdkVersion', DEFAULT_COMPILE_SDK_VERSION)

    defaultConfig {
        minSdkVersion safeExtGet('minSdkVersion', DEFAULT_MIN_SDK_VERSION)
        targetSdkVersion safeExtGet('targetSdkVersion', DEFAULT_TARGET_SDK_VERSION)
        consumerProguardFiles 'proguard-rules.pro'
        versionCode 1
        versionName "1.0"
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
}

repositories{
    mavenCentral()
    maven {
        url './libs'
    }
}

dependencies {
    def lifeCycleRuntimeVersion = safeExtGet('lifeCycleRuntimeVersion', DEFAULT_LIFE_CYCLE_RUNTIME_VERSION)
    def lifeCycleExtensionsVersion = safeExtGet('lifeCycleExtensionsVersion', DEFAULT_LIFE_CYCLE_EXTENSIONS_VERSION)

    implementation "com.facebook.react:react-native:${safeExtGet('reactNativeVersion', '+')}"
    implementation(group: 'com.transistorsoft', name:'tsbackgroundfetch', version: '+')
    // LifeCycleObserver
    implementation "androidx.lifecycle:lifecycle-runtime:$lifeCycleRuntimeVersion"
    implementation "androidx.lifecycle:lifecycle-extensions:$lifeCycleExtensionsVersion"
}