feat: add BatchBadDebtRepay steward contract

.gitignore

@@ -12,3 +12,7 @@ docs/
 
 # Dotenv file
 .env
+
+.vscode
+
+node_modules

.gitmodules

@@ -1,3 +1,9 @@
 [submodule "lib/aave-helpers"]
 	path = lib/aave-helpers
 	url = https://github.com/bgd-labs/aave-helpers
+[submodule "lib/aave-address-book"]
+	path = lib/aave-address-book
+	url = https://github.com/bgd-labs/aave-address-book
+[submodule "lib/solidity-utils"]
+	path = lib/solidity-utils
+	url = https://github.com/bgd-labs/solidity-utils

.prettierignore

@@ -0,0 +1,4 @@
+out
+lib
+cache
+node_modules

.prettierrc

@@ -0,0 +1,24 @@
+{
+  "overrides": [
+    {
+      "files": "*.sol",
+      "options": {
+        "printWidth": 100,
+        "tabWidth": 2,
+        "useTabs": false,
+        "singleQuote": true,
+        "bracketSpacing": false
+      }
+    },
+    {
+      "files": "*.ts",
+      "options": {
+        "printWidth": 100,
+        "tabWidth": 2,
+        "useTabs": false,
+        "singleQuote": true,
+        "bracketSpacing": false
+      }
+    }
+  ]
+}

foundry.toml

@@ -1,6 +1,7 @@
 [profile.default]
 src = "src"
 out = "out"
+test = "tests"
 libs = ["lib"]
 
 # See more config options https://github.com/foundry-rs/foundry/blob/master/crates/config/README.md#all-options

package.json

@@ -0,0 +1,23 @@
+{
+  "name": "aave-stewards",
+  "version": "1.0.0",
+  "scripts": {
+    "lint": "prettier . --check",
+    "lint:fix": "prettier . --write"
+  },
+  "repository": {
+    "type": "git",
+    "url": "git+https://github.com/bgd-labs/aave-stewards.git"
+  },
+  "author": "BGD Labs for Aave",
+  "license": "BUSL-1.1",
+  "bugs": {
+    "url": "https://github.com/bgd-labs/aave-stewards/issues"
+  },
+  "homepage": "https://github.com/bgd-labs/aave-stewards#readme",
+  "type": "module",
+  "dependencies": {
+    "prettier": "^3.4.2",
+    "prettier-plugin-solidity": "^1.4.2"
+  }
+}

src/maintenance/BatchRepayBadDebtSteward.sol

@@ -0,0 +1,85 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import {IPool, DataTypes} from 'aave-address-book/AaveV3.sol';
+import {IERC20} from 'solidity-utils/contracts/oz-common/interfaces/IERC20.sol';
+import {SafeERC20} from 'solidity-utils/contracts/oz-common/SafeERC20.sol';
+
+import {IBatchRepayBadDebtSteward} from './interfaces/IBatchRepayBadDebtSteward.sol';
+
+/// @title BatchRepayBadDebtSteward
+/// @author BGD Labs
+/// @notice This contract allows to repay all the bad debt of a list of users
+/// @dev Only allowed those users that have some debt and doesn't have any collateral
+contract BatchRepayBadDebtSteward is IBatchRepayBadDebtSteward {
+  using SafeERC20 for IERC20;
+
+  /* PUBLIC GLOBAL VARIABLES */
+
+  /// @inheritdoc IBatchRepayBadDebtSteward
+  IPool public immutable override POOL;
+
+  /* CONSTRUCTOR */
+
+  constructor(address _pool) {
+    POOL = IPool(_pool);
+  }
+
+  /* EXTERNAL FUNCTIONS */
+
+  /// @inheritdoc IBatchRepayBadDebtSteward
+  function batchRepayBadDebt(address asset, address[] memory users) external override {
+    (uint256 totalDebtAmount, uint256[] memory debtAmounts) = getBadDebtAmount(asset, users);
+
+    IERC20(asset).safeTransferFrom(msg.sender, address(this), totalDebtAmount);
+    IERC20(asset).forceApprove(address(POOL), totalDebtAmount);
+
+    uint256 length = users.length;
+    for (uint256 i = 0; i < length; i++) {
+      POOL.repay({asset: asset, amount: debtAmounts[i], interestRateMode: 2, onBehalfOf: users[i]});
+
+      emit UserBadDebtRepaid({user: users[i], asset: asset, amount: debtAmounts[i]});
+    }
+  }
+
+  /* PUBLIC VIEW FUNCTIONS */
+
+  /// @inheritdoc IBatchRepayBadDebtSteward
+  function getBadDebtAmount(
+    address asset,
+    address[] memory users
+  ) public view override returns (uint256, uint256[] memory) {
+    uint256 length = users.length;
+
+    uint256 totalDebtAmount;
+    uint256[] memory debtAmounts = new uint256[](length);
+
+    DataTypes.ReserveDataLegacy memory reserveData = POOL.getReserveData(asset);
+
+    for (uint256 i = 0; i < length; i++) {
+      address user = users[i];
+
+      for (uint256 j = i + 1; j < length; j++) {
+        if (user == users[j]) {
+          revert UsersShouldBeDifferent(user);
+        }
+      }
+
+      (uint256 totalCollateralBase, uint256 totalDebtBase, , , , ) = POOL.getUserAccountData(user);
+
+      if (totalCollateralBase > 0) {
+        revert UserHasSomeCollateral(user);
+      }
+
+      if (totalDebtBase == 0) {
+        revert UserHasNoDebt(user);
+      }
+
+      totalDebtAmount += debtAmounts[i] = IERC20(reserveData.variableDebtTokenAddress).balanceOf(
+        user
+      );
+    }
+
+    return (totalDebtAmount, debtAmounts);
+  }
+}

src/maintenance/interfaces/IBatchRepayBadDebtSteward.sol

@@ -0,0 +1,54 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import {IPool} from 'aave-address-book/AaveV3.sol';
+
+interface IBatchRepayBadDebtSteward {
+  /* EVENTS */
+
+  /// @notice Emitted when a user has been repaid his bad debt
+  /// @param user The address of the user
+  /// @param asset The address of the asset
+  /// @param amount The amount repaid
+  event UserBadDebtRepaid(address indexed user, address indexed asset, uint256 amount);
+
+  /* ERRORS */
+
+  /// @notice Thrown when a user has some collateral
+  /// @param user The address of the user
+  error UserHasSomeCollateral(address user);
+
+  /// @notice Thrown when a user has no debt
+  /// @param user The address of the user
+  error UserHasNoDebt(address user);
+
+  /// @notice Thrown when an array contains two users with the same address
+  /// @param user The address of the user
+  error UsersShouldBeDifferent(address user);
+
+  /* GLOBAL VARIABLES */
+
+  /// @notice The Aave pool
+  function POOL() external view returns (IPool);
+
+  /* EXTERNAL FUNCTIONS */
+
+  /// @notice Repays all the bad debt of the users
+  /// @dev Will fail if the user has some collateral or no debt
+  /// @param asset The address of the asset to repay
+  /// @param users The addresses of the users to repay
+  function batchRepayBadDebt(address asset, address[] calldata users) external;
+
+  /* EXTERNAL VIEW FUNCTIONS */
+
+  /// @notice Returns the total bad debt amount and the debt amounts of users
+  /// @dev Will fail if the user has some collateral or no debt
+  /// @param asset The address of the asset to repay
+  /// @param users The addresses of the users to repay
+  /// @return totalDebtAmount The total debt amount
+  /// @return debtAmounts The debt amounts of the users
+  function getBadDebtAmount(
+    address asset,
+    address[] memory users
+  ) external view returns (uint256 totalDebtAmount, uint256[] memory debtAmounts);
+}