Mock sub select query (addQueryFactorySubselect to ChildAccounts)

[lukethacoder]

Is there a way to mock the response of this selector method with ChildAccounts populated?

I feel like I'm missing some sort of mock for the addQueryFactorySubselect method?

// AccountSelector
public List<Account> selectById(Set<Id> idSet) {
  if (idSet.isEmpty()) {
    return new List<Account>();
  }

  fflib_QueryFactory qf = getQueryFactory();
  qf.selectFields(getSObjectFieldListWithRelatedFields());
  qf.setCondition('Id IN :idSet');

  new AccountSelector().addQueryFactorySubselect(qf,'ChildAccounts');

  return Database.query(qf.toSOQL());
}

---

SObject record

throws an error of Field is not writeable: Account.ChildAccounts

Account accountRecord = new Account(
  Id = fflib_IDGenerator.generate(Account.SObjectType),
  ChildAccounts = new List<Account>{
    new Account(
      Id = fflib_IDGenerator.generate(Account.SObjectType),
      Name = 'Child Account'
    )
  }
);

SObject record (via put)

throws an error of System.SObjectException: Invalid field ChildAccounts for Account

Account accountRecord = new Account(
  Id = fflib_IDGenerator.generate(Account.SObjectType)
);
accountRecord.put(
  'ChildAccounts',
  new List<Account>{
    new Account(
      Id = fflib_IDGenerator.generate(Account.SObjectType),
      Name = 'Child Account'
    )
  }
);

SObject record (via putSObject)

does not even deploy as putSObject expects a single SObject, not a list of them.

Account accountRecord = new Account(
  Id = fflib_IDGenerator.generate(Account.SObjectType)
);
accountRecord.putSObject(
  'ChildAccounts',
  new List<Account>{
    new Account(
      Id = fflib_IDGenerator.generate(Account.SObjectType),
      Name = 'Child Account'
    )
  }
);

SObject record (via serialize/deserialize)

throws an error of System.JSONException: QueryResult must start with '{'

Map<String, SObject[]> newSObject = new Map<String, SObject[]>();
newSObject.put(
  'ChildAccounts',
  new List<SObject>{ 
    new Account(
      Id = fflib_IDGenerator.generate(Account.SObjectType),
      Name = 'Child Account'
    ) 
  }
);

String accountAsString = JSON.serialize(newSObject);
Account accountRecord = (Account)JSON.deserialize(accountAsString, Account.class);

[stohn777]

Hi @lukethacoder,

I believe the serialization route is the better path to pursue. However, pull a native Account list having child Accounts from Salesforce, serialize and inspect. The ChildAccounts JSON property has some extra information to synthesize, including "totalSize", "done" and "records". The latter containing the serialized, children list.

Here's a fairly simple, native serialization that I pulled:

[ {
  "attributes" : {
    "type" : "Account",
    "url" : "/services/data/v55.0/sobjects/Account/0012200000bJ0myAAC"
  },
  "Id" : "0012200000bJ0myAAC",
  "Name" : "Acme",
  "ChildAccounts" : {
    "totalSize" : 2,
    "done" : true,
    "records" : [ {
      "attributes" : {
        "type" : "Account",
        "url" : "/services/data/v55.0/sobjects/Account/0012200000bJ0mzAAC"
      },
      "ParentId" : "0012200000bJ0myAAC",
      "Id" : "0012200000bJ0mzAAC",
      "Name" : "Acme Child 1"
    }, {
      "attributes" : {
        "type" : "Account",
        "url" : "/services/data/v55.0/sobjects/Account/0012200000bJ0n0AAC"
      },
      "ParentId" : "0012200000bJ0myAAC",
      "Id" : "0012200000bJ0n0AAC",
      "Name" : "Acme Child 2"
    } ]
  }
} ]

[lukethacoder]

sneaky extra params breaking my serialization, thanks @stohn777

[stohn777]

Also @lukethacoder, I was reminded by @ImJohnMDaniel that the fflib_ApexMocksUtils.makeRelationship(Type parentsType, List parents, SObjectField relationshipField, List<List> children) method that will do all of the work for you.