Validate conditional fields

[cueckoo]

Originally opened by @ostcar in cuelang/cue#706

I have a list of structs. Dependent on the value of one field the structs have different other fields.

For example here is a yml file with two persons. Minors need someone responsible:

---
person1:
  name: Bob
  age: 35

person2:
  name: Bill
  age: 12
  responsible: Anna

I am trying to validate this with this schema:

person1: #Person
person2: #Person

#Person: {
	name: string
	age: int

    if age < 18 {
        responsible: string
    }
}

But cue vet returns: person2: field "responsible" not allowed in closed struct.

It seems, that conditional fields only work with cue eval.

Is there a way to conditionally validate a struct?

[cueckoo]

Original reply by @extemporalgenome in cuelang/cue#706 (comment)

You can open a definition struct using ..., such as:

#Person: {
  name: string
  age: int

  if age < 18 {
      responsible: string
  }
  ...
}

However, that means data or other types that refer to #Person are now open ended to accept any other fields, which is often not desired.

I'm fairly new to CUE, but I believe the conventional approach is:

#Person: {
  name: string
  age:  int & >=0
}

#Person: {
  age:         <18
  responsible: string
  aspirations: [string]
} | {
  age: >=18
  regrets: [string]
}

This evaluates to:

#Person: {
    name:        string
    age:         uint & <18
    responsible: string
    aspirations: [string]
} | {
    name: string
    age:  >=18 & int
    regrets: [string]
}

[cueckoo]

Original reply by @ostcar in cuelang/cue#706 (comment)

Thank you a lot. That worked perfectly!

[cueckoo]

Original reply by @myitcv in cuelang/cue#706 (comment)

Please can you give a bit more detail on what you tried originally (including CUE version)?

Because it does/should work:

cue vet schema.cue persons.yaml

-- persons.yaml --
person1:
  name: Bob
  age: 35

person2:
  name: Bill
  age: 12
  responsible: Anna
-- schema.cue --
package p

person1: #Person
person2: #Person

#Person: {
	name: string
	age:  int

	if age < 18 {
		responsible: string
	}
}

Run with CUE version ed8bdafc which might be relevant.

[cueckoo]

Original reply by @extemporalgenome in cuelang/cue#706 (comment)

So what is the preferred style? I'd imagine if for this kind of conditionally required extra field, since that's more convenient?

[cueckoo]

Original reply by @ostcar in cuelang/cue#706 (comment)

I am using the cue version from the archlinux repo: cue version 0.2.2 linux/amd64

I am calling cue vet persons.yaml schema.cue

The output is:

person2: field "responsible" not allowed in closed struct:
    ./persons.yaml:8:17

[cueckoo]

Original reply by @myitcv in cuelang/cue#706 (comment)

Ah @ostcar thanks for confirming.

Whilst v0.2.2 is indeed the latest stable release, you are strongly encouraged to use the latest v0.3.0 pre-release:

https://github.com/cuelang/cue/releases/tag/v0.3.0-beta.3

A significant amount has changed since v0.2.2 and, whilst the v0.3.0 release has been a long time in coming, it lays the foundations for all future work in CUE (not to mention being an incredibly complex rewrite).

[cueckoo]

Original reply by @myitcv in cuelang/cue#706 (comment)

(sorry, that sent too early)

We are entirely focussed on getting v0.3.0 out the door as soon as possibly incidentally. At which point hopefully far fewer people will accidentally use an "old" version.

Thanks for confirming details in any case.

[cueckoo]

Original reply by @ostcar in cuelang/cue#706 (comment)

I can confirm this. After I installed cue from the sources (GO111MODULE=on go get -u cuelang.org/go/cmd/cue@v0.3.0-beta.3), the example works fine.