Update python-cffsubr-git

archlinuxcn/python-cffsubr-git/PKGBUILD

@@ -0,0 +1,39 @@
+# Maintainer: taotieren <admin@taotieren.com>
+
+pkgname=python-cffsubr-git
+pkgver=0.2.9.post1.r0.g5999ae5
+pkgrel=1
+pkgdesc='Standalone CFF subroutinizer based on AFDKO tx'
+url='https://github.com/adobe-type-tools/cffsubr'
+license=('Apache')
+arch=(any)
+depends=(python
+         python-fonttools)
+makedepends=(python-setuptools-git-ls-files
+             python-setuptools-scm)
+checkdepends=(python-pytest)
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("$pkgname::git+$url.git")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "$pkgname"
+    git describe --long --tags | sed 's/^v//g;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+    cd "$pkgname"
+    python -m build -wn
+}
+
+check() {
+    cd "$pkgname"
+    PYTHONPATH=src pytest tests
+}
+
+package() {
+    cd "$pkgname"
+    python -m installer -d "$pkgdir" dist/*.whl
+}
+

archlinuxcn/python-cffsubr-git/lilac.yaml

@@ -0,0 +1,13 @@
+maintainers:
+  - github: taotieren
+
+build_prefix: archlinuxcn-x86_64
+
+pre_build: vcs_update
+
+post_build_script: |
+  git_pkgbuild_commit()
+
+update_on:
+  - source: github
+    github: adobe-type-tools/cffsubr