gp-vpn: reintroduce no-longer supported package (see NixOS/nixpkgs#31…

…6526)

flake.nix

@@ -127,7 +127,9 @@
       };
 
       packages.${system} = {
-        inherit (pkgs) bazecor metals metals-updater zoom-us;
+        inherit (pkgs) bazecor metals metals-updater;
+        # crappy software I need for $work
+        inherit (pkgs) globalprotect-openconnect slack zoom-us;
       };
     };
 }

lib/overlays.nix

@@ -99,6 +99,11 @@ let
   pipewireOverlay = f: p: {
     pipewire-zoom = inputs.nixpkgs-zoom.legacyPackages.${system}.pipewire;
   };
+
+  # globalprotect vpn overlay for no-longer supported package
+  gloabalProtectOverlay = f: p: {
+    inherit (inputs.nixpkgs-zoom.legacyPackages.${system}) globalprotect-openconnect;
+  };
 in
 [
   cowsayOverlay
@@ -113,6 +118,7 @@ in
   statix.overlays.default
   xargsOverlay
   pipewireOverlay
+  gloabalProtectOverlay
   (import ../home/overlays/bat-lvl)
   (import ../home/overlays/bazecor)
   (import ../home/overlays/hypr-monitor-attached)

outputs/os.nix

@@ -27,6 +27,7 @@ in
     inherit lib pkgs system;
     specialArgs = { inherit inputs; };
     modules = [
+      ../system/modules/globalprotectvpn.nix
       ../system/machine/thinkpad-x1
       ../system/configuration.nix
       extraSystemConfig

system/modules/globalprotectvpn.nix

@@ -0,0 +1,57 @@
+{ config, lib, pkgs, ... }:
+
+let
+  cfg = config.services.globalprotectvpn;
+
+  execStart =
+    if cfg.csdWrapper == null then
+      "${pkgs.globalprotect-openconnect}/bin/gpservice"
+    else
+      "${pkgs.globalprotect-openconnect}/bin/gpservice --csd-wrapper=${cfg.csdWrapper}";
+in
+{
+  options.services.globalprotectvpn = {
+    enable = lib.mkEnableOption "globalprotectvpn";
+
+    settings = lib.mkOption {
+      description = ''
+        GlobalProtect-openconnect configuration. For more information, visit
+        <https://github.com/yuezk/GlobalProtect-openconnect/wiki/Configuration>.
+      '';
+      default = { };
+      example = {
+        "vpn1.company.com" = {
+          openconnect-args = "--script=/path/to/vpnc-script";
+        };
+      };
+      type = lib.types.attrs;
+    };
+
+    csdWrapper = lib.mkOption {
+      description = ''
+        A script that will produce a Host Integrity Protection (HIP) report,
+        as described at <https://www.infradead.org/openconnect/hip.html>
+      '';
+      default = null;
+      example = lib.literalExpression ''"''${pkgs.openconnect}/libexec/openconnect/hipreport.sh"'';
+      type = lib.types.nullOr lib.types.path;
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    services.dbus.packages = [ pkgs.globalprotect-openconnect ];
+
+    environment.etc."gpservice/gp.conf".text = lib.generators.toINI { } cfg.settings;
+
+    systemd.services.gpservice = {
+      description = "GlobalProtect openconnect DBus service";
+      serviceConfig = {
+        Type = "dbus";
+        BusName = "com.yuezk.qt.GPService";
+        ExecStart = execStart;
+      };
+      wantedBy = [ "multi-user.target" ];
+      after = [ "network.target" ];
+    };
+  };
+}