build.gradle

plugins {
    id "java"
    id "maven-publish"
    id "com.jfrog.bintray" version "1.8.4"
    id "org.jetbrains.kotlin.jvm" version "1.3.61"
}

def GROUP_ID = 'com.andreapivetta.kolor'
def ARTIFACT_ID = 'kolor'
def VERSION = '1.0.0'

group GROUP_ID
version VERSION

sourceCompatibility = 1.8

repositories {
    mavenCentral()
}

dependencies {
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8"
    testImplementation "junit:junit:4.13"
}

task sourcesJar(type: Jar, dependsOn: classes) {
    archiveClassifier.set("sources")
    from sourceSets.main.allSource
}

artifacts {
    archives sourcesJar
}

publishing {
    publications {
        MyPublication(MavenPublication) {
            from components.java
            artifact sourcesJar
            groupId GROUP_ID
            artifactId ARTIFACT_ID
            version VERSION
        }
    }
}

bintray {
    user = project.hasProperty('BINTRAY_USER') ? BINTRAY_USER : ''
    key = project.hasProperty('BINTRAY_KEY') ? BINTRAY_KEY : ''
    publications = ['MyPublication']
    pkg {
        repo = ARTIFACT_ID
        name = ARTIFACT_ID
        licenses = ['Apache-2.0']
        vcsUrl = 'https://github.com/ziggy42/kolor.git'
        version {
            name = VERSION
            released = new Date()
        }
    }
}