build.gradle

plugins {
    id "java-gradle-plugin"
    id "com.gradle.plugin-publish" version "0.21.0"
    id 'org.sonarqube' version '6.0.0.5145'
    id 'be.vbgn.ci-detect' version '0.5.0'
    id 'be.vbgn.dev-conventions' version '0.5.3'
    id 'jacoco'
    id "maven-publish"
    id "idea"
}

group 'eu.xenit.gradle'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(11)
    }
}

repositories {
    mavenCentral()
}


sourceSets {
    integrationTest {
        java {
            compileClasspath += main.output + test.output
            runtimeClasspath += main.output + test.output
        }
    }
}

configurations {
    integrationTestCompileClasspath.extendsFrom testCompileClasspath
    integrationTestRuntimeClasspath.extendsFrom testRuntimeClasspath
}

dependencies {
    implementation gradleApi()
    testImplementation group: 'junit', name: 'junit', version: '4.13.2'
    testImplementation group: 'commons-io', name: 'commons-io', version: '2.18.0'
}
import org.gradle.util.GradleVersion

task integrationTest(type: Test, group: "verification") {
    testClassesDirs = sourceSets.integrationTest.output.classesDirs
    classpath = sourceSets.integrationTest.runtimeClasspath
    shouldRunAfter(test)
    doFirst {
        if (gradle.startParameter.offline) {
            systemProperty "eu.xenit.gradle.alfrescosdk.integration.useGradleVersion", GradleVersion.current().version
        }
    }
}

tasks.withType(Test) {
    systemProperty("eu.xenit.gradle.alfrescosdk.deprecation.stacktrace", "false")
    systemProperty("eu.xenit.gradle.alfrescosdk.deprecation.warnAlways", "true")
}

javadoc {
    exclude("**/internal/**")
}

check.dependsOn(tasks.withType(Test))

gradlePlugin {
    plugins {
        ampBase {
            id = "eu.xenit.amp-base"
            implementationClass = "eu.xenit.gradle.alfrescosdk.AmpBasePlugin"
        }
        amp {
            id = "eu.xenit.amp"
            implementationClass = "eu.xenit.gradle.alfrescosdk.AmpPlugin"
        }

        alfresco {
            id = "eu.xenit.alfresco"
            implementationClass = "eu.xenit.gradle.alfrescosdk.AlfrescoPlugin"
        }
    }
}

pluginBundle {
    vcsUrl = "https://github.com/xenit-eu/alfresco-gradle-sdk"
    website = vcsUrl
    description = "Gradle plugins and tasks to support Alfresco development"
    tags = ["alfresco"]
    plugins {
        ampBase {
            displayName = "Alfresco AMP base plugin"
        }
        amp {
            displayName = "Alfresco AMP plugin"
        }
        alfresco {
            displayName = "Alfresco dependency management plugin"
        }
    }

    mavenCoordinates {
        groupId = "eu.xenit.gradle"
        artifactId = "alfresco-sdk"
    }
}