Merge pull request facebook#98 from tonyhb/feature/datepicker-android

Add DatePickerAndroid API

.travis.yml

@@ -3,7 +3,7 @@ node_js:
   - "7"
 
 script:
-  - npm run build
+  - npm run clean-build
 
 cache:
   directories:

STATUS.md

@@ -54,7 +54,7 @@
 - [x] BackHandler
 - [ ] CameraRoll
 - [ ] Clipboard
-- [ ] DatePickerAndroid
+- [x] DatePickerAndroid
 - [x] Dimensions
 - [ ] Easing
 - [ ] Geolocation

package.json

@@ -4,7 +4,7 @@
 	"scripts": {
 		"build": "bsb -make-world",
 		"start": "bsb -make-world -w",
-		"clean": "bsb -clean-world",
+		"clean-build": "bsb -clean-world -make-world",
 		"test": "exit 0"
 	},
 	"license": "MIT",

src/datePickerAndroid.re

@@ -0,0 +1,59 @@
+[@bs.scope "DatePickerAndroid"] [@bs.module "react-native"] external dateSet : string =
+  "dateSetAction";
+
+[@bs.scope "DatePickerAndroid"] [@bs.module "react-native"] external dismissed : string =
+  "dismissedAction";
+
+type mode =
+  | Calendar
+  | Spinner
+  | Default;
+
+type response = {
+  year: int,
+  month: int,
+  day: int
+};
+
+type action =
+  | Dismissed
+  | Set(response);
+
+let action = (resp) =>
+  if (resp##action == dateSet) {
+    Set({year: resp##year, month: resp##month, day: resp##day})
+  } else if (resp##action == dismissed) {
+    Dismissed
+  } else {
+    failwith(
+      "Unknown action received from DatePickerAndroid. Please report this in the bs-react-native repository"
+    )
+  };
+
+type responseJs = {. "action": string, "year": int, "month": int, "day": int};
+
+type optsJs = {
+  .
+  "date": Js.Date.t,
+  "minDate": Js.Nullable.t(Js.Date.t),
+  "maxDate": Js.Nullable.t(Js.Date.t),
+  "mode": string
+};
+
+[@bs.scope "DatePickerAndroid"] [@bs.module "react-native"]
+external _open : optsJs => Js.Promise.t(responseJs) =
+  "open";
+
+let open_ = (~date: Js.Date.t, ~minDate=?, ~maxDate=?, ~mode=Default, ()) =>
+  _open({
+    "date": date,
+    "minDate": Js.Nullable.from_opt(minDate),
+    "maxDate": Js.Nullable.from_opt(maxDate),
+    "mode":
+      switch mode {
+      | Default => "default"
+      | Calendar => "calendar"
+      | Spinner => "spinner"
+      }
+  })
+  |> Js.Promise.then_((resp: responseJs) => resp |> action |> Js.Promise.resolve);

src/datePickerAndroid.rei

@@ -0,0 +1,18 @@
+type response = {
+  year: int,
+  month: int,
+  day: int
+};
+
+type action =
+  | Dismissed
+  | Set(response);
+
+type mode =
+  | Calendar
+  | Spinner
+  | Default;
+
+let open_:
+  (~date: Js.Date.t, ~minDate: Js.Date.t=?, ~maxDate: Js.Date.t=?, ~mode: mode=?, unit) =>
+  Js.Promise.t(action);