build: add nix flake (#2)

Co-authored-by: uncenter <47499684+uncenter@users.noreply.github.com>

.gitignore

@@ -1 +1,2 @@
-/target
+target/
+result/

default.nix

@@ -0,0 +1,22 @@
+{
+  pkgs ? import <nixpkgs> {},
+  lib ? pkgs.lib,
+  version ? "latest",
+  ...
+}:
+pkgs.rustPlatform.buildRustPackage {
+  pname = "kittysay";
+  inherit version;
+
+  src = ./.;
+  cargoLock.lockFile = ./Cargo.lock;
+
+  doCheck = false;
+
+  meta = with lib; {
+    description = "The cutest successor of cowsay.";
+    homepage = "https://github.com/uncenter/kittysay";
+    license = licenses.mit;
+    maintainers = [maintainers.uncenter];
+  };
+}

flake.nix

@@ -0,0 +1,24 @@
+{
+  description = "kittysay";
+
+  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.11";
+
+  outputs = {
+    self,
+    nixpkgs,
+    ...
+  }: let
+    forAllSystems = nixpkgs.lib.genAttrs ["x86_64-linux" "x86_64-darwin" "i686-linux" "aarch64-linux" "aarch64-darwin"];
+    pkgsForEach = nixpkgs.legacyPackages;
+    version = self.shortRev or "dirty";
+  in {
+    packages = forAllSystems (system: rec {
+      default = pkgsForEach.${system}.callPackage ./default.nix {inherit version;};
+      kittysay = default;
+    });
+
+    devShells = forAllSystems (system: {
+      default = pkgsForEach.${system}.callPackage ./shell.nix {};
+    });
+  };
+}

shell.nix

@@ -0,0 +1,17 @@
+{
+  callPackage,
+  rust-analyzer,
+  rustfmt,
+  clippy,
+}: let
+  mainPkg = callPackage ./default.nix {version = "debug";};
+in
+  mainPkg.overrideAttrs (oa: {
+    nativeBuildInputs =
+      [
+        rust-analyzer
+        rustfmt
+        clippy
+      ]
+      ++ (oa.nativeBuildInputs or []);
+  })