added enum support

db/migrations/20200324211956_create_issue.cr

@@ -0,0 +1,14 @@
+class CreateIssue::V20200324211956 < Avram::Migrator::Migration::V1
+  def migrate
+    create table_for(Issue) do
+      primary_key id : Int64
+      add status : Int32
+      add role : Int32
+      add_timestamps
+    end
+  end
+
+  def rollback
+    drop table_for(Issue)
+  end
+end

spec/support/boxes/issue_box.cr

@@ -0,0 +1,14 @@
+class IssueBox < BaseBox
+  def initialize
+    status Issue::Status.new(:opened)
+    role Issue::Role.new(:issue)
+  end
+
+  def build_model
+    Issue.new(
+      id: 123_i64,
+      status: 0,
+      role: 0
+    )
+  end
+end

spec/support/issue.cr

@@ -0,0 +1,23 @@
+class Issue < BaseModel
+  COLUMN_SQL = "issues.id, issues.status, issues.role"
+
+  avram_enum Status do
+    Opened
+    Closed
+    Duplicated
+  end
+
+  avram_enum Role do
+    Issue    = 1
+    Bug      = 2
+    Critical = 3
+  end
+
+  table do
+    column status : Issue::Status
+    column role : Issue::Role
+  end
+end
+
+class IssueQuery < Issue::BaseQuery
+end

spec/type_extensions/enum_spec.cr

@@ -0,0 +1,28 @@
+require "../spec_helper"
+
+include LazyLoadHelpers
+
+describe "Enum" do
+  it "check enum" do
+    issue = IssueBox.create
+
+    issue.status.enum.should eq(Issue::AvramStatus::Opened)
+    issue.role.enum.should eq(Issue::AvramRole::Issue)
+  end
+
+  it "update enum" do
+    issue = IssueBox.create
+
+    updated_issue = Issue::SaveOperation.update!(issue, status: Issue::Status.new(:closed))
+
+    updated_issue.status.enum.should eq(Issue::AvramStatus::Closed)
+    updated_issue.role.enum.should eq(Issue::AvramRole::Issue)
+  end
+
+  it "access enum methods" do
+    issue = IssueBox.create
+
+    issue.status.opened?.should eq(true)
+    issue.status.value.should eq(0)
+  end
+end

src/avram/charms/enum_extensions.cr

@@ -0,0 +1,61 @@
+macro avram_enum(enum_name, &block)
+  enum Avram{{ enum_name }}
+    {{ block.body }}
+  end
+
+  class {{ enum_name }}
+    def self.adapter
+      Lucky
+    end
+
+    getter :enum
+
+    # You may need to prefix with {{ @type }}
+    #
+    #   {{ @type }}::{{enum_name}}
+    def initialize(@enum : Avram{{ enum_name }})
+    end
+
+    def initialize(enum_value : Int32)
+      @enum = Avram{{ enum_name }}.from_value(enum_value)
+    end
+
+    def initialize(enum_value : String)
+      @enum = Avram{{ enum_name }}.from_value(enum_value.to_i)
+    end
+
+    forward_missing_to @enum
+
+    module Lucky
+      alias ColumnType = Int32
+      include Avram::Type
+
+      def from_db!(value : Int32)
+        {{ enum_name }}.new(value)
+      end
+
+      def parse(value : Avram{{ enum_name }})
+        SuccessfulCast({{ enum_name }}).new(value)
+      end
+
+      def parse(value : String)
+        SuccessfulCast({{ enum_name }}).new({{ enum_name }}.new(value.to_i))
+      end
+
+      def parse(value : Int32)
+        SuccessfulCast({{ enum_name }}).new({{ enum_name }}.new(value))
+      end
+
+      def to_db(value : Int32)
+        value.to_s
+      end
+
+      def to_db(value : {{ enum_name }})
+        value.value.to_s
+      end
+
+      class Criteria(T, V) < Int32::Lucky::Criteria(T, V)
+      end
+    end
+  end
+end