app-misc/font-manager: 0.8.9

app-misc/font-manager/Manifest

@@ -1,2 +1,3 @@
 DIST font-manager-0.8.7.tar.gz 3231977 BLAKE2B 636c5d8c66f002800e908563b2dbf7d5c6c8092e2ed8eb0583eaee270d02f5ff4c4a01d76dd12b1992859ea085abebed745f83b108e5555ec02c5de9a0e1040b SHA512 1a2cd22b977b1f8ff13b72c53fe6fb12c630a8e9f1753dc76e63fc5936d9b954d62cf62e11f9a3197986e37e9570fc167c9d19605367a14abd3dc83183c5ecce
 DIST font-manager-0.8.8.tar.gz 3284114 BLAKE2B 3d00c048541e98114f2d7fb11f8e8cfabe98b6b0fcc2bab93b0e3917419d2871a566d9798b68b728f4165f9741502e41c489e9bfb55d42f896092a8b78abbd89 SHA512 0849a8988ee3d1c9f34198b25ab14115747ca5cb825f2b48f26d542e20fff7f6583d24c3946e6fc97ca08f44d100a6aa8a10dd8662d90b94c3923341ff2cc3ff
+DIST font-manager-0.8.9.tar.gz 3479197 BLAKE2B d664b6535d588d3cf6b924419ca672669175060634b2a77e89525de1712f601d21787dcd61d213246a3694c6744daaf552ec3bcf334161f73c3de4163a2bcc91 SHA512 deb8023e88cc29f9ed4b764fe80717932d52a15ad74f69b54373c770679f6bebd6cf42eb7044d1abe16d60b45193b34b3031e5e1f06bd4f3ef75ec22f6a57580

app-misc/font-manager/font-manager-0.8.9.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+EMESON_BUILDTYPE=release
+
+inherit gnome2 meson vala
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/FontManager/font-manager.git"
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/FontManager/font-manager/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="A simple font management application for Gtk+ Desktop Environments"
+HOMEPAGE="https://fontmanager.github.io"
+
+VALA_MIN_API_VERSION=0.44
+VALA_USE_DEPEND="vapigen"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="doc gnome-search-provider google-fonts +manager nautilus nemo reproducible thunar +viewer +nls"
+
+RDEPEND="gnome-base/gnome-common
+	>=dev-db/sqlite-3.8
+	>=dev-libs/json-glib-0.15
+	>=dev-libs/libxml2-2.9
+	>=media-libs/fontconfig-2.12
+	>=media-libs/freetype-2.5
+	>=x11-libs/gtk+-3.22
+	>=x11-libs/pango-1.4
+	google-fonts? (
+		>=net-libs/libsoup-2.62
+		>=net-libs/webkit-gtk-2.24
+	)
+	nautilus? ( gnome-base/nautilus )
+	nemo? ( gnome-extra/nemo )
+	thunar? ( xfce-base/thunar )
+"
+
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	doc? (
+		app-text/yelp-tools
+		dev-util/gtk-doc
+	)
+"
+
+src_prepare() {
+	default
+	vala_setup
+	gnome2_src_prepare
+}
+
+src_configure() {
+	meson_src_configure \
+		$(meson_use manager) \
+		$(meson_use viewer) \
+		$(meson_use reproducible) \
+		$(meson_use nautilus) \
+		$(meson_use nemo) \
+		$(meson_use thunar) \
+		$(meson_use gnome-search-provider search-provider) \
+		$(meson_use google-fonts webkit) \
+		$(meson_use nls enable-nls) \
+		$(meson_use doc yelp-doc) \
+		$(meson_use doc gtk-doc)
+}