Add c:JSONAPI.View.get_field/3

lib/jsonapi/view.ex

@@ -73,6 +73,21 @@ defmodule JSONAPI.View do
   In order to use [sparse fieldsets](https://jsonapi.org/format/#fetching-sparse-fieldsets)
   you must include the `JSONAPI.QueryParser` plug.
 
+  If you want to fetch fields from the given data *dynamically*, you can use the
+  `c:get_field/3` callback.
+
+      defmodule UserView do
+        use JSONAPI.View
+
+        def fields, do: [:id, :username, :email]
+
+        def type, do: "user"
+
+        def get_field(field, data, _conn) do
+          Map.fetch!(data, field)
+        end
+      end
+
   ## Relationships
 
   Currently the relationships callback expects that a map is returned
@@ -127,6 +142,7 @@ defmodule JSONAPI.View do
   @callback attributes(data(), Conn.t() | nil) :: map()
   @callback id(data()) :: resource_id() | nil
   @callback fields() :: [field()]
+  @callback get_field(field(), data(), Conn.t()) :: any()
   @callback hidden(data()) :: [field()]
   @callback links(data(), Conn.t()) :: links()
   @callback meta(data(), Conn.t()) :: meta() | nil
@@ -141,6 +157,8 @@ defmodule JSONAPI.View do
   @callback url_for_rel(term(), String.t(), Conn.t() | nil) :: String.t()
   @callback visible_fields(data(), Conn.t() | nil) :: list(atom)
 
+  @optional_callbacks [get_field: 3]
+
   defmacro __using__(opts \\ []) do
     {type, opts} = Keyword.pop(opts, :type)
     {namespace, opts} = Keyword.pop(opts, :namespace)
@@ -168,9 +186,15 @@ defmodule JSONAPI.View do
 
         Enum.reduce(visible_fields, %{}, fn field, intermediate_map ->
           value =
-            case function_exported?(__MODULE__, field, 2) do
-              true -> apply(__MODULE__, field, [data, conn])
-              false -> Map.get(data, field)
+            cond do
+              function_exported?(__MODULE__, field, 2) ->
+                apply(__MODULE__, field, [data, conn])
+
+              function_exported?(__MODULE__, :get_field, 3) ->
+                apply(__MODULE__, :get_field, [field, data, conn])
+
+              true ->
+                Map.get(data, field)
             end
 
           Map.put(intermediate_map, field, value)

test/jsonapi/view_test.exs

@@ -43,6 +43,18 @@ defmodule JSONAPI.ViewTest do
     use JSONAPI.View, type: "cars", namespace: ""
   end
 
+  defmodule DynamicView do
+    use JSONAPI.View
+
+    def type, do: "dyns"
+
+    def fields, do: [:static_fun, :static_field, :dynamic_1, :dynamic_2]
+
+    def static_fun(_data, _conn), do: "static_fun/2"
+
+    def get_field(field, _data, _conn), do: "#{field}!"
+  end
+
   setup do
     Application.put_env(:jsonapi, :field_transformation, :underscore)
     Application.put_env(:jsonapi, :namespace, "/other-api")
@@ -290,4 +302,16 @@ defmodule JSONAPI.ViewTest do
 
     assert %{body: "Chunky"} == PostView.attributes(data, conn)
   end
+
+  test "attributes/2 can return dynamic fields" do
+    data = %{static_field: "static_field from the map"}
+    conn = %Plug.Conn{assigns: %{jsonapi_query: %JSONAPI.Config{}}}
+
+    assert %{
+             dynamic_1: "dynamic_1!",
+             dynamic_2: "dynamic_2!",
+             static_field: "static_field!",
+             static_fun: "static_fun/2"
+           } == DynamicView.attributes(data, conn)
+  end
 end