Migrate account

Cargo.toml

@@ -3,10 +3,8 @@
 members = [
     "cairo/crates/cairo-lang-casm",
     "cairo/crates/cairo-lang-compiler",
-    "cairo/crates/cairo-lang-utils",
     "cairo/crates/cairo-lang-debug",
     "cairo/crates/cairo-lang-defs",
-    "cairo/crates/cairo-lang-proc-macros",
     "cairo/crates/cairo-lang-diagnostics",
     "cairo/crates/cairo-lang-eq-solver",
     "cairo/crates/cairo-lang-filesystem",
@@ -15,23 +13,25 @@ members = [
     "cairo/crates/cairo-lang-lowering",
     "cairo/crates/cairo-lang-parser",
     "cairo/crates/cairo-lang-plugins",
+    "cairo/crates/cairo-lang-proc-macros",
     "cairo/crates/cairo-lang-project",
     "cairo/crates/cairo-lang-runner",
     "cairo/crates/cairo-lang-semantic",
+    "cairo/crates/cairo-lang-sierra",
     "cairo/crates/cairo-lang-sierra-ap-change",
     "cairo/crates/cairo-lang-sierra-gas",
     "cairo/crates/cairo-lang-sierra-generator",
     "cairo/crates/cairo-lang-sierra-to-casm",
-    "cairo/crates/cairo-lang-sierra",
     "cairo/crates/cairo-lang-starknet",
-    "cairo/crates/cairo-lang-syntax-codegen",
     "cairo/crates/cairo-lang-syntax",
+    "cairo/crates/cairo-lang-syntax-codegen",
     "cairo/crates/cairo-lang-test-runner",
+    "cairo/crates/cairo-lang-utils",
     "cairo/tests",
 ]
 
 [workspace.package]
-version = "1.0.0-alpha.7"
+version = "1.0.0-rc0"
 edition = "2021"
 repository = "https://github.com/starkware-libs/cairo/"
 license = "Apache-2.0"
@@ -45,7 +45,6 @@ assert_matches = "1.5"
 bimap = "0.6.2"
 cairo-felt = "0.3.0-rc1"
 cairo-vm = "0.3.0-rc1"
-chrono = "0.4.23"
 clap = { version = "4.0", features = ["derive"] }
 colored = "2"
 const-fnv1a-hash = "1.1.0"
@@ -60,6 +59,7 @@ ignore = "0.4.20"
 indexmap = { version = "1.9.1", features = ["serde"] }
 indoc = "2.0.1"
 itertools = "0.10.3"
+keccak = "0.1.3"
 lalrpop-util = { version = "0.19.9", features = ["lexer"] }
 log = "0.4"
 lsp = { version = "0.93", package = "lsp-types" }
@@ -84,6 +84,7 @@ test-case = "2.2.2"
 test-case-macros = "2.2.2"
 test-log = "0.2.11"
 thiserror = "1.0.32"
+time = { version = "0.3.20", features = ["formatting", "macros", "local-offset"] }
 tokio = { version = "1.18.2", features = ["full", "sync"] }
 toml = "0.4.2"
 tower-lsp = "0.17.0"

src/openzeppelin/account.cairo

@@ -0,0 +1,201 @@
+use starknet::ContractAddress;
+use openzeppelin::utils::check_gas;
+use openzeppelin::utils::span_to_array;
+
+const ERC165_ACCOUNT_ID: u32 = 0xa66bd575_u32;
+const ERC1271_VALIDATED: u32 = 0x1626ba7e_u32;
+
+const TRANSACTION_VERSION: felt252 = 1;
+// 2**128 + TRANSACTION_VERSION
+const QUERY_VERSION: felt252 = 340282366920938463463374607431768211457;
+
+#[derive(Serde, Drop)]
+struct Call {
+    to: ContractAddress,
+    selector: felt252,
+    calldata: Array<felt252>
+}
+
+#[abi]
+trait IAccount {
+    #[external]
+    fn __execute__(calls: Array<Call>) -> Array<Array<felt252>>;
+    #[external]
+    fn __validate__(calls: Array<Call>) -> felt252;
+    #[external]
+    fn __validate_declare__(class_hash: felt252) -> felt252;
+    #[external]
+    fn __validate_deploy__(
+        class_hash: felt252, contract_address_salt: felt252, _public_key: felt252
+    ) -> felt252;
+    #[external]
+    fn set_public_key(new_public_key: felt252);
+    #[view]
+    fn get_public_key() -> felt252;
+    #[view]
+    fn is_valid_signature(message: felt252, signature: Array<felt252>) -> u32;
+    #[view]
+    fn supports_interface(interface_id: u32) -> bool;
+}
+
+#[account_contract]
+mod Account {
+    use array::SpanTrait;
+    use array::ArrayTrait;
+    use box::BoxTrait;
+    use option::OptionTrait;
+    use zeroable::Zeroable;
+    use ecdsa::check_ecdsa_signature;
+    use serde::ArraySerde;
+    use starknet::get_tx_info;
+    use starknet::get_caller_address;
+    use starknet::get_contract_address;
+
+    use super::Call;
+    use super::ERC165_ACCOUNT_ID;
+    use super::ERC1271_VALIDATED;
+    use super::TRANSACTION_VERSION;
+    use super::QUERY_VERSION;
+    use super::span_to_array;
+
+    use openzeppelin::introspection::erc165::ERC165;
+    use openzeppelin::utils::check_gas;
+
+    //
+    // Storage and Constructor
+    //
+
+    struct Storage {
+        public_key: felt252
+    }
+
+    #[constructor]
+    fn constructor(_public_key: felt252) {
+        ERC165::register_interface(ERC165_ACCOUNT_ID);
+        public_key::write(_public_key);
+    }
+
+    //
+    // Externals
+    //
+
+    // TODO: Use Span in the inner Array of the return type
+    #[external]
+    fn __execute__(mut calls: Array<Call>) -> Array<Array<felt252>> {
+        // avoid calls from other contracts
+        // https://github.com/OpenZeppelin/cairo-contracts/issues/344
+        let sender = get_caller_address();
+        assert(sender.is_zero(), 'Account: invalid caller');
+
+        // check tx version
+        let tx_info = get_tx_info().unbox();
+        let version = tx_info.version;
+        if version != TRANSACTION_VERSION { // > operator not defined for felt252
+            assert(version == QUERY_VERSION, 'Account: invalid tx version');
+        }
+
+        _execute_calls(calls)
+    }
+
+    #[external]
+    fn __validate__(mut calls: Array<Call>) -> felt252 {
+        _validate_transaction()
+    }
+
+    #[external]
+    fn __validate_declare__(class_hash: felt252) -> felt252 {
+        _validate_transaction()
+    }
+
+    #[external]
+    fn __validate_deploy__(
+        class_hash: felt252, contract_address_salt: felt252, _public_key: felt252
+    ) -> felt252 {
+        _validate_transaction()
+    }
+
+    #[external]
+    fn set_public_key(new_public_key: felt252) {
+        _assert_only_self();
+        public_key::write(new_public_key);
+    }
+
+    //
+    // View
+    //
+
+    #[view]
+    fn get_public_key() -> felt252 {
+        public_key::read()
+    }
+
+    #[view]
+    fn is_valid_signature(message: felt252, signature: Array<felt252>) -> u32 {
+        if _is_valid_signature(message, signature.span()) {
+            ERC1271_VALIDATED
+        } else {
+            0_u32
+        }
+    }
+
+    #[view]
+    fn supports_interface(interface_id: u32) -> bool {
+        ERC165::supports_interface(interface_id)
+    }
+
+    //
+    // Internals
+    //
+
+    #[internal]
+    fn _assert_only_self() {
+        let caller = get_caller_address();
+        let self = get_contract_address();
+        assert(self == caller, 'Account: unauthorized');
+    }
+
+    #[internal]
+    fn _validate_transaction() -> felt252 {
+        let tx_info = get_tx_info().unbox();
+        let tx_hash = tx_info.transaction_hash;
+        let signature = tx_info.signature;
+        assert(_is_valid_signature(tx_hash, signature), 'Account: invalid signature');
+        starknet::VALIDATED
+    }
+
+    #[internal]
+    fn _is_valid_signature(message: felt252, signature: Span<felt252>) -> bool {
+        let valid_length = signature.len() == 2_u32;
+
+        valid_length
+            & check_ecdsa_signature(
+                message, public_key::read(), *signature.at(0_u32), *signature.at(1_u32)
+            )
+    }
+
+    #[internal]
+    fn _execute_calls(mut calls: Array<Call>) -> Array<Array<felt252>> {
+        let mut res = ArrayTrait::new();
+        loop {
+            match calls.pop_front() {
+                Option::Some(call) => {
+                    let _res = _execute_single_call(call);
+                    res.append(_res);
+                },
+                Option::None(_) => {
+                    break ();
+                },
+            }
+            check_gas();
+        };
+        res
+    }
+
+    #[internal]
+    fn _execute_single_call(call: Call) -> Array<felt252> {
+        let Call{to, selector, calldata } = call;
+
+        let res = starknet::call_contract_syscall(to, selector, calldata.span()).unwrap_syscall();
+        span_to_array(res)
+    }
+}

src/openzeppelin/lib.cairo

@@ -1,5 +1,6 @@
 mod introspection;
 mod security;
+mod account;
 mod token;
 mod tests;
 mod utils;

src/openzeppelin/tests.cairo

@@ -1,4 +1,5 @@
 mod test_erc165;
+mod test_account;
 mod test_erc20;
 mod test_pausable;
 mod test_initializable;