test_DAs_gnuplot.txt

# tic label frequency
set xrange [ARG1:ARG2]
set yrange [0:2]
set y2range [0:10]

set ylabel 'Normalized Difficulty'
set y2label 'Normalized Hashrate and Solvetimes'

set ylabel font "Arial, 10"
set y2label font "Arial, 10"

set xtics ARG3
set xtics rotate
set ytics 0.2
set y2tics 1

set tics font "Arial,10"
# tics between labels
# set mxtics 2 
set grid xtics ytics mxtics mytics
set term gif size 1200, 400
set output "gif_" . ARG4 . ".gif"

set size 1,1

set title font "Arial, 15"
set title ARG4 offset 0,-1

# Do large plots
plot "plot_" . ARG4 . ".txt" using 1:2 with filledcurve y1=1 title "Difficulty", \
		"plot_" . ARG4 . ".txt" using 1:4 with filledcurve y2=1 axes x1y2 title "Actual HashRate", \
		"plot_" . ARG4 . ".txt" using 1:5 lt rgb "blue" lw 1 with lines axes x1y2 title "Avg " . ARG5 .  " ST", \
		"plot_" . ARG4 . ".txt" using 1:6 lt rgb "red" lw 1 with lines axes x1y2 title "11 ST's estimate of Hashrate", \
		"plot_" . ARG4 . ".txt" using 1:7 lt rgb "blue" pt 1 with points axes x1y1 title "TSA"
#		"plot_" . ARG4 . ".txt" using 1:7 lt rgb "blue" with filledcurve y2=0 axes x1y2 title "Delays", \