Questions about how to set multiple fields in a list with cue

[cbrgm]

Hello, I have a quick question about the following cue snippet.

Given is a list with projects and configurations for the stages Dev, Int and Prd.

#ProjectGroup: {
    Name: string
    Configs: [...#Config]
}

#Config: close({
    Cluster:   string
    Namespace: string
    Stage:  "DEV" | "INT" | "PRD" | "GLOBAL"
})

#DevConfig: #Config & {
    Cluster: "dev.cluster"
    Namespace: string
    Stage: "DEV"
}

#IntConfig: #Config & {
    Cluster: "int.cluster"
    Namespace: string
    Stage: "INT"
}

#PrdConfig: #Config & {
   Cluster: "prd.cluster"
    Namespace: string
    Stage: "PRD"
}

#GlobalConfig: [
    #DevConfig,
    #IntConfig,
    #PrdConfig,
]

#ProjectGroups: [...#ProjectGroup]

projects: #ProjectGroups & [{
    Name: "foo-project"
    Configs: [
        #DevConfig & { Namespace: "foo" },
        #IntConfig & { Namespace: "foo" },
        #PrdConfig & { Namespace: "foo" },
    ]
}

Furthermore, there is a global config that combines all three configs as a list. For the global config I would like to define the namespace once with cue and set it in each element in the list.

After a bit of trial and error I have found that it either works like this:

[...]

{
    Name: "foo-project"
    Configs: #GlobalConfig & [...{ Namespace: "bar" }]
}]

or with this:

[...]

{
    Name: "foo-project"
    Configs: #GlobalKubeConfig & [for x in #GlobalKubeConfig { Namespace: "bar" }]
}]

Did I understand correctly that ... does the same as for in a list? Is this just a shortcut?

Can anyone tell me when it is better to work with for instead of using ...? Is for specifically meant to work with named variables e.g. when a if condition follows?

Sorry if this should be basics, I just started to learn a little bit about cue today. :)

[eonpatapon]

... just indicates that the list length can be as long as you want. We call this an open list, like structs can be open or closed. You can see this as a constrain.

// An open list of strings
// if not set it will default to an empty list
l1: [...string]

// A list of 2 strings
l2: [string, string]

// A list of at least one string
l3: [string, ...string]

List comprehensions (for expressions) are used to create a list of values in a field. The result of the expression must conform to the constrain defined on this field (if any).

users: {
	john: email:  "john@example.com"
	bob: email:   "bob@example.com"
	alice: email: "alice@example.com"
}

l1: [ for u, _ in users {u}]
l2: [ for u, _ in users {u}]
l3: [ for u, _ in users {u}]

 cue eval y.cue
l2: incompatible list lengths (2 and 3)

You can also define a list of any value with:

l: [..._]

Which is the same as:

l: [...]

About your use-case it works it both cases thanks to unification.

l1: MyList & [...{a: "foo"}]
l2: MyList & [for x in MyList { a: "bar" }]

In the l1 case for each value of MyList cue will unify it with {a: "foo"}
In the l2 case we are unifying 2 lists of the same size, values at every index will be unified.

For this use-case I think the l1 way is more elegant.

[cbrgm]

Thank you so much for the detailed explanation @eonpatapon! This helps a lot!

[cueckoo]

This discussion has been migrated to cue-lang/cue#1067.

For more details about CUE's migration to a new home, please see cue-lang/cue#1078.