Autoload an opt plugin on Filetype.

[heliomeiralins]

After reading the documentation it seems that it's the user responsibility to load opt plugins. ( with :packadd)
Could minpac provide an API to load plugins on certain filetypes? Or is there an easy native way( besides Autocomd's) to do it?

[k-takata]

Currently minpac doesn't provide an easy way to load opt plugins. (Because, personally, I don't use it.)
I think that the following code will work:

augroup PackFTLoad
  autocmd!
  autocmd FileType THEFILETYPE packadd PLUGINNAME
augroup END

[ony]

Other hack-around:

" minautopac.vim

" Naïve autoload of packs
" See https://github.com/k-takata/minpac/issues/28
" And https://github.com/junegunn/vim-plug/blob/9813d5e/plug.vim#L271-L276
function! minautopac#add(repo, ...)
    let l:opts = get(a:000, 0, {})
    if has_key(l:opts, 'for')
        let l:name = substitute(a:repo, '^.*/', '', '')
        let l:ft = l:opts.for  " TODO: support array
        execut printf('autocmd FileType %s packadd %s', l:ft, l:name)
    endif
endfunction

if exists('*minpac#init')
    call minpac#init()

    command! -nargs=+ -bar Plugin call minpac#add(<args>) | call minautopac#add(<args>)
else
    " do nothing
    command! -nargs=+ Plugin call minautopac#add(<args>)
endif

command! -bar PackUpdate packadd minpac | runtime minautopac.vim | call minpac#update()
command! -bar PackClean packadd minpac | runtime minautopac.vim | call minpac#clean()

runtime! OPT ftdetect/*.vim

augroup MinAutoPac
    autocmd!
    runtime! myplugins.vim
augroup END

" myplugins.vim
Plugin 'eagletmt/neco-ghc', {'type': 'opt', 'for': 'haskell'}

[ghost]

function! minautopac#add(repo, ...) abort
    let l:opts = get(a:000, 0, {})
    if has_key(l:opts, 'for')
        let l:name = substitute(a:repo, '^.*/', '', '')
        let l:ft = type(l:opts.for) == type([]) ? join(l:opts.for, ',') : l:opts.for
        execut printf('autocmd FileType %s packadd %s', l:ft, l:name)
    endif
endfunction