-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle.kts
186 lines (148 loc) · 5.2 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
plugins {
id( "fabric-loom" )
kotlin( "jvm" ) version( System.getProperty( "kotlin_version" ) )
kotlin( "plugin.serialization" ) version( System.getProperty( "kotlin_version" ) )
id( "maven-publish" )
id( "signing" )
}
base {
archivesName.set( project.extra[ "archives_base_name" ] as String )
}
version = project.extra[ "mod_version" ] as String
group = project.extra[ "maven_group" ] as String
repositories {}
dependencies {
// Minecraft
minecraft( "com.mojang", "minecraft", project.extra[ "minecraft_version" ] as String )
// Minecraft source mappings - https://github.com/FabricMC/yarn
mappings( "net.fabricmc", "yarn", project.extra[ "yarn_mappings" ] as String, null, "v2" )
// Fabric Loader - https://github.com/FabricMC/fabric-loader
modImplementation( "net.fabricmc", "fabric-loader", project.extra[ "loader_version" ] as String )
// Fabric API - https://github.com/FabricMC/fabric
modImplementation( "net.fabricmc.fabric-api", "fabric-api", project.extra[ "fabric_version" ] as String )
// Kotlin support for Fabric - https://github.com/FabricMC/fabric-language-kotlin
modImplementation( "net.fabricmc", "fabric-language-kotlin", project.extra[ "fabric_language_kotlin_version" ] as String )
}
tasks {
val javaVersion = JavaVersion.toVersion( ( project.extra[ "java_version" ] as String ).toInt() )
withType<JavaCompile> {
options.encoding = "UTF-8"
sourceCompatibility = javaVersion.toString()
targetCompatibility = javaVersion.toString()
options.release.set( javaVersion.toString().toInt() )
}
withType<org.jetbrains.kotlin.gradle.tasks.KotlinCompile> {
kotlinOptions {
jvmTarget = javaVersion.toString()
}
}
jar {
from( "LICENSE.txt" ) {
rename { "${ it }_${ base.archivesName.get() }.txt" }
}
}
processResources {
// Metadata
filesMatching( "fabric.mod.json" ) {
expand( mutableMapOf(
"version" to project.extra[ "mod_version" ] as String,
"java" to project.extra[ "java_version" ] as String,
"minecraft" to project.extra[ "minecraft_version" ] as String,
"fabricloader" to project.extra[ "loader_version" ] as String,
"fabric_api" to project.extra[ "fabric_version" ] as String,
"fabric_language_kotlin" to project.extra[ "fabric_language_kotlin_version" ] as String
) )
}
// Mixins
filesMatching( "*.mixins.json" ) {
expand( mutableMapOf(
"java" to project.extra[ "java_version" ] as String
) )
}
}
java {
toolchain {
languageVersion.set( JavaLanguageVersion.of( javaVersion.toString() ) )
}
sourceCompatibility = javaVersion
targetCompatibility = javaVersion
withSourcesJar()
}
// Empty javadoc JAR
register<Jar>( "javadocJar" ) {
archiveClassifier.set( "javadoc" )
includeEmptyDirs = false
from( "." ) {
include( "README.md" )
}
}
}
publishing {
repositories {
// GitHub Packages - https://docs.github.com/en/packages/working-with-a-github-packages-registry/working-with-the-gradle-registry
maven {
name = "GitHubPackages"
url = uri( "https://maven.pkg.github.com/viral32111/library" )
credentials {
username = project.findProperty( "ghpkg.user" ) as String? ?: System.getenv( "GHPKG_USER" )
password = project.findProperty( "ghpkg.token" ) as String? ?: System.getenv( "GHPKG_TOKEN" )
}
}
// OSSRH - https://central.sonatype.org/publish/publish-gradle/
maven {
name = "OSSRH"
url = uri( "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/" )
credentials {
username = project.findProperty( "ossrh.user" ) as String? ?: System.getenv( "OSSRH_USER" )
password = project.findProperty( "ossrh.token" ) as String? ?: System.getenv( "OSSRH_TOKEN" )
}
}
}
// https://docs.gradle.org/current/userguide/publishing_maven.html
publications {
create<MavenPublication>( "mavenJava" ) {
groupId = project.extra[ "maven_group" ] as String
artifactId = project.extra[ "archives_base_name" ] as String
version = project.extra[ "mod_version" ] as String
// Metadata
pom {
name.set( "Library" )
description.set( "Shared code for my Minecraft mods." )
url.set( "https://github.com/viral32111/library" )
licenses {
license {
name.set( "GNU Affero General Public License v3.0" )
url.set( "https://github.com/viral32111/library/blob/main/LICENSE.txt" )
}
}
developers {
developer {
id.set( "viral32111" )
name.set( "viral32111" )
url.set( "https://viral32111.com" )
email.set( "contact@viral32111.com" )
}
}
scm {
connection.set( "scm:git:git://github.com/viral32111/library.git" )
developerConnection.set( "scm:git:git://github.com/viral32111/library.git" )
url.set( "https://github.com/viral32111/library" )
}
}
// Include main & sources JAR
from( components[ "java" ] )
// Include empty JavaDoc JAR
artifact( tasks[ "javadocJar" ] ) {
classifier = "javadoc"
}
}
}
}
signing {
useInMemoryPgpKeys(
project.findProperty( "signing.keyId" ) as String? ?: System.getenv( "SIGNING_KEY_ID" ),
project.findProperty( "signing.secretKey" ) as String? ?: System.getenv( "SIGNING_SECRET_KEY" ),
project.findProperty( "signing.password" ) as String? ?: System.getenv( "SIGNING_PASSWORD" )
)
sign( publishing.publications[ "mavenJava" ] )
}