-
Notifications
You must be signed in to change notification settings - Fork 736
Commit
This commit does not belong to any branch on this repository, and may belong to a fork outside of the repository.
* Add Ammo cookoff * Remove tabs * Add initial ammo box cook-off Does not include a fire effect, mostly just a proof of concept. Should probably also add further potential cook-off conditons (if hit by tracer for example). * Add burning effects to ammo box cook off - Add burning effect while ammo box is cooking off - Add setting to enable/disable ammo boxes cooking off - Clear magazine cargo while box is burning Currently the box will burn for 60 seconds hardcoded, this is to allow time for the ammunition to cook off (since boxes sink into the ground and dissapear when destroyed). Perhaps we can implement a way to burn until all ammo is expended. * Improve ammo cookoff * Integrate ammo cookoff with the incendiary grenade * Disable ammo cook off underwater * Optimize fnc_detonateAmmunition I say optimize, the only real performance optimization is using `vectorMultiply`. The rest is readability optimization though! * Improve ammo box cook off - Remove unnecessary light source (fire particles provide lighting) - Add randomness to cook off time - Cook off begins with fire effect rather than smoke * Add tracer induced ammo box cook off Due to limitations in the way arma handles tracer rounds (there's no way to check if an individual projectile is a tracer), only magazines with a high enough tracer density (at least 1 in 4) can cause cook off this way. However this is deemed an acceptable approximation since the chance of this happening should be quite low anyway. * Decrease amount of explosions from ammo cookoff * Add is local check for remote event
- Loading branch information
Showing
18 changed files
with
342 additions
and
16 deletions.
There are no files selected for viewing
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
Original file line number | Diff line number | Diff line change |
---|---|---|
@@ -0,0 +1,33 @@ | ||
class CfgAmmo { | ||
class ShellBase; | ||
class ace_ammoExplosion: ShellBase { | ||
hit = 10; | ||
indirectHit = 0.5; | ||
indirectHitRange = 1; | ||
soundHit[] = {"", 1, 1, 0}; | ||
typicalSpeed = 100; | ||
explosive = 0; | ||
cost = 300; | ||
model = "\A3\Weapons_F\empty.p3d"; | ||
airFriction = 0; | ||
timeToLive = 1; | ||
explosionTime = 0.001; | ||
soundFly[] = {"",1,1}; | ||
soundEngine[] = {"",1,4}; | ||
explosionEffects = "ExploAmmoExplosion"; | ||
}; | ||
|
||
class SmallSecondary; | ||
class ACE_ammoExplosionLarge: SmallSecondary { | ||
soundHit[] = {"", 1, 1, 0}; | ||
model = "\A3\Weapons_F\empty.p3d"; | ||
soundFly[] = {"",1,1}; | ||
soundEngine[] = {"",1,4}; | ||
soundHit1[] = {"",1,1,1}; | ||
soundHit2[] = {"",1,1,1}; | ||
soundHit3[] = {"",1,1,1}; | ||
supersonicCrackFar[] = {"",1,1,1}; | ||
supersonicCrackNear[] = {"",1,1,1}; | ||
craterEffects = "ImpactEffectsMedium"; | ||
}; | ||
}; |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
Original file line number | Diff line number | Diff line change |
---|---|---|
@@ -0,0 +1,75 @@ | ||
/* | ||
* Author: KoffeinFlummi, commy2, SilentSpike | ||
* Start a cook-off in the given ammo box. | ||
* | ||
* Arguments: | ||
* 0: Ammo box <OBJECT> | ||
* | ||
* Return Value: | ||
* None | ||
* | ||
* Example: | ||
* [_box] call ace_cookoff_fnc_cookOffBox | ||
* | ||
* Public: No | ||
*/ | ||
#include "script_component.hpp" | ||
|
||
params ["_box"]; | ||
|
||
if (_box getVariable [QGVAR(isCookingOff), false]) exitWith {}; | ||
_box setVariable [QGVAR(isCookingOff), true]; | ||
|
||
if (local _vehicle) then { | ||
[QGVAR(cookOffBox), _box] call CBA_fnc_remoteEvent; | ||
}; | ||
|
||
[{ | ||
params ["_box"]; | ||
|
||
// Box will start smoking | ||
private _smoke = "#particlesource" createVehicleLocal [0,0,0]; | ||
_smoke setParticleClass "AmmoSmokeParticles2"; | ||
_smoke attachTo [_box, [0,0,0]]; | ||
|
||
private _effects = [_smoke]; | ||
|
||
if (isServer) then { | ||
private _sound = createSoundSource ["Sound_Fire", position _box, [], 0]; | ||
_effects pushBack _sound; | ||
}; | ||
|
||
[{ | ||
params ["_box", "_effects"]; | ||
|
||
// These functions are smart and do all the cooking off work | ||
if (local _box) then { | ||
_box call FUNC(secondaryExplosions); | ||
if (_box getVariable [QGVAR(enableAmmoCookoff), GVAR(enableAmmoCookoff)]) then { | ||
[_box, magazinesAmmo _box] call FUNC(detonateAmmunition); | ||
}; | ||
|
||
// This shit is busy being on fire, magazines aren't accessible/usable | ||
clearMagazineCargoGlobal _box; | ||
}; | ||
|
||
// Light the fire (also handles lighting) | ||
private _fire = "#particlesource" createVehicleLocal [0,0,0]; | ||
_fire setParticleClass "AmmoBulletCore"; | ||
_fire attachTo [_box, [0,0,0]]; | ||
|
||
_effects pushBack _fire; | ||
|
||
[{ | ||
params ["_box", "_effects"]; | ||
|
||
{ | ||
deleteVehicle _x; | ||
} forEach _effects; | ||
|
||
if (local _box) then { | ||
_box setDamage 1; | ||
}; | ||
}, [_box, _effects], 45 + random 75] call CBA_fnc_waitAndExecute; // Give signifcant time for ammo cookoff to occur (perhaps keep the box alive until all cooked off?) | ||
}, [_box, _effects], 3 + random 15] call CBA_fnc_waitAndExecute; | ||
}, _box, 0.5 + random 5] call CBA_fnc_waitAndExecute; |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
Original file line number | Diff line number | Diff line change |
---|---|---|
@@ -0,0 +1,112 @@ | ||
/* | ||
* Author: Glowbal | ||
* Detonates ammunition from a vehicle until no ammo left | ||
* | ||
* Arguments: | ||
* 0: vehicle <OBJECT> | ||
* | ||
* Return Value: | ||
* None | ||
* | ||
* Example: | ||
* [_vehicle, magazinesAmmo _vehicle] call ace_cookoff_fnc_detonateAmmunition | ||
* | ||
* Public: No | ||
*/ | ||
#include "script_component.hpp" | ||
#define MAX_TIME_BETWEEN_AMMO_DET 25 | ||
|
||
params ["_vehicle", "_magazines"]; | ||
|
||
if (isNull _vehicle) exitWith {}; // vehicle got deleted | ||
if (_magazines isEqualTo []) exitWith {}; // nothing to detonate anymore | ||
if (underwater _vehicle) exitWith {}; | ||
|
||
private _magazineIndex = floor random(count _magazines); | ||
private _magazine = _magazines select _magazineIndex; | ||
_magazine params ["_magazineClassname", "_amountOfMagazines"]; | ||
|
||
if (_amountOfMagazines > 0) exitWith { | ||
private _newMagCount = _amountOfMagazines - floor(1 + random(6)); | ||
if (_newMagCount <= 0) then { | ||
_magazines deleteAt _magazineIndex; | ||
} else { | ||
_magazine set [1, _newMagCount]; // clear out the magazine | ||
}; | ||
private _ammo = getText (configFile >> "CfgMagazines" >> _magazineClassname >> "ammo"); | ||
|
||
private _timeBetweenAmmoDetonation = (random 7) * (1 / random (_amountOfMagazines)) min MAX_TIME_BETWEEN_AMMO_DET; | ||
_timeBetweenAmmoDetonation = _timeBetweenAmmoDetonation max 0.1; | ||
|
||
private _speedOfAmmo = getNumber (configFile >> "CfgMagazines" >> _magazineClassname >> "initSpeed"); | ||
private _simulationTime = getNumber (configFile >> "CfgAmmo" >> _ammo >> "simulation"); | ||
private _caliber = getNumber (configFile >> "CfgAmmo" >> _ammo >> "caliber"); | ||
private _simType = getText (configFile >> "CfgAmmo" >> _ammo >> "simulation"); | ||
|
||
private _effect2pos = _vehicle selectionPosition "destructionEffect2"; | ||
|
||
private _spawnProjectile = { | ||
params ["_vehicle", "_ammo", "_speed", "_flyAway"]; | ||
|
||
private _spawnPos = _vehicle modelToWorld [-0.2 + (random 0.4), -0.2 + (random 0.4), random 3]; | ||
if (_spawnPos select 2 < 0) then { | ||
_spawnPos set [2, 0]; | ||
}; | ||
private _projectile = _ammo createVehicle [0,0,0]; | ||
_projectile setPos _spawnPos; | ||
if (_flyAway) then { | ||
private _vectorAmmo = [(-1 + (random 2)), (-1 + (random 2)), -0.2 + (random 1)]; | ||
private _velVec = _vectorAmmo vectorMultiply _speed; | ||
_projectile setVectorDir _velVec; | ||
_projectile setVelocity _velVec; | ||
[ACE_player, _projectile, [1,0,0,1]] call EFUNC(frag,addTrack); | ||
} else { | ||
_projectile setDamage 1; | ||
}; | ||
|
||
_projectile; | ||
}; | ||
|
||
private _speed = random (_speedOfAmmo / 10) max 1; | ||
|
||
if (toLower _simType == "shotbullet") then { | ||
private _sound = selectRandom [QUOTE(PATHTO_R(sounds\light_crack_close.wss)), QUOTE(PATHTO_R(sounds\light_crack_close_filtered.wss)), QUOTE(PATHTO_R(sounds\heavy_crack_close.wss)), QUOTE(PATHTO_R(sounds\heavy_crack_close_filtered.wss))]; | ||
playSound3D [_sound, objNull, false, (getPosASL _vehicle), 2, 1, 1250]; | ||
|
||
if (random 1 < 0.6) then { | ||
[_vehicle, _ammo, _speed, true] call _spawnProjectile; | ||
}; | ||
}; | ||
if (toLower _simType == "shotshell") then { | ||
private _sound = selectRandom [QUOTE(PATHTO_R(sounds\heavy_crack_close.wss)), QUOTE(PATHTO_R(sounds\heavy_crack_close_filtered.wss))]; | ||
playSound3D [_sound, objNull, false, (getPosASL _vehicle), 2, 1, 1300]; | ||
|
||
if (random 1 < 0.15) then { | ||
[_vehicle, _ammo, _speed, random 1 < 0.15] call _spawnProjectile; | ||
}; | ||
}; | ||
if (toLower _simType == "shotgrenade") then { | ||
if (random 1 < 0.9) then { | ||
_speed = 0; | ||
}; | ||
[_vehicle, _ammo, _speed, random 1 < 0.5] call _spawnProjectile; | ||
}; | ||
if (toLower _simType == "shotrocket" || {toLower _simType == "shotmissile"}) then { | ||
if (random 1 < 0.1) then { | ||
private _sound = selectRandom [QUOTE(PATHTO_R(sounds\cannon_crack_close.wss)), QUOTE(PATHTO_R(sounds\cannon_crack_close_filtered.wss))]; | ||
playSound3D [_sound, objNull, false, (getPosASL _vehicle), 3, 1, 1600]; | ||
|
||
[_vehicle, _ammo, _speed, random 1 < 0.3] call _spawnProjectile; | ||
} else { | ||
"ACE_ammoExplosionLarge" createvehicle (_vehicle modelToWorld _effect2pos); | ||
}; | ||
}; | ||
if (toLower _simType in ["shotdirectionalbomb", "shotilluminating", "shotmine"]) then { | ||
if (random 1 < 0.5) then { | ||
[_vehicle, _ammo, 0, false] call _spawnProjectile; | ||
}; | ||
}; | ||
|
||
[FUNC(detonateAmmunition), [_vehicle, _magazines], _timeBetweenAmmoDetonation] call CBA_fnc_waitAndExecute; | ||
}; | ||
[FUNC(detonateAmmunition), [_vehicle, _magazines], random 3] call CBA_fnc_waitAndExecute; |
Oops, something went wrong.