firedragon: init at 11.15.0-1

pkgs/applications/networking/browsers/firedragon/default.nix

@@ -0,0 +1,91 @@
+{
+ buildMozillaMach,
+ callPackage,
+ fetchurl,
+ lib,
+ pkgs,
+ python311,
+ stdenv,
+}:
+let
+ current = lib.trivial.importJSON ./version.json;
+ packageVersion = current.version;
+in
+(
+ (buildMozillaMach rec {
+ pname = "firedragon";
+ applicationName = "FireDragon";
+ binaryName = "firedragon";
+ branding = "browser/branding/firedragon";
+ requireSigning = false;
+ allowAddonSideload = true;
+
+ inherit packageVersion;
+
+ src = fetchurl {
+ url = "https://gitlab.com/api/v4/projects/55893651/packages/generic/firedragon/${packageVersion}/firedragon-v${packageVersion}.source.tar.zst";
+ inherit (current) hash;
+ };
+
+ # Must match the contents of `browser/config/version.txt` in the source tree
+ version = "115.13.0";
+
+ updateScript = callPackage ./update.nix { };
+
+ extraConfigureFlags = [
+ "--disable-crashreporter"
+ "--disable-debug"
+ "--disable-debug-js-modules"
+ "--disable-debug-symbols"
+ "--disable-default-browser-agent"
+ "--disable-gpsd"
+ "--disable-necko-wifi"
+ "--disable-rust-tests"
+ "--disable-tests"
+ "--disable-updater"
+ "--disable-warnings-as-errors"
+ "--disable-webspeech"
+ "--enable-bundled-fonts"
+ "--enable-jxl"
+ "--enable-private-components"
+ "--enable-proxy-bypass-protection"
+ "--with-app-name=${pname}"
+ "--with-app-basename=${applicationName}"
+ "--with-distribution-id=org.garudalinux"
+ "--with-unsigned-addon-scopes=app,system"
+ ];
+
+ extraNativeBuildInputs = [ pkgs.zstd ];
+
+ meta = {
+ badPlatforms = lib.platforms.darwin;
+ description = "Floorp fork build using custom branding & settings";
+ homepage = "https://gitlab.com/garuda-linux/firedragon";
+ license = lib.licenses.mpl20;
+ maintainers = with lib; [ maintainers.dr460nf1r3 ];
+ broken = stdenv.buildPlatform.is32bit;
+ # since Firefox 60, build on 32-bit platforms fails with "out of memory".
+ # not in `badPlatforms` because cross-compilation on 64-bit machine might work.
+ maxSilent = 14400; # 4h, double the default of 7200s (c.f. #129212, #129115)
+ platforms = lib.platforms.unix;
+ mainProgram = "firedragon";
+ };
+ }).override
+ {
+ crashreporterSupport = false;
+ enableOfficialBranding = false;
+ pgoSupport = true;
+ privacySupport = true;
+ python3 = python311;
+ webrtcSupport = true;
+ }
+).overrideAttrs
+ {
+ MOZ_APP_REMOTINGNAME = "firedragon";
+ MOZ_CRASHREPORTER = "";
+ MOZ_DATA_REPORTING = "";
+ MOZ_SERVICES_HEALTHREPORT = "";
+ MOZ_TELEMETRY_REPORTING = "";
+ OPT_LEVEL = "3";
+ RUSTC_OPT_LEVEL = "3";
+ }

pkgs/applications/networking/browsers/firedragon/update.nix

@@ -0,0 +1,48 @@
+{
+ writeShellScript,
+ lib,
+ coreutils,
+ findutils,
+ gnugrep,
+ gnused,
+ curl,
+ jq,
+ git,
+ nix,
+ moreutils,
+ ...
+}:
+let
+ path = lib.makeBinPath [
+ coreutils
+ curl
+ findutils
+ gnugrep
+ gnused
+ jq
+ moreutils
+ git
+ nix
+ ];
+in
+writeShellScript "update-firedragon" ''
+ set -euo pipefail
+ PATH=${path}
+
+ srcJson=pkgs/firedragon/version.json
+ localVer=$(jq -r .version <$srcJson)
+
+ latestVer=$(curl -s https://gitlab.com/api/v4/projects/55893651/releases/ | jq '.[0].tag_name' -r | sed 's/v//g')
+
+ if [ "$localVer" == "$latestVer" ]; then
+ exit 0
+ fi
+
+ latestSha256=$(nix-prefetch-url --type sha256 "https://gitlab.com/api/v4/projects/55893651/packages/generic/firedragon/$latestVer/firedragon-v$latestVer.source.tar.zst")
+ latestHash=$(nix-hash --to-sri --type sha256 "$latestSha256")
+
+ jq \
+ --arg latestVer "$latestVer" --arg latestHash "$latestHash" \
+ ".version = \$latestVer | .hash = \$latestHash" \
+ "$srcJson" | sponge $srcJson
+''

pkgs/applications/networking/browsers/firedragon/version.json

@@ -0,0 +1,4 @@
+{
+ "version": "11.15.0-1",
+ "hash": "sha256-QoKWjnfH1AKhNWBKt9XhVbvDTL/s7xjLjEZAhtyKPD0="
+}

pkgs/top-level/all-packages.nix

@@ -30622,6 +30622,10 @@ with pkgs;
  libName = "librewolf";
  };
 
+ firedragon-unwrapped = callPackage ../applications/networking/browsers/firedragon {};
+
+ firedragon = wrapFirefox firedragon-unwrapped { libName = "firedragon"; };
+
  firefox_decrypt = python3Packages.callPackage ../tools/security/firefox_decrypt { };
 
  flac = callPackage ../applications/audio/flac { };