build.gradle

// *****************************************************************************
//
// *****************************************************************************

subprojects {

    apply plugin: 'java'
    apply plugin: 'osgi'
    apply plugin: 'maven'

    version             = '1.0.0.SNAPSHOT'
    group               = 'com.github.lburgazzoli'
    sourceCompatibility = '1.7'
    targetCompatibility = '1.7'

    project.ext.slf4jVersion              = '1.7.5'
    project.ext.log4jVersion              = '1.2.17'
    project.ext.jacksonVersion            = '2.3.2'
    project.ext.jacksonAnnotationsVersion = '2.3.2'
    project.ext.openhftLangVersion        = '6.1.4'
    project.ext.openhftChronicleVersion   = '2.0.3'
    project.ext.hazelcastVersion          = '3.1.6'
    project.ext.osgiVersion               = '5.0.0'
    project.ext.guavaVersion              = '15.0'
    project.ext.axonVersion               = '2.1.1'
    project.ext.junitVersion              = '4.11'
    project.ext.felixVersion              = '4.2.1'
    project.ext.paxExamVersion            = '3.4.0'
    project.ext.paxUrlVersion             = '1.6.0'
    project.ext.jgroupsVersion            = '3.4.2.Final'
    project.ext.commonsLangVersion        = '3.2.1'
    project.ext.commonsBeanutilsVersion   = '1.8.3'
    project.ext.commonsCollectionsVersion = '3.2.1'
    project.ext.javaxCacheVersion         = '0.5' //''1.0.0-RC1'
    project.ext.springVersion             = '3.1.0.RELEASE'

    repositories {
        mavenCentral()
        mavenLocal()
    }

    dependencies {
        compile "org.apache.commons:commons-lang3:$commonsLangVersion"
        compile "commons-beanutils:commons-beanutils:$commonsBeanutilsVersion"
        compile "org.slf4j:slf4j-api:$slf4jVersion"
        compile "org.slf4j:slf4j-ext:$slf4jVersion"
        compile "org.slf4j:jul-to-slf4j:$slf4jVersion"
        compile "org.slf4j:jcl-over-slf4j:$slf4jVersion"
        compile "org.slf4j:slf4j-log4j12:$slf4jVersion"
        compile "log4j:log4j:$log4jVersion"
        compile "org.apache.geronimo.specs:geronimo-jpa_2.0_spec:1.1"
        compile "org.axonframework:axon-core:$axonVersion"
        compile "org.axonframework:axon-distributed-commandbus:$axonVersion"
        compile "org.jgroups:jgroups:$jgroupsVersion"
    }

    jar {
        baseName = "${project.name}"

        manifest.attributes['Bundle-Description'     ] = "lb :: ${project.name}"
        manifest.attributes['Bundle-Name'            ] = "lb :: ${project.name}"
        manifest.attributes['Bundle-SymbolicName'    ] = "${project.group}.${project.name}"
        manifest.attributes['Bundle-Version'         ] = project.version
        manifest.attributes['Implementation-Title'   ] = "${project.group}-${project.name}-${project.version}"
        manifest.attributes['Implementation-Version' ] = project.version
        manifest.attributes['Implementation-Vendor'  ] = 'lb'

        manifest.classesDir = new File("$buildDir/classes/main")
        manifest.classpath  = project.runtimeClasspath
    }

    test {
        testLogging {
            events "failed"
            exceptionFormat "full"
        }

        systemProperties = [
            'version.project'            : version,
            'version.slf4j'              : slf4jVersion,
            'version.log4j'              : log4jVersion,
            'version.jackson'            : jacksonVersion,
            'version.hazelcast'          : hazelcastVersion,
            'version.osgi'               : osgiVersion,
            'version.guava'              : guavaVersion,
            'version.axon'               : axonVersion,
            'version.junit'              : junitVersion,
            'version.felix'              : felixVersion,
            'version.paxExam'            : paxExamVersion,
            'version.paxUrl'             : paxUrlVersion,
            'version.commonsLang'        : commonsLangVersion,
            'version.commonsCollections' : commonsCollectionsVersion,
            'version.javaxCache'         : javaxCacheVersion,
            'pax.exam.framework'         : 'felix',
            'pax.exam.logging'           : 'none'
        ]
    }

    [compileJava, compileTestJava]*.options*.compilerArgs = [
        "-Xlint:unchecked",
        "-Xlint:deprecation",
    ]
}

// *****************************************************************************
//
// *****************************************************************************

task wrapper(type: Wrapper) {
    gradleVersion = '1.9'
}