Build examples using native CMake

cmake/GzUtils.cmake

@@ -1944,6 +1944,159 @@ macro(gz_build_tests)
 
 endmacro()
 
+#################################################
+# gz_build_examples(
+#     SOURCE_DIR <source_dir>
+#     BINARY_DIR <binary_dir>
+#     [COMPONENTS <project_component_dependencies>]
+#     [DEPENDENCIES <project_dependencies>]
+#
+# Requires a CMakeLists.txt file to be in SOURCE_DIR that acts
+# Build examples for a Gazebo project. 
+# as a top level project.
+#
+# This generates two test targets
+# * EXAMPLES_Configure_TEST - Equivalent of calling "cmake .." on
+#                             the examples directory
+#
+# * EXAMPLES_Build_TEST - Equivalent of calling "make" on the
+#                         examples directory
+#
+# These tests are run during "make test" or can be run specifically
+# via "ctest -R EXAMPLES_ -V"
+#
+# Arguments are as follows:
+#
+# SOURCE_DIR: Required. Path to the examples folder.
+#             For example ${CMAKE_CURRENT_SOURCE_DIR}/examples
+#
+# BINARY_DIR: Required. Path to the output binary folder
+#             For example ${CMAKE_CURRENT_BINARY_DIR}/examples
+#
+# COMPONENTS: 
+#     Optional. List of components built by this project that are used in the examples.
+#     For example "cli" for gz-utils
+#
+# DEPENDENCIES: 
+#     Optional. Additional Gazebo library dependencies for this example 
+#     This is in addition to things that the project library already depends on.
+#     For example: gz-utils2 gz-common5
+
+macro(gz_build_examples)
+  #------------------------------------
+  # Define the expected arguments
+  set(options)
+  set(oneValueArgs SOURCE_DIR BINARY_DIR)
+  set(multiValueArgs COMPONENTS DEPENDENCIES)
+
+  #------------------------------------
+  # Parse the arguments
+  _gz_cmake_parse_arguments(gz_build_examples "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  set(BUILD_EXAMPLES_CMAKE "")
+  set(BUILD_EXAMPLES_INCLUDES "")
+
+  get_target_property(PROJECT_LIBRARY_DEPS ${PROJECT_LIBRARY_TARGET_NAME} INTERFACE_LINK_LIBRARIES)
+
+  # Below here we are generating a series of arguments to the cmake command that is to follow.
+  # Since we may be building in a colcon workspace or otherwise isolated, we are passing
+  # in the resolved dependency directories via -Ddep_DIR=${dep_DIR}
+
+  # Always depends on on gz-cmake
+  list(APPEND BUILD_EXAMPLES_CMAKE "-Dgz-cmake${GZ_CMAKE_VER}_DIR=${gz-cmake${GZ_CMAKE_VER}_DIR}")
+
+  # Iterate through the project library dependencies and add them to the cmake args
+  foreach(PROJECT_LIBRARY_DEP ${PROJECT_LIBRARY_DEPS})
+    get_target_property(DEP_NAME ${PROJECT_LIBRARY_DEP} NAME)
+
+    string(REPLACE "::" ";" DEP_NAME ${DEP_NAME})
+    list(GET DEP_NAME 0 DEP_PACKAGE)
+    list(GET DEP_NAME 0 DEP_COMPONENT)
+    list(APPEND BUILD_EXAMPLES_CMAKE "-D${DEP_PACKAGE}_DIR=${${DEP_PACKAGE}_DIR}")
+
+    # For each dependency, also include the components that were requested
+    # at the find_package call to reduce verbosity in COMPONENTS arg
+    if (TARGET ${DEP}::requested)
+      get_target_property(REQUESTED_COMPONENTS ${DEP}::requested INTERFACE_LINK_LIBRARIES)
+
+      foreach(LINKLIB ${REQUESTED_COMPONENTS})
+        string(REGEX REPLACE "^${DEP}::" "" GZ_COMPONENT ${LINKLIB})
+
+        if (GZ_COMPONENT STREQUAL DEP)
+          continue()
+        endif()
+
+        list(APPEND BUILD_EXAMPLES_CMAKE "-D${GZ_COMPONENT}_DIR=${${GZ_COMPONENT}_DIR}")
+      endforeach()
+    endif()
+  endforeach()
+
+  # Iterate through additional dependencies, that is things that the project library 
+  # doesn't depend on, but are needed for the examples.
+  # While this opens up the possibility of using any gazebo packages as part of the 
+  # examples, care should be exercised to not introduce circular depdendencies.
+  foreach(DEP ${gz_build_examples_DEPENDENCIES})
+    list(APPEND BUILD_EXAMPLES_CMAKE "-D${DEP}_DIR=${${DEP}_DIR}")
+
+    # For each dependency, also include the components that were requested
+    # at the find_package call to reduce verbosity in COMPONENTS arg
+    if (TARGET ${DEP}::requested)
+      get_target_property(REQUESTED_COMPONENTS ${DEP}::requested INTERFACE_LINK_LIBRARIES)
+
+      foreach(LINKLIB ${REQUESTED_COMPONENTS})
+        string(REGEX REPLACE "^${DEP}::" "" GZ_COMPONENT ${LINKLIB})
+
+        if (GZ_COMPONENT STREQUAL DEP)
+          continue()
+        endif()
+
+        list(APPEND BUILD_EXAMPLES_CMAKE "-D${GZ_COMPONENT}_DIR=${${GZ_COMPONENT}_DIR}")
+      endforeach()
+    endif()
+  endforeach()
+
+  # Add root project CMake directory
+  list(APPEND BUILD_EXAMPLES_CMAKE "-D${PROJECT_NAME}_DIR=${PROJECT_BINARY_DIR}/cmake")
+
+  # Add project component CMake directories
+  foreach (COMPONENT ${gz_build_examples_COMPONENTS})
+    list(APPEND BUILD_EXAMPLES_CMAKE "-D${PROJECT_NAME}-${COMPONENT}_DIR=${PROJECT_BINARY_DIR}/cmake")
+  endforeach()
+
+  # Get core library includes from target include directories
+  get_target_property(core_INCLUDES ${PROJECT_LIBRARY_TARGET_NAME} INTERFACE_INCLUDE_DIRECTORIES)
+  list(APPEND BUILD_EXAMPLES_INCLUDES ${core_INCLUDES} )
+
+  # Get component library includes
+  foreach (COMPONENT ${gz_build_examples_COMPONENTS})
+    get_target_property(component_INCLUDES ${PROJECT_LIBRARY_TARGET_NAME}-${COMPONENT} INTERFACE_INCLUDE_DIRECTORIES)
+
+    message(STATUS "${COMPONENT}_INCLUDES = ${component_INCLUDES}")
+    list(APPEND BUILD_EXAMPLES_INCLUDES ${component_INCLUDES} )
+  endforeach()
+
+  # Join everything with semicolon to be passed on command line
+  set(INCLUDES "$<JOIN:${BUILD_EXAMPLES_INCLUDES},;>")
+
+  add_test(
+    NAME EXAMPLES_Configure_TEST
+    COMMAND ${CMAKE_COMMAND} -G${CMAKE_GENERATOR}
+                             -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
+                             -S ${gz_build_examples_SOURCE_DIR}
+                             -B ${gz_build_examples_BINARY_DIR}
+                             ${BUILD_EXAMPLES_CMAKE}
+                             "-D${PROJECT_LIBRARY_TARGET_NAME}_INCLUDE_DIRS_OVERRIDE=${INCLUDES}"
+  )
+
+  add_test(
+    NAME EXAMPLES_Build_TEST
+    COMMAND ${CMAKE_COMMAND} --build ${gz_build_examples_BINARY_DIR}
+                             --config $<CONFIG>
+  )
+  set_tests_properties(EXAMPLES_Build_TEST
+    PROPERTIES DEPENDS "EXAMPLES_Configure_TEST")
+endmacro()
+
 #################################################
 # _gz_cmake_parse_arguments(<prefix> <options> <oneValueArgs> <multiValueArgs> [ARGN])
 #

cmake/gz-config.cmake.in

@@ -137,7 +137,12 @@ endif()
 # contain imported targets, so @PKG_NAME@_INCLUDE_DIRS is never needed.
 set(@PKG_NAME@_CORE_LIBRARY @simple_import_name@)
 set(@PKG_NAME@_LIBRARIES @gz_namespace@requested)
-set_and_check(@PKG_NAME@_INCLUDE_DIRS "@PACKAGE_GZ_INCLUDE_INSTALL_DIR_FULL@")
+
+if (NOT @PKG_NAME@_INCLUDE_DIRS_OVERRIDE)
+  set_and_check(@PKG_NAME@_INCLUDE_DIRS "@PACKAGE_GZ_INCLUDE_INSTALL_DIR_FULL@")
+else()
+  set_and_check(@PKG_NAME@_INCLUDE_DIRS ${@PKG_NAME@_INCLUDE_DIRS_OVERRIDE})
+endif()
 
 # Backwards compatibility variables
 set(@LEGACY_PROJECT_PREFIX@_LIBRARIES ${@PKG_NAME@_LIBRARIES})