forked from antbryan/www
-
Notifications
You must be signed in to change notification settings - Fork 2
/
metalink2rdfxml.xsl
295 lines (252 loc) · 10.6 KB
/
metalink2rdfxml.xsl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
<?xml version="1.0" ?> <!-- encoding="UTF-8" -->
<!-- metalink2rdfxml.xsl
Converts metalinker.org XML files to an RDF representation
This version : 2007-08-10
Status : second pass, should be complete and valid, ready for feedback
Mapping Notes :
generally if an element is missing, it'll also be left out of the RDF/XML version
m:origin -> dc:source
date attributes on elements moved out to equivalent elements - was easier for format conversion
translated from RFC822 to RFC3339 format (if not correct RFC(2)822 then property left out)
m:pubdate -> dc:date
m:refreshdate -> dcterms:modified
m:tags split (on ' ' and/or ','), expressed individually using Tag Ontology
m:type (on root metalink element) -> m:type
m:type (on m:url elements) -> individual of type scheme:Scheme
see http://n2.talis.com/svn/playground/danja/schemas/uri-schemes.rdf
m:type when used with hash element has been changed into m:md5_hash etc. properties
m:url -> m:url@rdf:resource
structure around files/file has been flattened, see code
pieces rearranged, see code
Contributors :
Anthony Bryan
Dan Brickley
Danny Ayers
-->
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
xmlns:foaf="http://xmlns.com/foaf/0.1/"
xmlns:dc="http://purl.org/dc/elements/1.1/"
xmlns:dcterms="http://purl.org/dc/terms/"
xmlns:doap="http://usefulinc.com/ns/doap#"
xmlns:xhtml="http://www.w3.org/1999/xhtml"
xmlns:tags="http://www.holygoat.co.uk/owl/redwood/0.1/tags/"
xmlns:scheme="http://purl.org/stuff/uri-schemes"
xmlns:m="http://www.metalinker.org/"
xmlns="http://www.metalinker.org/">
<xsl:output method="xml" indent="yes" /><!-- encoding="UTF-8" -->
<xsl:template match="/m:metalink">
<rdf:RDF>
<Metalink>
<xsl:if test="@type">
<xsl:attribute name="m:type"><xsl:value-of select="@type"/></xsl:attribute>
</xsl:if>
<xsl:if test="@generator">
<xsl:attribute name="m:type"><xsl:value-of select="@type"/></xsl:attribute>
</xsl:if>
<xsl:if test="@origin">
<xsl:attribute name="dc:source"><xsl:value-of select="@origin"/></xsl:attribute>
</xsl:if>
<xsl:if test="@pubdate">
<xsl:call-template name="date">
<xsl:with-param name="name" select="'dc:date'"/>
<xsl:with-param name="raw_date" select="@pubdate"/>
</xsl:call-template>
</xsl:if>
<xsl:if test="@refreshdate">
<xsl:call-template name="date">
<xsl:with-param name="name" select="'dcterms:modified'"/>
<xsl:with-param name="raw_date" select="@refreshdate"/>
</xsl:call-template>
</xsl:if>
<xsl:apply-templates select="m:publisher"/>
<xsl:if test="m:description/text()">
<dc:description><xsl:value-of select="m:description" /></dc:description>
</xsl:if>
<xsl:apply-templates select="m:tags"/>
<xsl:copy-of select="m:identity" />
<xsl:copy-of select="m:version" />
<m:file>
<xsl:apply-templates select="m:files"/>
</m:file>
</Metalink>
</rdf:RDF>
</xsl:template>
<xsl:template match="m:publisher">
<m:publisher rdf:parseType="Resource">
<m:name><xsl:value-of select="m:name" /></m:name>
<m:url>
<xsl:attribute name="rdf:resource"><xsl:value-of select="m:url" /></xsl:attribute>
</m:url>
</m:publisher>
</xsl:template>
<xsl:template match="m:tags">
<xsl:variable name="space-separated-tags"><xsl:value-of select="translate(text(), ',', ' ')"/></xsl:variable>
<xsl:call-template name="split-list">
<xsl:with-param name="list"><xsl:value-of select="$space-separated-tags" /></xsl:with-param>
</xsl:call-template>
</xsl:template>
<xsl:template match="m:files">
<xsl:for-each select="m:file">
<m:File m:name="{@name}">
<xsl:copy-of select="m:os" />
<xsl:copy-of select="m:size" />
<m:verification rdf:parseType="Resource">
<xsl:for-each select="m:verification/m:hash">
<xsl:element name="m:{@type}_hash"><xsl:value-of select="text()"/></xsl:element>
</xsl:for-each>
<xsl:for-each select="m:verification/m:pieces">
<xsl:call-template name="pieces">
<xsl:with-param name="pieces" select="." />
</xsl:call-template>
</xsl:for-each>
</m:verification>
<xsl:apply-templates />
</m:File>
</xsl:for-each>
</xsl:template>
<xsl:template name="pieces">
<xsl:param name="pieces" />
<m:pieces>
<m:Pieces m:length="{@length}">
<xsl:for-each select="m:hash">
<xsl:element name="m:{../@type}">
<xsl:attribute name="rdf:parseType">Resource</xsl:attribute>
<m:position><xsl:value-of select="position()"/></m:position>
<rdf:value><xsl:value-of select="text()" /></rdf:value>
</xsl:element>
</xsl:for-each>
</m:Pieces>
</m:pieces>
</xsl:template>
<xsl:template match="m:resources">
<xsl:for-each select="m:url">
<m:url>
<xsl:attribute name="rdf:resource"><xsl:value-of select="./text()"/></xsl:attribute>
<xsl:attribute name="scheme:scheme">http://purl.org/stuff/uri-schemes/<xsl:value-of select="@type"/></xsl:attribute>
<xsl:attribute name="m:location"><xsl:value-of select="@location" /></xsl:attribute>
<xsl:attribute name="m:preference"><xsl:value-of select="@preference" /></xsl:attribute>
</m:url>
</xsl:for-each>
</xsl:template>
<!-- based on a trick in Michael Kay's XSLT Ref. book -->
<xsl:template name="split-list">
<xsl:param name="list" />
<xsl:variable name="newlist" select="concat(normalize-space($list), ' ')" />
<xsl:variable name="first" select="substring-before($newlist, ' ')" />
<xsl:variable name="remaining" select="substring-after($newlist, ' ')" />
<tags:taggedWithTag rdf:parseType="Resource">
<tags:tagName><xsl:value-of select="$first" /></tags:tagName>
</tags:taggedWithTag>
<xsl:if test="$remaining">
<xsl:call-template name="split-list">
<xsl:with-param name="list" select="$remaining" />
</xsl:call-template>
</xsl:if>
</xsl:template>
<xsl:template name="date"> <!-- derived from mortenf's rss xslt -->
<xsl:param name="name" select="'dc:date'"/>
<xsl:param name="raw_date" />
<xsl:if test="contains($raw_date,',') and string-length(normalize-space(substring-before($raw_date,',')))=3">
<xsl:variable name="dmyhisz" select="normalize-space(substring-after($raw_date,','))"/>
<!-- Fetch date of month. -->
<xsl:if test="contains($dmyhisz,' ') and string-length(substring-before($dmyhisz,' '))<=2">
<xsl:variable name="d" select="substring-before($dmyhisz,' ')"/>
<xsl:variable name="myhisz" select="normalize-space(substring-after($dmyhisz,' '))"/>
<!-- Validate date of month, fetch and translate month name to month number. -->
<xsl:if test="string-length(translate($d,'0123456789',''))=0 and contains($myhisz,' ') and string-length(substring-before($myhisz,' '))=3">
<xsl:variable name="m-temp" select="translate(substring-before($myhisz,' '),'ABCDEFGHIJKLMNOPQRSTUVWXYZ','abcdefghijklmnopqrstuvwxyz')"/>
<xsl:variable name="yhisz" select="normalize-space(substring-after($myhisz,' '))"/>
<xsl:variable name="m">
<xsl:choose>
<xsl:when test="$m-temp='jan'">
<xsl:value-of select="'1'"/>
</xsl:when>
<xsl:when test="$m-temp='feb'">
<xsl:value-of select="'2'"/>
</xsl:when>
<xsl:when test="$m-temp='mar'">
<xsl:value-of select="'3'"/>
</xsl:when>
<xsl:when test="$m-temp='apr'">
<xsl:value-of select="'4'"/>
</xsl:when>
<xsl:when test="$m-temp='may'">
<xsl:value-of select="'5'"/>
</xsl:when>
<xsl:when test="$m-temp='jun'">
<xsl:value-of select="'6'"/>
</xsl:when>
<xsl:when test="$m-temp='jul'">
<xsl:value-of select="'7'"/>
</xsl:when>
<xsl:when test="$m-temp='aug'">
<xsl:value-of select="'8'"/>
</xsl:when>
<xsl:when test="$m-temp='sep'">
<xsl:value-of select="'9'"/>
</xsl:when>
<xsl:when test="$m-temp='oct'">
<xsl:value-of select="'10'"/>
</xsl:when>
<xsl:when test="$m-temp='nov'">
<xsl:value-of select="'11'"/>
</xsl:when>
<xsl:when test="$m-temp='dec'">
<xsl:value-of select="'12'"/>
</xsl:when>
</xsl:choose>
</xsl:variable>
<!-- Validate month, fetch (possibly translating) year. -->
<xsl:if test="string-length($m)!=0 and contains($yhisz,' ')">
<xsl:variable name="y-temp" select="substring-before($yhisz,' ')"/>
<xsl:variable name="hisz" select="normalize-space(substring-after($yhisz,' '))"/>
<xsl:variable name="y">
<xsl:choose>
<xsl:when test="string-length(translate($y-temp,'0123456789',''))=0 and string-length($y-temp)=2 and $y-temp < 70">
<xsl:value-of select="concat('20',$y-temp)"/>
</xsl:when>
<xsl:when test="string-length(translate($y-temp,'0123456789',''))=0 and string-length($y-temp)=2 and $y-temp >= 70">
<xsl:value-of select="concat('19',$y-temp)"/>
</xsl:when>
<xsl:when test="string-length(translate($y-temp,'0123456789',''))=0 and string-length($y-temp)=4">
<xsl:value-of select="$y-temp"/>
</xsl:when>
</xsl:choose>
</xsl:variable>
<!-- Validate year, fetch time, fetch and translate (valid) time zone. -->
<xsl:if test="string-length($y)!=0 and contains($hisz,' ')">
<xsl:variable name="his" select="substring-before($hisz,' ')"/>
<xsl:variable name="z" select="normalize-space(substring-after($hisz,' '))"/>
<xsl:variable name="offset">
<xsl:choose>
<xsl:when test="$z='GMT' or $z='+0000'">
<xsl:value-of select="'Z'"/>
</xsl:when>
<xsl:when test="string-length($z)=5 and $z!='-0000' and (substring($z,1,1)='-' or substring($z,1,1)='+') and (substring($z,2,1)='0' or substring($z,2,1)='1') and string-length(translate($z,'0123456789',''))=1">
<xsl:value-of select="concat(substring($z,1,3),':',substring($z,4,2))"/>
</xsl:when>
</xsl:choose>
</xsl:variable>
<!-- Validate time and time zone. -->
<xsl:choose>
<xsl:when test="string-length($his)=8 and string-length(translate($his,'0123456789',''))=2 and string-length(translate($his,':',''))=6 and string-length($offset)!=0">
<xsl:element name="{$name}">
<xsl:value-of select="concat($y,'-',format-number($m,'00'),'-',format-number($d,'00'),'T',$his,$offset)"/>
</xsl:element>
</xsl:when>
<xsl:otherwise>
<xsl:comment>
<xsl:value-of select="."/>
</xsl:comment>
</xsl:otherwise>
</xsl:choose>
</xsl:if>
</xsl:if>
</xsl:if>
</xsl:if>
</xsl:if>
</xsl:template>
<xsl:template match="text()"/>
</xsl:stylesheet>