Dynamic validation

[phtj]

I have the following example data:

apps: [
    {name: "aaa"},
    {name: "bbb"},
    {name: "ccc"}
]
names: ["aaa", "ccc"]

I would like to write a schema that constraints my data, so that the names must contain only aaa, bbb, or ccc. The person writing the schema will be different from the person writing that data, so I would like a clean separation.

I tried something like this:

// --- SCHEMA ---
#App: {
    name: string
}
#Apps: [... #App]
#Names: [ for _, a in #Apps {a.name} ]

// --- DATA ---
apps: #Apps & [
    {name: "aaa"},
    {name: "bbb"},
    {name: "ccc"}
]
names: #Names
names: ["aaa", "ccc"]

But that will give me an error

names: incompatible list lengths (0 and 2)

Does anyone have any suggestions?

[eadlam]

You need to dynamically produce an enum from the app names:

#Name: "aaa" | "bbb" | "ccc"

You can do that with the or() function. For example:

package main

// --- SCHEMA ---
#App: {
    name: string
}
#Apps: [... #App]

// Given a list of Apps, dynamically produce a Name Enum
// #Name: "aaa" | "bbb" | "ccc"
#Name: or([ for a in apps {a.name} ])

// --- DATA ---
apps: #Apps & [
    {name: "aaa"},
    {name: "bbb"},
    {name: "ccc"}
]

names: [...#Name]
names: ["aaa", "ccc"]

If you want to move that schema to a separate package and/or produce multiple enums from different lists, you can use the function pattern to make #Name more flexible:

package main

// --- SCHEMA ---
#App: {
    name: string
}
#Apps: [... #App]

// Given a list of Apps, dynamically produce a Name Enum
// #Name: "aaa" | "bbb" | "ccc"
#Name: {
    #apps: #Apps
    or([ for a in #apps {a.name} ])
}

// --- DATA ---
apps: #Apps & [
    {name: "aaa"},
    {name: "bbb"},
    {name: "ccc"}
]
names: [...{#Name, #apps: apps}]
names: ["aaa", "ccc"]

[phtj]

Thanks!