Add circular-buffer exercise

config.json

@@ -593,6 +593,14 @@
         "prerequisites": [],
         "difficulty": 6
       },
+      {
+        "slug": "circular-buffer",
+        "name": "Circular Buffer",
+        "uuid": "6b01cbb4-6a20-4214-83a0-bb1691bbdb10",
+        "practices": [],
+        "prerequisites": [],
+        "difficulty": 8
+      },
       {
         "slug": "knapsack",
         "name": "Knapsack",

exercises/practice/circular-buffer/.docs/instructions.md

@@ -0,0 +1,58 @@
+# Instructions
+
+A circular buffer, cyclic buffer or ring buffer is a data structure that uses a single, fixed-size buffer as if it were connected end-to-end.
+
+A circular buffer first starts empty and of some predefined length.
+For example, this is a 7-element buffer:
+
+```text
+[ ][ ][ ][ ][ ][ ][ ]
+```
+
+Assume that a 1 is written into the middle of the buffer (exact starting location does not matter in a circular buffer):
+
+```text
+[ ][ ][ ][1][ ][ ][ ]
+```
+
+Then assume that two more elements are added — 2 & 3 — which get appended after the 1:
+
+```text
+[ ][ ][ ][1][2][3][ ]
+```
+
+If two elements are then removed from the buffer, the oldest values inside the buffer are removed.
+The two elements removed, in this case, are 1 & 2, leaving the buffer with just a 3:
+
+```text
+[ ][ ][ ][ ][ ][3][ ]
+```
+
+If the buffer has 7 elements then it is completely full:
+
+```text
+[5][6][7][8][9][3][4]
+```
+
+When the buffer is full an error will be raised, alerting the client that further writes are blocked until a slot becomes free.
+
+When the buffer is full, the client can opt to overwrite the oldest data with a forced write.
+In this case, two more elements — A & B — are added and they overwrite the 3 & 4:
+
+```text
+[5][6][7][8][9][A][B]
+```
+
+3 & 4 have been replaced by A & B making 5 now the oldest data in the buffer.
+Finally, if two elements are removed then what would be returned is 5 & 6 yielding the buffer:
+
+```text
+[ ][ ][7][8][9][A][B]
+```
+
+Because there is space available, if the client again uses overwrite to store C & D then the space where 5 & 6 were stored previously will be used not the location of 7 & 8.
+7 is still the oldest element and the buffer is once again full.
+
+```text
+[C][D][7][8][9][A][B]
+```

exercises/practice/circular-buffer/.meta/config.json

@@ -0,0 +1,19 @@
+{
+  "authors": [
+    "glennj"
+  ],
+  "files": {
+    "solution": [
+      "circular-buffer.sml"
+    ],
+    "test": [
+      "test.sml"
+    ],
+    "example": [
+      ".meta/example.sml"
+    ]
+  },
+  "blurb": "A data structure that uses a single, fixed-size buffer as if it were connected end-to-end.",
+  "source": "Wikipedia",
+  "source_url": "https://en.wikipedia.org/wiki/Circular_buffer"
+}

exercises/practice/circular-buffer/.meta/example.sml

@@ -0,0 +1,59 @@
+structure CircularBuffer :> sig
+  type buffer
+
+  exception BufferFull
+  exception BufferEmpty
+
+  val create : int -> buffer
+  val read : buffer -> int
+  val write : buffer -> int -> unit
+  val clear : buffer -> unit
+  val overwrite : buffer -> int -> unit
+end = struct
+  type buffer = {
+                   data : int Array.array,
+                   size : int,
+                   count : int ref,
+                   readPtr : int ref,
+                   writePtr : int ref
+                }
+
+  exception BufferFull
+  exception BufferEmpty
+
+  fun create size = {
+      data = Array.array (size, 0),
+      size = size,
+      count = ref 0,
+      readPtr = ref 0,
+      writePtr = ref 0
+    }
+
+  fun read buff =
+    if !(#count buff) = 0
+    then raise BufferEmpty
+    else let val value = Array.sub (#data buff, !(#readPtr buff))
+         in  #readPtr buff := (!(#readPtr buff) + 1) mod #size buff;
+             #count buff   := !(#count buff) - 1;
+             value
+         end
+
+  fun write buff value =
+    if !(#count buff) = #size buff
+    then raise BufferFull
+    else ( Array.update (#data buff, !(#writePtr buff), value);
+           #writePtr buff := (!(#writePtr buff) + 1) mod #size buff;
+           #count buff    := !(#count buff) + 1 )
+
+  fun clear buff =
+    ( #writePtr buff := !(#readPtr buff);
+      #count buff    := 0 )
+
+  fun overwrite buff value =
+    let val _ = if !(#count buff) = #size buff
+                then read buff
+                else 0
+    in  write buff value
+    end
+end
+

exercises/practice/circular-buffer/.meta/tests.toml

@@ -0,0 +1,52 @@
+# This is an auto-generated file.
+#
+# Regenerating this file via `configlet sync` will:
+# - Recreate every `description` key/value pair
+# - Recreate every `reimplements` key/value pair, where they exist in problem-specifications
+# - Remove any `include = true` key/value pair (an omitted `include` key implies inclusion)
+# - Preserve any other key/value pair
+#
+# As user-added comments (using the # character) will be removed when this file
+# is regenerated, comments can be added via a `comment` key.
+
+[28268ed4-4ff3-45f3-820e-895b44d53dfa]
+description = "reading empty buffer should fail"
+
+[2e6db04a-58a1-425d-ade8-ac30b5f318f3]
+description = "can read an item just written"
+
+[90741fe8-a448-45ce-be2b-de009a24c144]
+description = "each item may only be read once"
+
+[be0e62d5-da9c-47a8-b037-5db21827baa7]
+description = "items are read in the order they are written"
+
+[2af22046-3e44-4235-bfe6-05ba60439d38]
+description = "full buffer can't be written to"
+
+[547d192c-bbf0-4369-b8fa-fc37e71f2393]
+description = "a read frees up capacity for another write"
+
+[04a56659-3a81-4113-816b-6ecb659b4471]
+description = "read position is maintained even across multiple writes"
+
+[60c3a19a-81a7-43d7-bb0a-f07242b1111f]
+description = "items cleared out of buffer can't be read"
+
+[45f3ae89-3470-49f3-b50e-362e4b330a59]
+description = "clear frees up capacity for another write"
+
+[e1ac5170-a026-4725-bfbe-0cf332eddecd]
+description = "clear does nothing on empty buffer"
+
+[9c2d4f26-3ec7-453f-a895-7e7ff8ae7b5b]
+description = "overwrite acts like write on non-full buffer"
+
+[880f916b-5039-475c-bd5c-83463c36a147]
+description = "overwrite replaces the oldest item on full buffer"
+
+[bfecab5b-aca1-4fab-a2b0-cd4af2b053c3]
+description = "overwrite replaces the oldest item remaining in buffer following a read"
+
+[9cebe63a-c405-437b-8b62-e3fdc1ecec5a]
+description = "initial clear does not affect wrapping around"

exercises/practice/circular-buffer/circular-buffer.sml

@@ -0,0 +1,33 @@
+structure CircularBuffer :> sig
+  type buffer
+
+  exception BufferFull
+  exception BufferEmpty
+
+  val create : int -> buffer
+  val read : buffer -> int
+  val write : buffer -> int -> unit
+  val clear : buffer -> unit
+  val overwrite : buffer -> int -> unit
+end = struct
+
+  type buffer = unit (* TODO define the data structure *)
+
+  exception BufferFull
+  exception BufferEmpty
+
+  fun create size =
+    raise Fail "'create' is not implemented"
+
+  fun read buff =
+    raise Fail "'read' is not implemented"
+
+  fun write buff value =
+    raise Fail "'write' is not implemented"
+
+  fun clear buff =
+    raise Fail "'clear' is not implemented"
+
+  fun overwrite buff value =
+    raise Fail "'overwrite' is not implemented"
+end

exercises/practice/circular-buffer/test.sml

@@ -0,0 +1,129 @@
+use "circular-buffer.sml";
+use "testlib.sml";
+
+infixr |>
+fun x |> f = f x
+
+val testsuite =
+  describe "circular-buffer" [
+    test "reading empty buffer should fail"
+      (fn _ => (fn _ => let val buf = CircularBuffer.create 1
+                        in  CircularBuffer.read buf
+                        end
+               ) |> Expect.error CircularBuffer.BufferEmpty),
+
+    test "can read an item just written"
+      (fn _ => let val buf = CircularBuffer.create 1
+               in  CircularBuffer.write buf 100;
+                   CircularBuffer.read buf |> Expect.equalTo 100
+               end),
+
+    test "each item may only be read once"
+      (fn _ => (fn _ => let val buf = CircularBuffer.create 1
+                        in  CircularBuffer.write buf 100;
+                            CircularBuffer.read buf |> Expect.equalTo 100;
+                            CircularBuffer.read buf
+                        end
+               ) |> Expect.error CircularBuffer.BufferEmpty),
+
+    test "items are read in the order they are written"
+      (fn _ => let val buf = CircularBuffer.create 2
+               in  CircularBuffer.write buf 100;
+                   CircularBuffer.write buf 200;
+                   CircularBuffer.read buf |> Expect.equalTo 100;
+                   CircularBuffer.read buf |> Expect.equalTo 200
+               end),
+
+    test "full buffer can't be written to"
+      (fn _ => (fn _ => let val buf = CircularBuffer.create 1
+                        in  CircularBuffer.write buf 100;
+                            CircularBuffer.write buf 200
+                        end
+               ) |> Expect.error CircularBuffer.BufferFull),
+
+    test "a read frees up capacity for another write"
+      (fn _ => let val buf = CircularBuffer.create 1
+               in  CircularBuffer.write buf 100;
+                   CircularBuffer.read buf |> Expect.equalTo 100;
+                   CircularBuffer.write buf 200;
+                   CircularBuffer.read buf |> Expect.equalTo 200
+               end),
+
+    test "read position is maintained even across multiple writes"
+      (fn _ => let val buf = CircularBuffer.create 3
+               in  CircularBuffer.write buf 100;
+                   CircularBuffer.write buf 200;
+                   CircularBuffer.read buf |> Expect.equalTo 100;
+                   CircularBuffer.write buf 300;
+                   CircularBuffer.read buf |> Expect.equalTo 200;
+                   CircularBuffer.read buf |> Expect.equalTo 300
+               end),
+
+    test "items cleared out of buffer can't be read"
+      (fn _ => (fn _ => let val buf = CircularBuffer.create 1
+                        in  CircularBuffer.write buf 100;
+                            CircularBuffer.clear buf;
+                            CircularBuffer.read buf
+                        end
+               ) |> Expect.error CircularBuffer.BufferEmpty),
+
+    test "clear frees up capacity for another write"
+      (fn _ => let val buf = CircularBuffer.create 1
+               in  CircularBuffer.write buf 100;
+                   CircularBuffer.clear buf;
+                   CircularBuffer.write buf 200;
+                   CircularBuffer.read buf |> Expect.equalTo 200
+               end),
+
+    test "clear does nothing on empty buffer"
+      (fn _ => let val buf = CircularBuffer.create 1
+               in  CircularBuffer.clear buf;
+                   CircularBuffer.write buf 100;
+                   CircularBuffer.read buf |> Expect.equalTo 100
+               end),
+
+    test "overwrite acts like write on non-full buffer"
+      (fn _ => let val buf = CircularBuffer.create 2
+               in  CircularBuffer.write buf 100;
+                   CircularBuffer.overwrite buf 200;
+                   CircularBuffer.read buf |> Expect.equalTo 100;
+                   CircularBuffer.read buf |> Expect.equalTo 200
+               end),
+
+    test "overwrite replaces the oldest item on full buffer"
+      (fn _ => let val buf = CircularBuffer.create 2
+               in  CircularBuffer.write buf 100;
+                   CircularBuffer.write buf 200;
+                   CircularBuffer.overwrite buf 300;
+                   CircularBuffer.read buf |> Expect.equalTo 200;
+                   CircularBuffer.read buf |> Expect.equalTo 300
+               end),
+
+    test "overwrite replaces the oldest item remaining in buffer following a read"
+      (fn _ => let val buf = CircularBuffer.create 3
+               in  CircularBuffer.write buf 100;
+                   CircularBuffer.write buf 200;
+                   CircularBuffer.write buf 300;
+                   CircularBuffer.read buf |> Expect.equalTo 100;
+                   CircularBuffer.write buf 400;
+                   CircularBuffer.overwrite buf 500;
+                   CircularBuffer.read buf |> Expect.equalTo 300;
+                   CircularBuffer.read buf |> Expect.equalTo 400;
+                   CircularBuffer.read buf |> Expect.equalTo 500
+               end),
+
+    test "initial clear does not affect wrapping around"
+      (fn _ => (fn _ => let val buf = CircularBuffer.create 2
+                        in  CircularBuffer.clear buf;
+                            CircularBuffer.write buf 100;
+                            CircularBuffer.write buf 200;
+                            CircularBuffer.overwrite buf 300;
+                            CircularBuffer.overwrite buf 400;
+                            CircularBuffer.read buf |> Expect.equalTo 300;
+                            CircularBuffer.read buf |> Expect.equalTo 400;
+                            CircularBuffer.read buf
+                        end
+               ) |> Expect.error CircularBuffer.BufferEmpty)
+  ]
+
+val _ = Test.run testsuite