feat(meetup): basic workflow

config/config.exs

@@ -69,7 +69,7 @@ config :groupher_server, :article,
   min_length: 10,
   max_length: 20_000,
   # NOTE: do not change unless you know what you are doing
-  threads: [:post, :job, :repo, :blog, :works, :radar, :guide],
+  threads: [:post, :job, :repo, :blog, :works, :radar, :guide, :meetup],
   # in this period, paged articles will sort front if non-article-author commented
   # 在此时间段内，一旦有非文章作者的用户评论，该文章就会排到前面
   active_period_days: %{
@@ -79,7 +79,8 @@ config :groupher_server, :article,
     blog: 10,
     works: 10,
     radar: 10,
-    guide: 10
+    guide: 10,
+    meetup: 10
   },
 
   # NOTE: if you want to add/remove emotion, just edit the list below

lib/groupher_server/cms/models/meetup.ex

@@ -0,0 +1,48 @@
+defmodule GroupherServer.CMS.Model.Meetup do
+  @moduledoc false
+  alias __MODULE__
+
+  use Ecto.Schema
+  use Accessible
+
+  import Ecto.Changeset
+  import GroupherServer.CMS.Helper.Macros
+
+  alias GroupherServer.CMS
+  alias CMS.Model.Embeds
+
+  @timestamps_opts [type: :utc_datetime_usec]
+
+  @required_fields ~w(title digest)a
+  @article_cast_fields general_article_cast_fields()
+  @optional_fields @article_cast_fields
+
+  @type t :: %Meetup{}
+  schema "cms_meetups" do
+    article_tags_field(:meetup)
+    article_communities_field(:meetup)
+    general_article_fields(:meetup)
+  end
+
+  @doc false
+  def changeset(%Meetup{} = meetup, attrs) do
+    meetup
+    |> cast(attrs, @optional_fields ++ @required_fields)
+    |> validate_required(@required_fields)
+    |> cast_embed(:meta, required: false, with: &Embeds.ArticleMeta.changeset/2)
+    |> generl_changeset
+  end
+
+  @doc false
+  def update_changeset(%Meetup{} = meetup, attrs) do
+    meetup
+    |> cast(attrs, @optional_fields ++ @required_fields)
+    |> generl_changeset
+  end
+
+  defp generl_changeset(changeset) do
+    changeset
+    |> validate_length(:title, min: 3, max: 50)
+    |> cast_embed(:emotions, with: &Embeds.ArticleEmotion.changeset/2)
+  end
+end

lib/groupher_server/cms/models/meetup_document.ex

@@ -0,0 +1,47 @@
+defmodule GroupherServer.CMS.Model.MeetupDocument do
+  @moduledoc """
+  mainly for full-text search
+  """
+  alias __MODULE__
+
+  use Ecto.Schema
+  use Accessible
+
+  import Ecto.Changeset
+  import Helper.Utils, only: [get_config: 2]
+
+  alias GroupherServer.CMS
+  alias CMS.Model.Meetup
+
+  @timestamps_opts [type: :utc_datetime_usec]
+
+  @max_body_length get_config(:article, :max_length)
+  @min_body_length get_config(:article, :min_length)
+
+  @required_fields ~w(body body_html meetup_id)a
+  @optional_fields []
+
+  @type t :: %MeetupDocument{}
+  schema "meetup_documents" do
+    belongs_to(:meetup, Meetup, foreign_key: :meetup_id)
+
+    field(:body, :string)
+    field(:body_html, :string)
+    field(:toc, :map)
+  end
+
+  @doc false
+  def changeset(%MeetupDocument{} = meetup, attrs) do
+    meetup
+    |> cast(attrs, @optional_fields ++ @required_fields)
+    |> validate_required(@required_fields)
+    |> validate_length(:body, min: @min_body_length, max: @max_body_length)
+  end
+
+  @doc false
+  def update_changeset(%MeetupDocument{} = meetup, attrs) do
+    meetup
+    |> cast(attrs, @optional_fields ++ @required_fields)
+    |> validate_length(:body, min: @min_body_length, max: @max_body_length)
+  end
+end

lib/groupher_server_web/schema/cms/cms_metrics.ex

@@ -219,6 +219,13 @@ defmodule GroupherServerWeb.Schema.CMS.Metrics do
     field(:sort, :sort_enum)
   end
 
+  @desc "meetup_filter doc"
+  input_object :paged_meetups_filter do
+    pagination_args()
+    article_filter_fields()
+    field(:sort, :sort_enum)
+  end
+
   @desc "article_filter doc"
   input_object :paged_repos_filter do
     @desc "limit of records (default 20), if first > 30, only return 30 at most"

lib/groupher_server_web/schema/cms/cms_types.ex

@@ -129,6 +129,18 @@ defmodule GroupherServerWeb.Schema.CMS.Types do
     timestamp_fields(:article)
   end
 
+  object :meetup do
+    interface(:article)
+
+    general_article_fields()
+    comments_fields()
+
+    field(:length, :integer)
+    field(:link_addr, :string)
+
+    timestamp_fields(:article)
+  end
+
   object :repo do
     interface(:article)
 

lib/groupher_server_web/schema/cms/mutations/meetup.ex

@@ -0,0 +1,52 @@
+defmodule GroupherServerWeb.Schema.CMS.Mutations.Meetup do
+  @moduledoc """
+  CMS mutations for meetup
+  """
+  use Helper.GqlSchemaSuite
+  import GroupherServerWeb.Schema.Helper.Mutations
+
+  object :cms_meetup_mutations do
+    @desc "create a meetup"
+    field :create_meetup, :meetup do
+      arg(:title, non_null(:string))
+      arg(:body, non_null(:string))
+      arg(:digest, non_null(:string))
+      arg(:community_id, non_null(:id))
+      arg(:thread, :thread, default_value: :meetup)
+      arg(:article_tags, list_of(:id))
+
+      middleware(M.Authorize, :login)
+      middleware(M.PublishThrottle)
+      resolve(&R.CMS.create_article/3)
+      middleware(M.Statistics.MakeContribute, for: [:user, :community])
+    end
+
+    @desc "update a cms/meetup"
+    field :update_meetup, :meetup do
+      arg(:id, non_null(:id))
+      arg(:title, :string)
+      arg(:body, :string)
+      arg(:digest, :string)
+
+      arg(:article_tags, list_of(:id))
+      # ...
+
+      middleware(M.Authorize, :login)
+      middleware(M.PassportLoader, source: :meetup)
+      middleware(M.Passport, claim: "owner;cms->c?->meetup.edit")
+
+      resolve(&R.CMS.update_article/3)
+    end
+
+    article_react_mutations(:meetup, [
+      :upvote,
+      :pin,
+      :mark_delete,
+      :delete,
+      :emotion,
+      :report,
+      :sink,
+      :lock_comment
+    ])
+  end
+end

priv/repo/migrations/20210626081546_create_meetup.exs

@@ -0,0 +1,32 @@
+defmodule GroupherServer.Repo.Migrations.CreateMeetup do
+  use Ecto.Migration
+
+  def change do
+    create table(:cms_meetups) do
+      add(:thread, :string)
+      add(:title, :string)
+      add(:digest, :string)
+      add(:views, :integer, default: 0)
+      add(:mark_delete, :boolean, default: false)
+      add(:meta, :map)
+      add(:emotions, :map)
+      add(:original_community_id, references(:communities, on_delete: :delete_all))
+      add(:author_id, references(:cms_authors, on_delete: :delete_all), null: false)
+
+      add(:active_at, :utc_datetime)
+
+      # reaction
+      add(:upvotes_count, :integer, default: 0)
+      add(:collects_count, :integer, default: 0)
+
+      # comments
+      add(:comments_participants_count, :integer, default: 0)
+      add(:comments_count, :integer, default: 0)
+      add(:comments_participants, :map)
+
+      timestamps()
+    end
+
+    create(index(:cms_meetups, [:author_id]))
+  end
+end

priv/repo/migrations/20210626081857_create_meetup_document.exs

@@ -0,0 +1,13 @@
+defmodule GroupherServer.Repo.Migrations.CreateMeetupDocument do
+  use Ecto.Migration
+
+  def change do
+    create table(:meetup_documents) do
+      add(:meetup_id, references(:cms_meetups, on_delete: :delete_all), null: false)
+      add(:body, :text)
+      add(:body_html, :text)
+      add(:markdown, :text)
+      add(:toc, :map)
+    end
+  end
+end

priv/repo/migrations/20210626082045_create_communities_join_meetups.exs

@@ -0,0 +1,12 @@
+defmodule GroupherServer.Repo.Migrations.CreateCommunitiesJoinMeetups do
+  use Ecto.Migration
+
+  def change do
+    create table(:communities_join_meetups) do
+      add(:community_id, references(:communities, on_delete: :delete_all), null: false)
+      add(:meetup_id, references(:cms_meetups, on_delete: :delete_all), null: false)
+    end
+
+    create(unique_index(:communities_join_meetups, [:community_id, :meetup_id]))
+  end
+end

priv/repo/migrations/20210626082257_add_meetup_to_others.exs

@@ -0,0 +1,41 @@
+defmodule GroupherServer.Repo.Migrations.AddMeetupToOthers do
+  use Ecto.Migration
+
+  def change do
+    alter table(:articles_join_tags) do
+      add(:meetup_id, references(:cms_meetups, on_delete: :delete_all))
+    end
+
+    alter table(:abuse_reports) do
+      add(:meetup_id, references(:cms_meetups, on_delete: :delete_all))
+    end
+
+    alter table(:article_collects) do
+      add(:meetup_id, references(:cms_meetups, on_delete: :delete_all))
+    end
+
+    alter table(:article_upvotes) do
+      add(:meetup_id, references(:cms_meetups, on_delete: :delete_all))
+    end
+
+    alter table(:comments) do
+      add(:meetup_id, references(:cms_meetups, on_delete: :delete_all))
+    end
+
+    alter table(:pinned_comments) do
+      add(:meetup_id, references(:cms_meetups, on_delete: :delete_all))
+    end
+
+    alter table(:articles_users_emotions) do
+      add(:meetup_id, references(:cms_meetups, on_delete: :delete_all))
+    end
+
+    alter table(:pinned_articles) do
+      add(:meetup_id, references(:cms_meetups, on_delete: :delete_all))
+    end
+
+    alter table(:cited_artiments) do
+      add(:meetup_id, references(:cms_meetups, on_delete: :delete_all))
+    end
+  end
+end

test/groupher_server/accounts/published/published_meetup_test.exs

@@ -0,0 +1,93 @@
+defmodule GroupherServer.Test.Accounts.Published.Meetup do
+  use GroupherServer.TestTools
+
+  alias GroupherServer.{Accounts, CMS}
+  alias Accounts.Model.User
+  alias Helper.ORM
+
+  @publish_count 10
+
+  setup do
+    {:ok, user} = db_insert(:user)
+    {:ok, user2} = db_insert(:user)
+    {:ok, meetup} = db_insert(:meetup)
+    {:ok, community} = db_insert(:community)
+    {:ok, community2} = db_insert(:community)
+
+    {:ok, ~m(user user2 meetup community community2)a}
+  end
+
+  describe "[publised meetups]" do
+    test "create meetup should update user published meta", ~m(community user)a do
+      meetup_attrs = mock_attrs(:meetup, %{community_id: community.id})
+      {:ok, _meetup} = CMS.create_article(community, :meetup, meetup_attrs, user)
+      {:ok, _meetup} = CMS.create_article(community, :meetup, meetup_attrs, user)
+
+      {:ok, user} = ORM.find(User, user.id)
+      assert user.meta.published_meetups_count == 2
+    end
+
+    test "fresh user get empty paged published meetups", ~m(user)a do
+      {:ok, results} = Accounts.paged_published_articles(user, :meetup, %{page: 1, size: 20})
+
+      assert results |> is_valid_pagination?(:raw)
+      assert results.total_count == 0
+    end
+
+    test "user can get paged published meetups", ~m(user user2 community community2)a do
+      pub_meetups =
+        Enum.reduce(1..@publish_count, [], fn _, acc ->
+          meetup_attrs = mock_attrs(:meetup, %{community_id: community.id})
+          {:ok, meetup} = CMS.create_article(community, :meetup, meetup_attrs, user)
+
+          acc ++ [meetup]
+        end)
+
+      pub_meetups2 =
+        Enum.reduce(1..@publish_count, [], fn _, acc ->
+          meetup_attrs = mock_attrs(:meetup, %{community_id: community2.id})
+          {:ok, meetup} = CMS.create_article(community, :meetup, meetup_attrs, user)
+
+          acc ++ [meetup]
+        end)
+
+      # unrelated other user
+      Enum.reduce(1..5, [], fn _, acc ->
+        meetup_attrs = mock_attrs(:meetup, %{community_id: community.id})
+        {:ok, meetup} = CMS.create_article(community, :meetup, meetup_attrs, user2)
+
+        acc ++ [meetup]
+      end)
+
+      {:ok, results} = Accounts.paged_published_articles(user, :meetup, %{page: 1, size: 20})
+
+      assert results |> is_valid_pagination?(:raw)
+      assert results.total_count == @publish_count * 2
+
+      random_meetup_id = pub_meetups |> Enum.random() |> Map.get(:id)
+      random_meetup_id2 = pub_meetups2 |> Enum.random() |> Map.get(:id)
+      assert results.entries |> Enum.any?(&(&1.id == random_meetup_id))
+      assert results.entries |> Enum.any?(&(&1.id == random_meetup_id2))
+    end
+  end
+
+  describe "[publised meetup comments]" do
+    test "can get published article comments", ~m(meetup user)a do
+      total_count = 10
+
+      Enum.reduce(1..total_count, [], fn _, acc ->
+        {:ok, comment} = CMS.create_comment(:meetup, meetup.id, mock_comment(), user)
+        acc ++ [comment]
+      end)
+
+      filter = %{page: 1, size: 20}
+      {:ok, articles} = Accounts.paged_published_comments(user, :meetup, filter)
+
+      entries = articles.entries
+      article = entries |> List.first()
+
+      assert article.article.id == meetup.id
+      assert article.article.title == meetup.title
+    end
+  end
+end