Add support for turning on caching by default for Athena data sources

grafana_data_source_athena/main.tf

@@ -15,3 +15,22 @@ resource "grafana_data_source" "athena" {
     workgroup      = each.value.workgroup
   })
 }
+
+# trunk-ignore(tflint/terraform_unused_declarations)
+data "http" "enable_caching" {
+  for_each = var.enable_caching && var.grafana_url != "" && var.bearer_token != "" ? grafana_data_source.athena : {}
+  url      = "${var.grafana_url}/api/datasources/${grafana_data_source.athena[each.key].uid}/cache/enable"
+  method   = "POST"
+
+  request_headers = {
+    Accept        = "application/json"
+    Authorization = "Bearer ${var.bearer_token}"
+  }
+
+  lifecycle {
+    postcondition {
+      condition     = contains([200, 201, 204], self.status_code)
+      error_message = "Status code invalid for enabling caching for Athena data source"
+    }
+  }
+}

grafana_data_source_athena/variables.tf

@@ -2,3 +2,22 @@ variable "data_sources" {
   description = "Path to the json files with data sources"
   type        = list(string)
 }
+
+variable "enable_caching" {
+  description = "Enable caching for the data source"
+  type        = bool
+  default     = true
+}
+
+variable "grafana_url" {
+  description = "URL of the Grafana instance"
+  type        = string
+  default     = ""
+}
+
+variable "bearer_token" {
+  description = "Bearer token for the Grafana API"
+  sensitive   = true
+  type        = string
+  default     = ""
+}

grafana_data_source_athena/versions.tf

@@ -6,5 +6,9 @@ terraform {
       source  = "grafana/grafana"
       version = ">= 2.9.0"
     }
+    http = {
+      source  = "hashicorp/http"
+      version = ">= 2.9.0"
+    }
   }
 }

grafana_data_source_athena/versions.tofu

@@ -6,5 +6,9 @@ terraform {
       source  = "grafana/grafana"
       version = ">= 2.9.0"
     }
+    http = {
+      source  = "hashicorp/http"
+      version = ">= 2.9.0"
+    }
   }
 }