test: add e2e test which uses copy_to_directory within an external …

…workspace

Refs #359.

This should catch regressions where no files are copied when built within an external workspace and not using `include_external_repositories`.

.github/workflows/ci.yaml

@@ -90,7 +90,9 @@ jobs:
           - "."
           - "e2e/coreutils"
           - "e2e/copy_to_directory"
+          - "e2e/external_copy_to_directory/workspace"
           - "e2e/smoke"
+          - "e2e/workspace"
         exclude:
           # Don't test Bazel 5.3 with bzlmod. (Unrecognized option: --enable_bzlmod)
           - bzlmodEnabled: true

e2e/external_copy_to_directory/.bazelignore

@@ -0,0 +1 @@
+app/

e2e/external_copy_to_directory/.bazelversion

@@ -0,0 +1 @@
+../../.bazelversion

e2e/external_copy_to_directory/BUILD.bazel

@@ -0,0 +1,13 @@
+load("@bazel_skylib//rules:build_test.bzl", "build_test")
+load(":directory.bzl", "directory")
+
+directory(
+    name = "dir",
+    srcs = ["foo.txt"],
+    visibility = ["//visibility:public"],
+)
+
+build_test(
+    name = "test",
+    targets = [":dir"],
+)

e2e/external_copy_to_directory/WORKSPACE

@@ -0,0 +1,28 @@
+workspace(name = "external_copy_to_directory")
+
+local_repository(
+    name = "aspect_bazel_lib",
+    path = "../..",
+)
+
+load("@aspect_bazel_lib//:internal_deps.bzl", "bazel_lib_internal_deps")
+
+bazel_lib_internal_deps()
+
+load("@aspect_bazel_lib//lib:repositories.bzl", "aspect_bazel_lib_dependencies")
+
+aspect_bazel_lib_dependencies()
+
+load("@aspect_bazel_lib//:deps.bzl", "go_dependencies")
+
+go_dependencies()
+
+load("@io_bazel_rules_go//go:deps.bzl", "go_register_toolchains", "go_rules_dependencies")
+
+go_rules_dependencies()
+
+go_register_toolchains(version = "1.18.3")
+
+load("@bazel_gazelle//:deps.bzl", "gazelle_dependencies")
+
+gazelle_dependencies()

e2e/external_copy_to_directory/app/.bazelversion

@@ -0,0 +1 @@
+../../../.bazelversion

e2e/external_copy_to_directory/app/BUILD.bazel

@@ -0,0 +1,6 @@
+sh_test(
+    name = "test",
+    srcs = ["test.sh"],
+    data = ["@external_copy_to_directory//:dir"],
+    deps = ["@bazel_tools//tools/bash/runfiles"],
+)

e2e/external_copy_to_directory/app/WORKSPACE

@@ -0,0 +1,31 @@
+local_repository(
+    name = "external_copy_to_directory",
+    path = "..",
+)
+
+local_repository(
+    name = "aspect_bazel_lib",
+    path = "../../..",
+)
+
+load("@aspect_bazel_lib//:internal_deps.bzl", "bazel_lib_internal_deps")
+
+bazel_lib_internal_deps()
+
+load("@aspect_bazel_lib//lib:repositories.bzl", "aspect_bazel_lib_dependencies")
+
+aspect_bazel_lib_dependencies()
+
+load("@aspect_bazel_lib//:deps.bzl", "go_dependencies")
+
+go_dependencies()
+
+load("@io_bazel_rules_go//go:deps.bzl", "go_register_toolchains", "go_rules_dependencies")
+
+go_rules_dependencies()
+
+go_register_toolchains(version = "1.18.3")
+
+load("@bazel_gazelle//:deps.bzl", "gazelle_dependencies")
+
+gazelle_dependencies()

e2e/external_copy_to_directory/app/test.sh

@@ -0,0 +1,19 @@
+# --- begin runfiles.bash initialization v2 ---
+# Copy-pasted from the Bazel Bash runfiles library v2.
+set -uo pipefail; set +e; f=bazel_tools/tools/bash/runfiles/runfiles.bash
+source "${RUNFILES_DIR:-/dev/null}/$f" 2>/dev/null || \
+  source "$(grep -sm1 "^$f " "${RUNFILES_MANIFEST_FILE:-/dev/null}" | cut -f2- -d' ')" 2>/dev/null || \
+  source "$0.runfiles/$f" 2>/dev/null || \
+  source "$(grep -sm1 "^$f " "$0.runfiles_manifest" | cut -f2- -d' ')" 2>/dev/null || \
+  source "$(grep -sm1 "^$f " "$0.exe.runfiles_manifest" | cut -f2- -d' ')" 2>/dev/null || \
+  { echo>&2 "ERROR: cannot find $f"; exit 1; }; f=; set -e
+# --- end runfiles.bash initialization v2 ---
+
+# Read external directory and make sure it exists with a file.
+readonly DIR=$(rlocation external_copy_to_directory/dir/)
+readonly FILES=$(ls "${DIR}" | wc -l)
+if [[ ${FILES} != 1 ]]; then
+  echo "Expected exactly 1 file under external directory, but found ${FILES}:" >&2
+  ls "${DIR}" >&2
+  exit 1
+fi

e2e/external_copy_to_directory/directory.bzl

@@ -0,0 +1,36 @@
+"""Test rule executing `copy_to_directory_bin_action`."""
+
+load("@aspect_bazel_lib//lib:copy_to_directory.bzl", "copy_to_directory_bin_action")
+
+def _directory_impl(ctx):
+    dst = ctx.actions.declare_directory(ctx.attr.name)
+
+    copy_to_directory_bin_action(
+        ctx,
+        name = ctx.attr.name,
+        copy_to_directory_bin = ctx.executable._tool,
+        dst = dst,
+        files = ctx.files.srcs,
+        verbose = True,
+    )
+
+    return DefaultInfo(files = depset([dst]))
+
+directory = rule(
+    implementation = _directory_impl,
+    attrs = {
+        "srcs": attr.label_list(
+            mandatory = True,
+            allow_files = True,
+        ),
+        "_tool": attr.label(
+            executable = True,
+            cfg = "exec",
+            default = "@aspect_bazel_lib//tools/copy_to_directory",
+        ),
+    },
+    doc = """
+        Copies the given source files to a directory with
+        `copy_to_directory_bin_action()`.
+    """,
+)

e2e/external_copy_to_directory/foo.txt

@@ -0,0 +1 @@
+foo