Max or Min decided by previous column

[jedi1992]

Hi
I have a column of type list and another column which has strings like "Min", "Max" eg

MyTable( my_list :[1,2,3], cmd : "Min");
MyTable( my_list :[1,2,3], cmd : "Max");

So I want the final predicate as
MyFinal(my_val: , my_list:, cmd:) :- where in based on the cmd the correct value should be in my_val . (i.e.) if cmd == "Min" then
my_val Min = (l:- l in my_list)
else if cmd == "Max" then
my_val Max = (l: l in my_list)

How to achieve this.

Thanks

[EvgSkv]

Hello,
it should work as follows:

MyFinal(my_val: , my_list:, cmd:) :-  
  min_val Min= (l:- l in my_list),
  max_val Max= (l :- l in my_list),
  my_val == (if cmd == "Min" then min_val else max_val);

And you can create a function to run over list to make it a little more readable:

Element(l) = x :- x in l;
MyFinal(my_val: , my_list:, cmd:) :-  
  min_val Min= Element(l),
  max_val Max= Element(l),
  my_val == (if cmd == "Min" then min_val else max_val);

Let me know if this helps.

[jedi1992]

In the above example instead of a list assume I have Date, cmd , value as columns

MyTable(date:, cmd:, value:) :- WeatherTable(....) 
# cmd is string "Min"/"Max" , value is single float value and I need to do
# group   by on date and  cmd and fill in the min or max value based on cmd.

MyFinal(Date:, cmd:, val? Max or Min based on cmd  = value)  distinct :- 
                              MyTable(Date:, cmd:, value);

I had taken the round about way of creating a list and the doing Max/Min on it . Just want to see if I can avoid the list creation altogether.How do I achieve this please.

Thanks for the help on the previous question on List , Only hitch there is - are min_val and max_val computed every time and one of them is chosen
OR is it lazily evaluated.

Thanks

[EvgSkv]

Only hitch there is - are min_val and max_val computed every time and one of them is chosen. OR is it lazily evaluated.

It's compiled to SQL's CASE WHEN ... THEN ... so it should be easily evaluated AFAIK.

For the table you could do as follows:

MinOrMax({val:, cmd:}) = (if cmd == "Min" then Min(val) else Max(val));

MyFinal(Date:, cmd:, val? MinOrMax= {val:, cmd:})  distinct :- 
                              MyTable(Date:, cmd:, val:);

Or:

MyFinalMin(date:, cmd: "Min", val? Min= val) distinct :-
  MyTable(date:, cmd: "Min", val:);
MyFinalMax(date:, cmd: "Max", val? Max= val) distinct :-
  MyTable(date:, cmd: "Max", val:);
MyFinal(date:, cmd:, val:) :-
  MyFinalMin(date:, cmd:, val:) |
  MyFinalMax(date:, cmd:, val:);

Let me know if you have further questions.