[Question] Parse string like '2 345.2' into number f32

[tarasyyyk]

Hi. I'm new in V and compiled languages at all.

I asked a question on Stackoverflow, but no answers yet. So, maybe someone can help there.
The question is how to convert strings like '2 345.5' to number with decimal.

What I'm doing is parsing JSON using json.decode() and Struct. Standard convertion to float gives 0:

import json

struct Account {
    id       int
    balance  f32  [json: availableCash]
}

json_data := '{ "id": 26, "availableCash": "1 475.26" }'
account := json.decode(Account, json_data) or { panic('failed to parse json') }

println(account)

Output is:

Account{
    id: 26
    balance: 0
}

[larpon]

What float value should it be? There's a whitespace in it that probably ruin the parsing. V accepts _ as delimiters though

[tarasyyyk]

Thanks for reply.
Yes, there is whitespace in string, but it not affects to result: "1475.4" also gives 0 when casting to f32 value.
I expect this string be parsed into 1475.4, so I can compare it or do math operations, etc.

[JalonSolov]

The space is very significant, as parsing usually stops at the first non-number. Same as if you had 1a475.4.

However, it is still a problem that it didn't get any number at all out of it (I would've expected it to set balance: 1 or balance: 1.0 with the code you show). It even gives 0 when you remove the space, and that's bad.

Have you tried using the x.json2 module?

[tarasyyyk]

Thanks for the tip. x.json2 module works!

[tarasyyyk]

Converting string like "1 475.4" as easy as "1 475.4".replace(' ', '').f32().
With module x.json2 you can write your own json parser for your struct. Here is complete example:

import x.json2

struct Account {
mut:
    id       int
    balance  f32 [json: availableCash]
}

pub fn (mut a Account) from_json(f json2.Any) {
    mp := f.as_map()
    mut field_name := ''
    $for field in Account.fields {
        field_name = field.name

        for attr in field.attrs {
            if attr.starts_with('json:') {
                field_name = attr.all_after('json:').trim_left(' ')
                break
            }
        }

        match field.name {
            'id' { a.id = mp[field_name].str().int() }
            'balance' { a.balance = mp[field_name].str().replace(' ', '').f32() }
            else {}
        }
    }
}

json_data := '{ "id": "26", "availableCash": "1 475.26" }'

account := json2.decode<Account>(json_data) or { panic('failed to parse json') }

println(account)

Thanks, @JalonSolov for help!