Add runnables queries (#79)

This PR adds run options to run main classes and tests via the IDE.
~One problem I wasnt able to overcome was me not being able to
dynamically decide whether to use maven or gradle to run.~

~An option would be to ship a script that, proxys maven and gradle and
decides which one to use. But i don't know how elegant that would be.
The Solution rn is just to show both options always.~

Author: lxgr-linux

languages/java/runnables.scm

@@ -0,0 +1,86 @@
+; Run the main function
+(
+    (package_declaration
+        (scoped_identifier) @java_package_name
+    )
+    (class_declaration
+        (modifiers) @class-modifier
+        (#match? @class-modifier "public")
+        name: (identifier) @java_class_name
+        body: (class_body
+            (method_declaration
+                (modifiers) @modifier
+                name: (identifier) @run
+                (#eq? @run "main")
+                (#match? @modifier "public")
+                (#match? @modifier "static")
+            )
+        )
+    ) @_
+    (#set! tag java-main)
+)
+
+; Run the main class
+(
+    (package_declaration
+        (scoped_identifier) @java_package_name
+    )
+    (class_declaration
+        (modifiers) @class-modifier
+        (#match? @class-modifier "public")
+        name: (identifier) @java_class_name @run
+        body: (class_body
+            (method_declaration
+                (modifiers) @modifier
+                name: (identifier) @method_name
+                (#eq? @method_name "main")
+                (#match? @modifier "public")
+                (#match? @modifier "static")
+            )
+        )
+    ) @_
+    (#set! tag java-main)
+)
+
+; Run test function
+(
+    (package_declaration
+        (scoped_identifier) @java_package_name
+    )
+    (class_declaration
+        name: (identifier) @java_class_name
+        body: (class_body
+            (method_declaration
+                (modifiers
+                    (marker_annotation
+                        name: (identifier) @annotation_name
+                    )
+                )
+                name: (identifier) @run @java_method_name
+                (#eq? @annotation_name "Test")
+            )
+        )
+    ) @_
+    (#set! tag java-test-method)
+)
+
+; Run test class
+(
+    (package_declaration
+        (scoped_identifier) @java_package_name
+    )
+    (class_declaration
+        name: (identifier) @java_class_name @run
+        body: (class_body
+            (method_declaration
+                (modifiers
+                    (marker_annotation
+                        name: (identifier) @annotation_name
+                    )
+                )
+                (#eq? @annotation_name "Test")
+            )
+        )
+    ) @_
+    (#set! tag java-test-class)
+)

languages/java/tasks.json

@@ -0,0 +1,29 @@
+[
+  {
+    "label": "Run $ZED_CUSTOM_java_class_name",
+    "command": "c=\"$ZED_CUSTOM_java_package_name.$ZED_CUSTOM_java_class_name\"; if [ -f pom.xml ]; then mvn clean compile exec:java -Dexec.mainClass=$c; elif [ -f gradlew ]; then ./gradlew run -PmainClass=$c; else >&2 echo 'No build system found'; exit 1; fi;",
+    "use_new_terminal": false,
+    "reveal": "always",
+    "tags": ["java-main"]
+  },
+  {
+    "label": "Test $ZED_CUSTOM_java_class_name.$ZED_CUSTOM_java_method_name",
+    "command": "c=\"$ZED_CUSTOM_java_package_name.$ZED_CUSTOM_java_class_name\"; m=\"$ZED_CUSTOM_java_method_name\"; if [ -f pom.xml ]; then mvn clean test -Dtest=\"$c#$m\"; elif [ -f gradlew ]; then ./gradlew test --tests $c.$m; else >&2 echo 'No build system found'; exit 1; fi;",
+    "use_new_terminal": false,
+    "reveal": "always",
+    "tags": ["java-test-method"]
+  },
+  {
+    "label": "Test class $ZED_CUSTOM_java_class_name",
+    "command": "c=\"$ZED_CUSTOM_java_package_name.$ZED_CUSTOM_java_class_name\"; if [ -f pom.xml ]; then mvn clean test -Dtest=\"$c\"; elif [ -f gradlew ]; then ./gradlew test --tests $c; else >&2 echo 'No build system found'; exit 1; fi;",
+    "use_new_terminal": false,
+    "reveal": "always",
+    "tags": ["java-test-class"]
+  },
+  {
+    "label": "Run tests",
+    "command": "if [ -f pom.xml ]; then mvn clean test; elif [ -f gradlew ]; then ./gradlew test; else >&2 echo 'No build system found'; exit 1; fi;",
+    "use_new_terminal": false,
+    "reveal": "always"
+  }
+]