fix(BaseEntity): Pass the entity to when closures

To enable calling scopes and other Quick methods,
the BaseEntity now has its own version of `when`
that it uses to pass the entity on instead of just
the QueryBuilder instance.

models/BaseEntity.cfc

@@ -1011,6 +1011,34 @@ component accessors="true" {
         return this;
     }
 
+    /**
+     * This method mirrors qb's `when` method.
+     * It exists so we can pass through the entity
+     * to the closures instead of just the QueryBuilder.
+     *
+     * @condition A boolean condition that if true will trigger the `onTrue` callback.
+     *            If not true the `onFalse` callback will trigger, if it was passed.
+     *            Otherwise, the query is returned unmodified.
+     * @onTrue    A closure that will be triggered if the `condition` is true.
+     * @onFalse   A closure that will be triggered if the `condition` is false.
+     */
+    public function when(
+        required boolean condition,
+        onTrue,
+        onFalse
+    ) {
+        var defaultCallback = function( q ) {
+            return q;
+        };
+        onFalse = isNull( onFalse ) ? defaultCallback : onFalse;
+        if ( condition ) {
+            onTrue( this );
+        } else {
+            onFalse( this );
+        }
+        return this;
+    }
+
     function newCollection( array entities = [] ) {
         return arguments.entities;
     }

tests/resources/app/models/User.cfc

@@ -19,6 +19,12 @@ component quick {
         return query.where( "type", type );
     }
 
+    function scopeOfTypeWithWhen( query, type ) {
+        return query.when( ! isNull( type ) && len( type ), function( q ) {
+            q.ofType( type );
+        } );
+    }
+
     function scopeResetPasswords( query ) {
         return query.updateAll( { "password" = "" } ).result.recordcount;
     }

tests/specs/integration/BaseEntity/ScopeSpec.cfc

@@ -26,6 +26,12 @@ component extends="tests.resources.ModuleIntegrationSpec" appMapping="/app" {
             it( "can return values from scopes as well as instances", function() {
                 expect( getInstance( "User" ).ofType( "admin" ).resetPasswords() ).toBe( 1 );
             } );
+
+            it( "can use the qb `when` helper in scopes", function() {
+                var users = getInstance( "User" ).ofTypeWithWhen( "admin" ).get();
+                expect( users ).toHaveLength( 1, "One user should exist in the database and be returned." );
+                expect( users[ 1 ].getUsername() ).toBe( "elpete" );
+            } );
         } );
     }